mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-11-20 22:27:17 -08:00
app-admin/metalog: add 20230707
Signed-off-by: Patrick McLean <chutzpah@gentoo.org>
This commit is contained in:
@@ -1 +1,2 @@
|
||||
DIST metalog-20220214.tar.gz 40898 BLAKE2B 7ef04b9e0cd1ba878a11d988ec4b4bffa3d733f86c6b8cec57d32dcf837fe48a001a233a2b09378443b26f6e69869b8de7afeb25f11bb7729b66e1aa3a305f67 SHA512 44a1443e8f9e92460f128aa35125d50ae247ba4f2ce8fd8cc32b96a491e29963cdc27be12a6db28f286e2d5a2bc6243e126a77ae3eb642e7c969d58446a18fcd
|
||||
DIST metalog-20230707.tar.gz 41729 BLAKE2B e027b918c3b6d795459d9b219a5d84a7813a27b48b6be9e059c19dd2ea546d24e48724360968a2078be8b81b32b296d5444389616afdc16ce9234fd105ee37c9 SHA512 ab341f5f2ac757e4579a1f4fad2a92fd446fe7e930e95e55231830d88bf177f79102f99554b56da0529aaa6fc37c02863824705bde2f47546d44284ab13538b9
|
||||
|
||||
@@ -0,0 +1,70 @@
|
||||
# Copyright 1999-2023 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=7
|
||||
|
||||
inherit autotools systemd
|
||||
|
||||
DESCRIPTION="A highly configurable replacement for syslogd/klogd"
|
||||
HOMEPAGE="https://github.com/hvisage/metalog"
|
||||
SRC_URI="https://github.com/hvisage/${PN}/archive/${P}.tar.gz"
|
||||
S="${WORKDIR}/${PN}-${P}"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
|
||||
IUSE="unicode"
|
||||
|
||||
RDEPEND="
|
||||
dev-libs/libpcre2
|
||||
"
|
||||
DEPEND="${RDEPEND}"
|
||||
BDEPEND="
|
||||
sys-devel/autoconf-archive
|
||||
virtual/pkgconfig
|
||||
"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/${PN}-0.9-metalog-conf.patch
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
eautoreconf
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
econf $(use_with unicode)
|
||||
}
|
||||
|
||||
src_install() {
|
||||
emake DESTDIR="${D}" install
|
||||
dodoc AUTHORS ChangeLog README NEWS metalog.conf
|
||||
|
||||
into /
|
||||
newsbin "${FILESDIR}"/consolelog.sh-r1 consolelog.sh
|
||||
|
||||
newinitd "${FILESDIR}"/metalog.initd-r1 metalog
|
||||
newconfd "${FILESDIR}"/metalog.confd metalog
|
||||
systemd_newunit "${FILESDIR}"/${PN}.service-r1 ${PN}.service
|
||||
}
|
||||
|
||||
pkg_preinst() {
|
||||
if [[ -d "${ROOT}"/etc/metalog && ! -e "${ROOT}"/etc/metalog.conf ]] ; then
|
||||
mv -f "${ROOT}"/etc/metalog/metalog.conf "${ROOT}"/etc/metalog.conf
|
||||
rmdir "${ROOT}"/etc/metalog
|
||||
export MOVED_METALOG_CONF=true
|
||||
else
|
||||
export MOVED_METALOG_CONF=false
|
||||
fi
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
if ${MOVED_METALOG_CONF} ; then
|
||||
ewarn "The default metalog.conf file has been moved"
|
||||
ewarn "from ${EROOT}/etc/metalog/metalog.conf to just"
|
||||
ewarn "${EROOT}/etc/metalog.conf. If you had a standard"
|
||||
ewarn "setup, the file has been moved for you."
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user