dev-python/thriftpy2: Bump to 0.5.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/thriftpy2/Manifest

@@ -1 +1,2 @@
 DIST thriftpy2-0.5.0.tar.gz 779019 BLAKE2B b29e5349e11e3ce3bd587a7c8212cd6def7b9b287554a068399591bb7493a5c1d0e97c9b38a64973c01d27a83d49e181aad64cb41ce9500e40b96c813caa7b2d SHA512 f4c83bac053a2f073507e38f284f981bd129ee960dc9817f3bd5795c8e9773b78fa23d49d97cb5975783dbd1f4b52f380861bf4fc32a1af795365f703856f350
+DIST thriftpy2-0.5.2.tar.gz 782261 BLAKE2B 657e8dadd8757f9f0f6b4a7f73e4347651f6301c969cf4d2c37cf87c6176322b7afad6372a39ed7d4c9f36d07850d6ae4edb73ff08dd3530b88e0194032abc9b SHA512 89a73d70b7ba74acc5344c1471587a66664331fb3d160eeb31d27434c78a3e76e3ec0d84dec14ec57d0bcc89e867759883d69247ae65bff1a9a8a00fc8ff7747

dev-python/thriftpy2/thriftpy2-0.5.2.ebuild

@@ -0,0 +1,57 @@
+# Copyright 2021-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{10..13} )
+
+inherit distutils-r1 flag-o-matic pypi
+
+DESCRIPTION="Pure python approach of Apache Thrift"
+HOMEPAGE="
+	https://github.com/Thriftpy/thriftpy2/
+	https://pypi.org/project/thriftpy2/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+RDEPEND="
+	<dev-python/ply-4[${PYTHON_USEDEP}]
+	<dev-python/six-2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+	test? (
+		dev-python/pytest-asyncio[${PYTHON_USEDEP}]
+		dev-python/pytest-reraise[${PYTHON_USEDEP}]
+		dev-python/tornado[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_compile() {
+	# -Werror=strict-aliasing
+	# https://bugs.gentoo.org/857105
+	# https://github.com/Thriftpy/thriftpy2/issues/246
+	#
+	# Don't trust this to LTO
+	append-flags -fno-strict-aliasing
+	filter-lto
+
+	distutils-r1_src_compile
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		tests/test_tornado.py::TornadoRPCTestCase::test_asynchronous_exception
+		tests/test_tornado.py::TornadoRPCTestCase::test_asynchronous_result
+	)
+
+	cd tests || die
+	epytest
+}