media-video/obs-studio: version bump to 21.0.2.

Package-Manager: Portage-2.3.24, Repoman-2.3.6
Closes: https://bugs.gentoo.org/647906
Closes: https://github.com/gentoo/gentoo/pull/7208
This commit is contained in:
Jimi Huotari
2018-02-18 18:15:12 +01:00
committed by Patrice Clement
parent e5632a73a5
commit ccbf804ffe
2 changed files with 109 additions and 0 deletions
+1
View File
@@ -2,3 +2,4 @@ DIST obs-studio-19.0.2.tar.gz 5509958 BLAKE2B a21ed69dacb982e5f2bf31b62b85622ced
DIST obs-studio-20.0.1.tar.gz 5610534 BLAKE2B 6db7a2bc591e88dac2f9450f60403095fc7e637f806657b0eb6fc928fd16fcae7a3d4a933b4bcad8b609fbf2197404bd675467a112e6aee84b9f023b9089a388 SHA512 891be96bbe18a2de4af8efd2eaeb54c388332ac7d93a66efcc18208af9ef2dfe3981f81ba351bdb16a93b2d66bcfef4f5277d3d8746261f0beb1f324ed9a7534
DIST obs-studio-20.1.0.tar.gz 5637636 BLAKE2B 11f42c894af9d8b58ef71eda4c669b557b1b69d8df48d2414ae6d4eda1b8ecb70bb15814a302b87c5b49a43323f772a92ee5dc4a6a58302723b6b1ebf1e35123 SHA512 fd0c4b910b9a07644a9ddb72c2622d1fac67878a8bf445d7ab33385aafa23a5207f89971c428a3be01fa851141d9cbb55e86ca81201928783227fc730d12b962
DIST obs-studio-20.1.3.tar.gz 5638299 BLAKE2B 8956e0ae444c05bc452284a730ba4cba7be9209d82f8b63f9cd0455ed73411eadc61825773c6ca5fe20435082399c72d3aaf8671c3830454d9237cc92ca4450f SHA512 9d7c6892fe8940df6c1f1686f07722ea554b5996e72b702758d670a75f1220de59295c0a7b8b6445825a86623521061f64b7672bbe7526aefc9a12bab902ed74
DIST obs-studio-21.0.2.tar.gz 5904469 BLAKE2B e4e7c1f2b445f1db6b76df0c7a12dd41ffd95e7ea5669d7efc3387cc0fd15e268d864b5da3da5c07d04bc57692a88a53a67351a370621b1a6ca648405d030454 SHA512 a22597ac3a85d4c72b9b1ff886367b158498b6b0141acfd2bdb096a2bd9d29cdfad900dfc00f870eaf0aad66836093579f37b278fa90ccd7b49022e849c1c590
@@ -0,0 +1,108 @@
# Copyright 1999-2018 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
EAPI=6
CMAKE_MIN_VERSION=3.9.6
inherit cmake-utils gnome2-utils
if [[ ${PV} == *9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://github.com/jp9000/obs-studio.git"
EGIT_SUBMODULES=()
else
SRC_URI="https://github.com/jp9000/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
KEYWORDS="~amd64 ~x86"
fi
DESCRIPTION="Software for Recording and Streaming Live Video Content"
HOMEPAGE="https://obsproject.com"
LICENSE="GPL-2"
SLOT="0"
IUSE="+alsa fdk imagemagick jack pulseaudio truetype v4l"
COMMON_DEPEND="
>=dev-libs/jansson-2.5
dev-qt/qtcore:5
dev-qt/qtdeclarative:5
dev-qt/qtgui:5
dev-qt/qtmultimedia:5
dev-qt/qtnetwork:5
dev-qt/qtquickcontrols:5
dev-qt/qtsql:5
dev-qt/qttest:5
dev-qt/qtwidgets:5
dev-qt/qtx11extras:5
media-video/ffmpeg:=[x264]
net-misc/curl
x11-libs/libXcomposite
x11-libs/libXinerama
x11-libs/libXrandr
alsa? ( media-libs/alsa-lib )
fdk? ( media-libs/fdk-aac:= )
imagemagick? ( media-gfx/imagemagick:= )
jack? ( virtual/jack )
pulseaudio? ( media-sound/pulseaudio )
truetype? (
media-libs/fontconfig
media-libs/freetype
)
v4l? ( media-libs/libv4l )
"
DEPEND="${COMMON_DEPEND}"
RDEPEND="${COMMON_DEPEND}"
CMAKE_REMOVE_MODULES_LIST=( FindFreetype )
src_configure() {
local libdir=$(get_libdir)
local mycmakeargs=(
-DDISABLE_ALSA=$(usex !alsa)
-DDISABLE_FREETYPE=$(usex !truetype)
-DDISABLE_JACK=$(usex !jack)
-DDISABLE_LIBFDK=$(usex !fdk)
-DDISABLE_PULSEAUDIO=$(usex !pulseaudio)
-DDISABLE_V4L2=$(usex !v4l)
-DLIBOBS_PREFER_IMAGEMAGICK=$(usex imagemagick)
-DOBS_MULTIARCH_SUFFIX=${libdir#lib}
-DOBS_VERSION_OVERRIDE=${PV}
-DUNIX_STRUCTURE=1
)
cmake-utils_src_configure
}
pkg_postinst() {
gnome2_icon_cache_update
if ! use alsa && ! use pulseaudio; then
elog
elog "For the audio capture features to be available,"
elog "either the 'alsa' or the 'pulseaudio' USE-flag needs to"
elog "be enabled."
elog
fi
if ! has_version "sys-apps/dbus"; then
elog
elog "The 'sys-apps/dbus' package is not installed, but"
elog "could be used for disabling hibernating, screensaving,"
elog "and sleeping. Where it is not installed,"
elog "'xdg-screensaver reset' is used instead"
elog "(if 'x11-misc/xdg-utils' is installed)."
elog
fi
if ! has_version "media-libs/speexdsp"; then
elog
elog "For the speexdsp-based noise suppression filter"
elog "to be available, the 'media-libs/speexdsp' package needs"
elog "to be installed."
elog
fi
}
pkg_postrm() {
gnome2_icon_cache_update
}