kde-apps/kate: drop 20.08.0*

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-apps/kate/Manifest

@@ -1,3 +1,2 @@
 DIST kate-20.04.3.tar.xz 5813840 BLAKE2B bc078ddb20edb282f3779f3f989cfc1e00444484667e80ab8b93d02a488ffa2308196243df44cc3738300ad6e8ecbf09d58d373c81c484ee3250e90ae617c622 SHA512 b2c850a94f8d07d4df29156c710d492422a021a75dceae53c9452fc2f569534b627646c39141dc39182d2d8c1d13691240f2c586220f6aa1ba7d1605903f04f9
-DIST kate-20.08.0.tar.xz 5848668 BLAKE2B ceec76208df253fd3a80f9c2ed905daee4265e63af9a7aac5708d5024044511c6e9c2895a956b38f4b7b367f11cdcefd0cfa4d9fc5d900e7a3bca194b06bef52 SHA512 223b90e9e17a4b3e41df64cb923b9d62783e49215d4e68722cfd81db0278b122aea5be61cc6fdd9ba87051992c1f3cf2fe3a74042f8d1b4b9a225e7fa93b6e41
 DIST kate-20.08.1.tar.xz 5848940 BLAKE2B 70a8848202d73ffe60a22a1565f9e96583d6a523da5ef55da178ba4a29fd188a103ba2d55fd37abae89a93b5022e48838d9e3299f226dae9292f4cbf0b428b4f SHA512 63d1c2d8371047abbdc3b1ea2e96b94a6f85ccec05ff5addc19f19d593e2b1760c91b4d87145d329516bd40e0bed740a94306df7760d1a2936edf09c87f6982a

kde-apps/kate/kate-20.08.0.ebuild

@@ -1,108 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-ECM_HANDBOOK="optional"
-ECM_TEST="true"
-KFMIN=5.72.0
-QTMIN=5.14.2
-VIRTUALX_REQUIRED="test"
-inherit ecm kde.org
-
-DESCRIPTION="Multi-document editor with network transparency, Plasma integration and more"
-HOMEPAGE="https://kate-editor.org/
-https://kde.org/applications/utilities/org.kde.kate"
-
-LICENSE="GPL-2" # TODO: CHECK
-SLOT="5"
-KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86"
-IUSE="activities +filebrowser lspclient +projects plasma +snippets sql telemetry"
-
-# only addons/externaltools depends on kiconthemes, too small for USE
-DEPEND="
-	>=dev-qt/qtdbus-${QTMIN}:5
-	>=dev-qt/qtgui-${QTMIN}:5
-	>=dev-qt/qtwidgets-${QTMIN}:5
-	>=dev-qt/qtxml-${QTMIN}:5
-	>=kde-frameworks/kcodecs-${KFMIN}:5
-	>=kde-frameworks/kcompletion-${KFMIN}:5
-	>=kde-frameworks/kconfig-${KFMIN}:5
-	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
-	>=kde-frameworks/kcoreaddons-${KFMIN}:5
-	>=kde-frameworks/kcrash-${KFMIN}:5
-	>=kde-frameworks/kdbusaddons-${KFMIN}:5
-	>=kde-frameworks/kguiaddons-${KFMIN}:5
-	>=kde-frameworks/ki18n-${KFMIN}:5
-	>=kde-frameworks/kiconthemes-${KFMIN}:5
-	>=kde-frameworks/kio-${KFMIN}:5
-	>=kde-frameworks/kitemviews-${KFMIN}:5
-	>=kde-frameworks/kjobwidgets-${KFMIN}:5
-	>=kde-frameworks/kparts-${KFMIN}:5
-	>=kde-frameworks/kservice-${KFMIN}:5
-	>=kde-frameworks/ktexteditor-${KFMIN}:5
-	>=kde-frameworks/ktextwidgets-${KFMIN}:5
-	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
-	>=kde-frameworks/kwindowsystem-${KFMIN}:5
-	>=kde-frameworks/kxmlgui-${KFMIN}:5
-	activities? ( >=kde-frameworks/kactivities-${KFMIN}:5 )
-	filebrowser? ( >=kde-frameworks/kbookmarks-${KFMIN}:5 )
-	lspclient? ( >=kde-frameworks/kitemmodels-${KFMIN}:5 )
-	plasma? ( >=kde-frameworks/plasma-${KFMIN}:5 )
-	projects? (
-		>=kde-frameworks/knewstuff-${KFMIN}:5
-		>=kde-frameworks/threadweaver-${KFMIN}:5
-	)
-	snippets? ( >=kde-frameworks/knewstuff-${KFMIN}:5 )
-	sql? (
-		>=dev-qt/qtsql-${QTMIN}:5
-		>=kde-frameworks/kwallet-${KFMIN}:5
-	)
-	telemetry? ( dev-libs/kuserfeedback:5 )
-"
-RDEPEND="${DEPEND}"
-
-src_prepare() {
-	ecm_src_prepare
-
-	# delete colliding kwrite translations
-	if [[ ${KDE_BUILD_TYPE} = release ]]; then
-		find po -type f -name "*po" -and -name "kwrite*" -delete || die
-		rm -rf po/*/docs/kwrite || die
-	fi
-}
-
-src_configure() {
-	local mycmakeargs=(
-		$(cmake_use_find_package activities KF5Activities)
-		-DBUILD_filebrowser=$(usex filebrowser)
-		-DBUILD_lspclient=$(usex lspclient)
-		-DBUILD_sessionapplet=$(usex plasma)
-		-DBUILD_project=$(usex projects)
-		-DBUILD_snippets=$(usex snippets)
-		-DBUILD_katesql=$(usex sql)
-		-DBUILD_kwrite=FALSE
-		$(cmake_use_find_package telemetry KUserFeedback)
-	)
-
-	ecm_src_configure
-}
-
-src_test() {
-	# tests hang
-	local myctestargs=(
-		-E "(session_manager_test|sessions_action_test)"
-	)
-
-	ecm_src_test
-}
-
-pkg_postinst() {
-	ecm_pkg_postinst
-
-	if [[ -z "${REPLACING_VERSIONS}" ]]; then
-		elog "The functionality of ktexteditorpreview plugin can be extended with:"
-		elog "  kde-misc/kmarkdownwebview"
-		elog "  media-gfx/kgraphviewer"
-	fi
-}