app-pda/libimobiledevice: Follow Fedora patches and GIT snapshot

Package-Manager: Portage-2.3.38, Repoman-2.3.9

app-pda/libimobiledevice/Manifest

@@ -1 +1,4 @@
+DIST libimobiledevice-1.2.0-git.patch 187304 BLAKE2B 7c184f823b831b913dbae16a58db1e4b7682fb42e573b1bab3983eb8150feb696795fd59c81ca7582fd56cd953e32489a8ddc502c4cb39a6ac88ff3d018ceace SHA512 cfc433a8eada9357ee5119ccfeb1e7444f10132637a43954174721905207b0e168f49a1728ee16ed6b0a9fd8b9617e8e35b04cf34f775abd1d12b8ecb7dbdbd2
+DIST libimobiledevice-1.2.0-userpref-GnuTLS-Fix-3.6.0-SHA1-compatibility.patch 2272 BLAKE2B 2f435af75c6f7fe319c76b52feac32d8f1389806835658bae5713d82471d0b2edd01b062871bff5e757795c220e2cd4c77d404c1df0cf9616c2fc2d77364b686 SHA512 a31741cfaae53781a1491fd53514e614e64c676573dc9252adea2fb0d64005eb5fad6483f1848b0246f0fff76c8fb4535f56a6e97c13dd7aa48a29061cabb172
+DIST libimobiledevice-1.2.0-userpref-GnuTLS-Use-valid-serial-for-3.6.0.patch 2014 BLAKE2B 8a6e51af145cf9983aa92ad7febf8d48a64b81f4f4664079ee7df3d433626141e10af6700ad38aad81bbbf3be03d6b35bae4f10a595e97f6998a06b6b2a4fbd4 SHA512 1c6002f8da5524603b989613fc1b14e526bc6fcbf515890f8c4976fe5e1b3801f04f6b210264624990ff7dd7de01063ad53dbf9ec506a0645098692a948216b9
 DIST libimobiledevice-1.2.0.tar.bz2 631495 BLAKE2B b04d87906615710e9e143013d27f4a0735e444160cb9dad464cb63d568470397f504680b3faca3995932cc8a80970a5923128d356fad9c98372af4981373ed69 SHA512 0de5f768aeb5d62445892855d84ceaff776f6667733c351ed6c34bf9d500802762d1a06e5efdf57f33cafc9ee788041cd9b6748fb9bad6c2e4ae2f9b9aa93589

app-pda/libimobiledevice/libimobiledevice-1.2.0-r1.ebuild

@@ -0,0 +1,113 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_4,3_5} )
+
+inherit autotools python-r1
+
+DESCRIPTION="Support library to communicate with Apple iPhone/iPod Touch devices"
+HOMEPAGE="http://www.libimobiledevice.org/"
+
+# Get patches from Fedora
+SRC_URI="http://www.libimobiledevice.org/downloads/${P}.tar.bz2
+	https://src.fedoraproject.org/rpms/libimobiledevice/raw/master/f/0001-userpref-GnuTLS-Fix-3.6.0-SHA1-compatibility.patch -> ${P}-userpref-GnuTLS-Fix-3.6.0-SHA1-compatibility.patch
+	https://src.fedoraproject.org/rpms/libimobiledevice/raw/master/f/0002-userpref-GnuTLS-Use-valid-serial-for-3.6.0.patch -> ${P}-userpref-GnuTLS-Use-valid-serial-for-3.6.0.patch
+	https://src.fedoraproject.org/rpms/libimobiledevice/raw/master/f/344409e1d1ad917d377b256214c5411dda82e6b0...5a85432719fb3d18027d528f87d2a44b76fd3e12.patch -> ${P}-git.patch"
+
+# While COPYING* doesn't mention 'or any later version', all the headers do, hence use +
+LICENSE="GPL-2+ LGPL-2.1+"
+
+SLOT="0/6" # based on SONAME of libimobiledevice.so
+
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+IUSE="gnutls python static-libs"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	>=app-pda/libplist-1.11:=
+	>=app-pda/libusbmuxd-1.0.9:=
+	gnutls? (
+		dev-libs/libgcrypt:0
+		>=dev-libs/libtasn1-1.1
+		>=net-libs/gnutls-2.2.0 )
+	!gnutls? ( dev-libs/openssl:0= )
+	python? (
+		${PYTHON_DEPS}
+		app-pda/libplist[python(-),${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	python? ( >=dev-python/cython-0.17[${PYTHON_USEDEP}] )
+"
+
+BUILD_DIR="${S}_build"
+
+PATCHES=(
+	"${DISTDIR}"/${P}-git.patch
+	"${DISTDIR}"/${P}-userpref-GnuTLS-Fix-3.6.0-SHA1-compatibility.patch
+	"${DISTDIR}"/${P}-userpref-GnuTLS-Use-valid-serial-for-3.6.0.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local ECONF_SOURCE=${S}
+
+	local myeconfargs=( $(use_enable static-libs static) )
+	use gnutls && myeconfargs+=( --disable-openssl )
+
+	do_configure() {
+		mkdir -p "${BUILD_DIR}" || die
+		pushd "${BUILD_DIR}" >/dev/null || die
+		econf "${myeconfargs[@]}" "${@}"
+		popd >/dev/null || die
+	}
+
+	do_configure_python() {
+		# Bug 567916
+		PYTHON_LDFLAGS="$(python_get_LIBS)" do_configure "$@"
+	}
+
+	do_configure --without-cython
+	use python && python_foreach_impl do_configure_python
+}
+
+src_compile() {
+	python_compile() {
+		emake -C "${BUILD_DIR}"/cython -j1 \
+			VPATH="${S}/cython:${native_builddir}/cython" \
+			imobiledevice_la_LIBADD="${native_builddir}/src/libimobiledevice.la"
+	}
+
+	local native_builddir=${BUILD_DIR}
+	pushd "${BUILD_DIR}" >/dev/null || die
+	emake -j1
+	use python && python_foreach_impl python_compile
+	popd >/dev/null || die
+}
+
+src_install() {
+	python_install() {
+		emake -C "${BUILD_DIR}/cython" -j1 \
+			VPATH="${S}/cython:${native_builddir}/cython" \
+			DESTDIR="${D}" install
+	}
+
+	local native_builddir=${BUILD_DIR}
+	pushd "${BUILD_DIR}" >/dev/null || die
+	emake -j1 DESTDIR="${D}" install
+	use python && python_foreach_impl python_install
+	popd >/dev/null || die
+
+	dodoc docs/html/*
+	if use python; then
+		insinto /usr/include/${PN}/cython
+		doins cython/imobiledevice.pxd
+	fi
+
+	find "${D}" -name '*.la' -delete || die
+}