dev-libs/softhsm: EAPI 8, pull in various correctness fixes from Fedora

* EAPI 8
* Pull in various memory safety & OpenSSL 3 fixes from Fedora (upstream
  is inactive)
* Filter LTO which also causes tests to fail in addition to the above

Closes: https://bugs.gentoo.org/867637
Signed-off-by: Sam James <sam@gentoo.org>

dev-libs/softhsm/Manifest

@@ -1 +1,2 @@
+DIST softhsm-2.6.1-patches.tar.xz 7460 BLAKE2B e9c5496ff1a79121ab62e77ab6541a1678d4254395622aaf76c4b8fdcabbd6144caba5c171e28744ae181169826d2523c9ddf73859ca9ca6bb7a5fdf36a8ea8e SHA512 35330e969d7de532f3b6a0821dc5faa40726dcdd9c62f5e78d05cfec1c35057e183dba0ed638388f3d0ad1bd536b4fbb3cc1ff060e133109cee9681c8ac48052
 DIST softhsm-2.6.1.tar.gz 1066766 BLAKE2B 0295c5f40235c8abd8879a8c6f7fbe8e8d686ee03355006e9c90c0f2f7135eaf6794a3d39febda1b1ed6e5d48dcacb1e14dae85fb0efb884d0d719bfc6624b92 SHA512 e77137096ff2ac2f5396971efbaa2007188855a8f723cb511182c6c5e5a353b3f98297442758e77a18c3a378c0ca3fce8abe090977f0f4f8d526de204fd523fb

dev-libs/softhsm/softhsm-2.6.1-r3.ebuild

@@ -0,0 +1,61 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit flag-o-matic
+
+DESCRIPTION="A software PKCS#11 implementation"
+HOMEPAGE="https://www.opendnssec.org/"
+SRC_URI="https://www.opendnssec.org/files/source/${P}.tar.gz"
+SRC_URI+=" https://dev.gentoo.org/~sam/distfiles/${CATEGORY}/${PN}/${PN}-2.6.1-patches.tar.xz"
+
+LICENSE="BSD"
+SLOT="2"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="gost migration-tool test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	migration-tool? ( dev-db/sqlite:3= )
+	dev-libs/openssl:=
+	!~dev-libs/softhsm-2.0.0:0
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	sys-devel/gcc:=[cxx]
+	virtual/pkgconfig
+	test? ( dev-util/cppunit )
+"
+
+DOCS=( NEWS README.md )
+
+PATCHES=(
+	"${WORKDIR}"/${PN}-2.6.1-patches/${PN}-2.6.1-onexit.patch
+	"${WORKDIR}"/${PN}-2.6.1-patches/${PN}-2.6.1-openssl3-tests.patch
+	"${WORKDIR}"/${PN}-2.6.1-patches/${PN}-2.6.1-uninitialised.patch
+	"${WORKDIR}"/${PN}-2.6.1-patches/${PN}-2.6.1-prevent-global-deleted-objects-access.patch
+)
+
+src_configure() {
+	# Test failures with LTO (bug #867637)
+	append-flags -fno-strict-aliasing
+	filter-lto
+
+	econf \
+		--with-crypto-backend=openssl \
+		--disable-p11-kit \
+		--localstatedir="${EPREFIX}/var" \
+		--enable-ecc \
+		$(use_enable gost) \
+		$(use_with migration-tool migrate)
+}
+
+src_install() {
+	default
+
+	find "${ED}" -name '*.la' -delete || die
+
+	keepdir /var/lib/softhsm/tokens
+}