mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-24 18:58:08 -07:00
dev-python/elasticsearch-curator: bump to 5.6.0
Package-Manager: Portage-2.3.52, Repoman-2.3.12 Signed-off-by: Tomáš Mózes <hydrapolic@gmail.com> Closes: https://github.com/gentoo/gentoo/pull/10544 Signed-off-by: Thomas Deutschmann <whissi@gentoo.org>
This commit is contained in:
Tomas Mozes
committed by
Thomas Deutschmann
Thomas Deutschmann
parent
a3943d843b
commit
cc068e3de6
@@ -1,4 +1,6 @@
|
||||
DIST elasticsearch-6.1.1.tar.gz 28462503 BLAKE2B a3ac6edf6ed110fc3832bc6b1c5e4d7acbc67ee2faeba35d9dc7215bbcf10fb3617cfbc050687d7361fc4b6f644afe9cbfc23591b5ae26e692f38dbf13872e7d SHA512 dcc23ef80ad2545490508d3e9db2fd0e6ae9a99cece0990f537c522265961dad234734548d1d86288af7f65a6ee681f5624d2c0e71df0e1dcc32fdb56dcefe92
|
||||
DIST elasticsearch-curator-5.4.1.tar.gz 294363 BLAKE2B 180882cee9ed3424569705beda727f823cea0cfc47897d06b1cb8258166e40fc9913eb266481b09155a0f5f88b52a680b9187f69417983c2d78b5d24874489c3 SHA512 a2f187d99ebcf8069bfd472316aefe501719400268120c250812670e5525209cebffa913f5fb988305d963bb2a7b61cf47426905b856e34f41afd3a9d67d28f3
|
||||
DIST elasticsearch-curator-5.5.4.tar.gz 221161 BLAKE2B 41828800dd9237142767d3163b3d87770ea5b904858991598cce2feb7c3a22d85c0d73275a2f232099ea82e7346fc20080a3bfef692ee808b730d3e4e6de405d SHA512 99ed18592105d19791513ad713115b6e2a6b589ab8b4e3fc4435b2878e25f552e0bda8d63cb6279970afc6ba39d9f3db17af1b4fb44500fe8a14b060e1530258
|
||||
DIST elasticsearch-curator-5.6.0.tar.gz 221555 BLAKE2B cbf1f645b266d2d08914ff74fd5c63bcd5661ef68a8b9286ed59b05d52d50e18e8d18e00b3a0e037f8e6452ce79213280b5ecffaf6af0a3fb70ef92458c80efa SHA512 7dc02b5d15228ea96254dc7dd8069d8396c5d3df883b7ab42936c7612b0f16f5399131563703ccd05469facee7ddf20a720daf62a2713943a4b9a0c9448dd676
|
||||
DIST elasticsearch-oss-6.3.2.tar.gz 29418577 BLAKE2B 152640dc01a10f44ba43f87f68361cc0dd5e1cf54d0ff92377f3acd1a12a247f002ffe2d003cc53760e891278249c10b1d6d4eb978b0bb1c1ebf8879a2cfcb9a SHA512 3c51a860414f7e55900b1d9a350bdbc3e673c8445e316454c2480315b4b9fc08df58090c6281cecc3ae63d12d78d6bd58e228b3371aa325db799ce18758a21f4
|
||||
DIST elasticsearch-oss-6.4.3.tar.gz 33727639 BLAKE2B b4f4821af7a2447a6a16158c32bf676ebbfd8598fde8af558dd19d6e365df66be17d0984e3acb9380a0d5e0cff486b85f6edf96312bd3bb3fc5ae52c270306f3 SHA512 b1147baa95119a8a96779125351358b4c62f2a546b65a9750c11d1d1b9270f06db6da8ff1d9ad11efade1eaea8487087e2d8839b0edfc5da6d9b54da6c6df4e7
|
||||
|
||||
@@ -0,0 +1,152 @@
|
||||
# Copyright 1999-2018 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
|
||||
|
||||
MY_PN="curator"
|
||||
ES_VERSION="6.4.3"
|
||||
|
||||
inherit distutils-r1
|
||||
|
||||
DESCRIPTION="Tending time-series indices in Elasticsearch"
|
||||
HOMEPAGE="https://github.com/elasticsearch/curator"
|
||||
SRC_URI="https://github.com/elasticsearch/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz
|
||||
test? ( https://artifacts.elastic.co/downloads/elasticsearch/elasticsearch-oss-${ES_VERSION}.tar.gz )"
|
||||
|
||||
LICENSE="Apache-2.0"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~x86"
|
||||
# tests fail in chroot
|
||||
# https://github.com/elastic/elasticsearch/issues/12018
|
||||
RESTRICT="test"
|
||||
IUSE="doc test"
|
||||
|
||||
RDEPEND="
|
||||
>=dev-python/elasticsearch-py-6.1.0[${PYTHON_USEDEP}]
|
||||
<dev-python/elasticsearch-py-7.0.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/click-6.7[${PYTHON_USEDEP}]
|
||||
<dev-python/click-7.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/certifi-2018.10.15[${PYTHON_USEDEP}]
|
||||
>=dev-python/urllib3-1.22[${PYTHON_USEDEP}]
|
||||
>=dev-python/voluptuous-0.9.3[${PYTHON_USEDEP}]"
|
||||
DEPEND="dev-python/setuptools[${PYTHON_USEDEP}]
|
||||
>=dev-python/six-1.11.0[${PYTHON_USEDEP}]
|
||||
dev-python/sphinx[${PYTHON_USEDEP}]
|
||||
>=dev-python/pyyaml-3.10[${PYTHON_USEDEP}]
|
||||
test? ( ${RDEPEND}
|
||||
virtual/jre:1.8
|
||||
dev-python/mock[${PYTHON_USEDEP}]
|
||||
dev-python/nose[${PYTHON_USEDEP}]
|
||||
dev-python/coverage[${PYTHON_USEDEP}]
|
||||
dev-python/nosexcover[${PYTHON_USEDEP}]
|
||||
dev-python/six[${PYTHON_USEDEP}] )"
|
||||
|
||||
S="${WORKDIR}/${MY_PN}-${PV}"
|
||||
|
||||
python_prepare_all() {
|
||||
# avoid downloading from net
|
||||
sed -e '/^intersphinx_mapping/,+3d' -i docs/conf.py || die
|
||||
|
||||
# requests_aws4auth not in portage
|
||||
sed -e '/boto3/d' \
|
||||
-e '/requests_aws4auth/d' \
|
||||
-i setup.cfg setup.py || die
|
||||
|
||||
distutils-r1_python_prepare_all
|
||||
}
|
||||
|
||||
python_compile_all() {
|
||||
emake -C docs -j1 man $(usex doc html "")
|
||||
}
|
||||
|
||||
# running tests in non-chroot environments:
|
||||
# FEATURES="test -usersandbox" emerge dev-python/elasticsearch-curator
|
||||
python_test() {
|
||||
# starts two ES instances (local,remote) and runs the tests
|
||||
# https://github.com/elastic/curator/blob/master/travis-run.sh
|
||||
local ES_INSTANCES="local remote"
|
||||
local ES_PATH="${WORKDIR}/elasticsearch-${ES_VERSION}"
|
||||
|
||||
declare -A ES_PORT
|
||||
ES_PORT[local]=25123
|
||||
ES_PORT[remote]=25124
|
||||
|
||||
local i
|
||||
declare -A ES_CONFIG_DIR ES_CONFIG_PATH ES_INSTANCE ES_LOG ES_PID
|
||||
for i in ${ES_INSTANCES}; do
|
||||
ES_CONFIG_DIR[$i]="${ES_PATH}/$i"
|
||||
ES_CONFIG_PATH[$i]="${ES_CONFIG_DIR[$i]}/elasticsearch.yml"
|
||||
ES_PID[$i]="${ES_PATH}/$i.pid"
|
||||
ES_LOG[$i]="${ES_PATH}/logs/$i.log"
|
||||
done
|
||||
|
||||
# configure ES instances
|
||||
for i in ${ES_INSTANCES}; do
|
||||
mkdir -p "${ES_CONFIG_DIR[$i]}" || die
|
||||
cp ${ES_PATH}/config/{jvm.options,log4j2.properties} "${ES_CONFIG_DIR[$i]}"/ || die
|
||||
echo 'network.host: 127.0.0.1' > "${ES_CONFIG_PATH[$i]}" || die
|
||||
echo "http.port: ${ES_PORT[$i]}" >> "${ES_CONFIG_PATH[$i]}" || die
|
||||
echo "cluster.name: $i" >> "${ES_CONFIG_PATH[$i]}" || die
|
||||
echo 'node.max_local_storage_nodes: 2' >> "${ES_CONFIG_PATH[$i]}" || die
|
||||
echo "discovery.zen.ping.unicast.hosts: [\"127.0.0.1:${ES_PORT[$i]}\"]" >> "${ES_CONFIG_PATH[$i]}" || die
|
||||
done
|
||||
|
||||
echo 'path.repo: /' >> "${ES_CONFIG_PATH[local]}" || die
|
||||
echo "reindex.remote.whitelist: localhost:${ES_PORT[remote]}" >> "${ES_CONFIG_PATH[local]}" || die
|
||||
|
||||
# start ES instances
|
||||
for i in ${ES_INSTANCES}; do
|
||||
ES_PATH_CONF=${ES_CONFIG_DIR[$i]} "${ES_PATH}/bin/elasticsearch" -d -p "${ES_PID[$i]}" || die
|
||||
|
||||
local j
|
||||
local es_started=0
|
||||
for j in {1..20}; do
|
||||
grep -q "started" "${ES_LOG[$i]}" 2> /dev/null
|
||||
if [[ $? -eq 0 ]]; then
|
||||
einfo "Elasticsearch $i started"
|
||||
es_started=1
|
||||
eend 0
|
||||
break
|
||||
elif grep -q 'BindException\[Address already in use\]' "${ES_LOG[$i]}" 2>/dev/null; then
|
||||
eend 1
|
||||
eerror "Elasticsearch $i already running"
|
||||
die "Cannot start Elasticsearch $i for tests"
|
||||
else
|
||||
einfo "Waiting for Elasticsearch $i"
|
||||
eend 1
|
||||
sleep 2
|
||||
continue
|
||||
fi
|
||||
done
|
||||
|
||||
[[ $es_started -eq 0 ]] && die "Elasticsearch failed to start"
|
||||
done
|
||||
|
||||
export TEST_ES_SERVER="localhost:${ES_PORT[local]}"
|
||||
export REMOTE_ES_SERVER="localhost:${ES_PORT[remote]}"
|
||||
|
||||
# run tests
|
||||
esetup.py test || die
|
||||
|
||||
for i in ${ES_INSTANCES}; do
|
||||
pkill -F ${ES_PID[$i]}
|
||||
done
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
use doc && local HTML_DOCS=( docs/_build/html/. )
|
||||
doman docs/_build/man/*
|
||||
distutils-r1_python_install_all
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
ewarn ""
|
||||
ewarn "For Python 3 support information please read: http://click.pocoo.org/latest/python3/"
|
||||
ewarn ""
|
||||
ewarn "Example usage on Python 3:"
|
||||
ewarn "export LC_ALL=en_US.UTF-8"
|
||||
ewarn "export LANG=en_US.UTF-8"
|
||||
ewarn "curator ..."
|
||||
}
|
||||
Reference in New Issue
Block a user