dev-debug/gfxreconstruct: add 1.4.350.0

Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

dev-debug/gfxreconstruct/Manifest

@@ -1,2 +1,4 @@
 DIST SPIRV-Reflect-1.4.341.0.tar.gz 348384 BLAKE2B 1fc461f02a3e35b610cae0b2e41cfc8b0938a13d5c1fe62d2e3a53d3822cf7bc94d3d3a5cda3ba3707ecc9aa34415b351f1ac25f92922e63378a2822e766fb68 SHA512 ee8abc9958af8887300eece7dbcf11ed4bf79d9ee281318e6794f093a988438736e0da642d61b975912475cc3a0b13fe8cd17d3a6b0fcfff653c9831f5d86ba0
+DIST SPIRV-Reflect-1.4.350.0.tar.gz 350953 BLAKE2B d99bdea2e976ed6c5818db12528142461eac143045fbf47e9cc6c3baf5250fad000d2cd562258335eb9624e43a171412badfb7fc8916e40976432e254e77f818 SHA512 7c7c281bc89d5d50d10dd47ca4afcaddb649a584743eeb8b16eb530ed8208c8ce6e6279ab47e215249aa82328d61684c3ff5cb59f4f057bd71df84c0576a3216
 DIST gfxreconstruct-1.4.341.0.tar.gz 50763927 BLAKE2B b532535012088bb043f1098886bd30ce1e3345515e217a77a05229f98b36678703ed9773169cf7cfa0f09f4694635c69532127df86649cd3e19daa2b6768ec4f SHA512 0efb51431b8ae40e723d06ff3ab6a2505094dc88104a0f2da42f4c1e301dbdd929398e7183a996b7b31854f45506ea636cec40f9fa883aafbe8d8b0b493716aa
+DIST gfxreconstruct-1.4.350.0.tar.gz 61924016 BLAKE2B 37addb3f4ae5581dd642f248b988040e4531b6c2839eee34ead5bfbdc959488781381420d4925528f2b0f8e1c43668ade48e17f963fced29df50882536359674 SHA512 f84979ccbf5dcd5402a6453fd23e36dec43368cd62f4d5e2ca1182e9654cd52906cfd2e38c12d1f23ef11e4b6d349b682de765f5d5df8f27ddd01e2fcd558ca2

dev-debug/gfxreconstruct/gfxreconstruct-1.4.350.0.ebuild

@@ -0,0 +1,76 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+inherit cmake
+
+if [[ ${PV} == 9999* ]]; then
+	EGIT_REPO_URI="https://github.com/LunarG/gfxreconstruct.git"
+	EGIT_SUBMODULES=( external/{Vulkan-Headers,SPIRV-Headers,SPIRV-Reflect} )
+	inherit git-r3
+else
+	SRC_URI="
+		https://github.com/LunarG/${PN}/archive/vulkan-sdk-${PV}.tar.gz -> ${P}.tar.gz
+		https://github.com/KhronosGroup/SPIRV-Reflect/archive/vulkan-sdk-${PV}.tar.gz -> SPIRV-Reflect-${PV}.tar.gz
+	"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}"/${PN}-vulkan-sdk-${PV}
+fi
+
+DESCRIPTION="Graphics API Capture and Replay Tools"
+HOMEPAGE="https://github.com/LunarG/gfxreconstruct"
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="wayland X"
+
+RDEPEND="
+	app-arch/lz4:=
+	app-arch/zstd:=
+	virtual/zlib:=
+
+	media-libs/vulkan-loader[wayland?,X?]
+	wayland? ( dev-libs/wayland )
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb
+		x11-libs/xcb-util-keysyms
+	)
+"
+DEPEND="${RDEPEND}
+	X? ( x11-libs/libXrandr )
+"
+if [[ ${PV} != 9999* ]]; then
+	DEPEND+="
+		~dev-util/spirv-headers-${PV}
+		~dev-util/vulkan-headers-${PV}
+	"
+	PATCHES=(
+		"${FILESDIR}"/1.3.313.0-use-system-vulkan.patch
+	)
+fi
+
+src_unpack() {
+	if [[ ${PV} == 9999* ]]; then
+		git-r3_src_unpack
+	else
+		default
+		rmdir "${S}"/external/SPIRV-Reflect || die
+		mv "${WORKDIR}"/SPIRV-Reflect-vulkan-sdk-${PV} "${S}"/external/SPIRV-Reflect || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_SKIP_RPATH=ON
+		-DBUILD_WERROR=OFF
+		-DBUILD_WSI_DISPLAY_SUPPORT=ON
+		-DBUILD_WSI_WAYLAND_SUPPORT=$(usex wayland)
+		-DBUILD_WSI_XCB_SUPPORT=$(usex X)
+		-DBUILD_WSI_XLIB_SUPPORT=$(usex X)
+		-DGFXRECON_ENABLE_OPENXR=OFF
+	)
+	cmake_src_configure
+}