dev-python/elastic-transport: Bump to 9.4.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/elastic-transport/Manifest

@@ -1 +1,2 @@
 DIST elastic-transport-python-9.2.1.gh.tar.gz 78272 BLAKE2B d469e4caa01f741dac083e30fd06b8770739060ae4eee5e4b6b5de1c043bbaf4a5267b3bac3bae63513416d0ddde2981b7c4867cd8a14dd53ea16e14e5187b4f SHA512 5de5929b01e213f61891c6e535da2d4a6197f31a8bc68b372622ce128141a1521fe2c20a92c83afdd0fd65487c9c753755bc0f08716e252fbc3e8ed1906305a6
+DIST elastic-transport-python-9.4.0.gh.tar.gz 78628 BLAKE2B 4bf9e5c7ed5829c13316df701e094feb72168e577f926df987878a40b6c7b9d27ffbd9dd8171a6781cef3e32e7e729fbd49e65640903c965a8099fd332c7c412 SHA512 e03c43dc8ee6866c705c2170a610d8f1c78a6957cffe3d41d92e7d54c6dc68ed537585cff5fcc21c0a98711ae38f7547ea1adfb637033a659db89421da2e07bc

dev-python/elastic-transport/elastic-transport-9.4.0.ebuild

@@ -0,0 +1,68 @@
+# Copyright 2023-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+MY_P=elastic-transport-python-${PV}
+DESCRIPTION="Transport classes and utilities shared among Python Elastic client libraries"
+HOMEPAGE="
+	https://github.com/elastic/elastic-transport-python/
+	https://pypi.org/project/elastic-transport/
+"
+SRC_URI="
+	https://github.com/elastic/elastic-transport-python/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+PROPERTIES="test_network"
+RESTRICT="test"
+
+RDEPEND="
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/sniffio[${PYTHON_USEDEP}]
+	>=dev-python/urllib3-2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/aiohttp[${PYTHON_USEDEP}]
+		dev-python/httpx[${PYTHON_USEDEP}]
+		dev-python/opentelemetry-api[${PYTHON_USEDEP}]
+		dev-python/opentelemetry-sdk[${PYTHON_USEDEP}]
+		dev-python/orjson[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dev-python/respx[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_sphinx docs/sphinx \
+	dev-python/furo \
+	dev-python/sphinx-autodoc-typehints
+EPYTEST_PLUGINS=( anyio pytest-asyncio pytest-httpbin pytest-httpserver )
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+EPYTEST_DESELECT=(
+	# fragile to random warnings
+	tests/node/test_http_aiohttp.py::TestAiohttpHttpNode::test_uses_https_if_verify_certs_is_off
+	tests/node/test_http_aiohttp.py::test_ssl_assert_fingerprint
+	tests/node/test_urllib3_chain_certs.py::test_assert_fingerprint_in_cert_chain
+	# hardcodes supported Accept-Encoding
+	# https://github.com/elastic/elastic-transport-python/issues/269
+	tests/async_/test_async_transport.py::test_async_transport_httpbin
+	tests/async_/test_httpbin.py::test_node
+	tests/test_httpbin.py::test_node
+)
+
+python_test() {
+	epytest -o addopts= # avoid coverage
+}