media-sound/aqualung: EAPI 6, sort deps, fix build w/ USE=mac

Gentoo-bug: 564366, 575880

Package-Manager: portage-2.3.3
This commit is contained in:
Andreas Sturmlechner
2017-02-18 17:53:06 +01:00
parent 45db788641
commit cb29aeb2c8
4 changed files with 155 additions and 1 deletions
@@ -0,0 +1,99 @@
# Copyright 1999-2017 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Id$
EAPI=6
inherit eutils
MY_PV=${PV/_/-}
DESCRIPTION="Music player for a wide range of formats designed for gapless playback"
HOMEPAGE="http://aqualung.jeremyevans.net/ https://github.com/jeremyevans/aqualung"
SRC_URI="mirror://sourceforge/aqualung/${PN}-${MY_PV}.tar.gz"
LICENSE="GPL-2"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="alsa cdda cddb debug flac ffmpeg ifp jack ladspa lame libsamplerate lua
mac modplug mp3 musepack oss podcast pulseaudio sndfile speex systray
vorbis wavpack"
RDEPEND="
app-arch/bzip2
dev-libs/libxml2
sys-libs/zlib
x11-libs/gtk+:2
alsa? ( media-libs/alsa-lib )
cdda? ( dev-libs/libcdio-paranoia )
cddb? ( media-libs/libcddb )
ffmpeg? ( >=virtual/ffmpeg-0.6.90 )
flac? ( media-libs/flac )
ifp? ( media-libs/libifp )
jack? ( media-sound/jack-audio-connection-kit )
ladspa? ( media-libs/liblrdf )
lame? ( media-sound/lame )
libsamplerate? ( media-libs/libsamplerate )
lua? ( dev-lang/lua:0= )
mac? ( media-sound/mac )
modplug? ( media-libs/libmodplug )
mp3? ( media-libs/libmad )
musepack? ( >=media-sound/musepack-tools-444 )
pulseaudio? ( media-sound/pulseaudio )
sndfile? ( media-libs/libsndfile )
speex? ( media-libs/speex media-libs/liboggz media-libs/libogg )
vorbis? ( media-libs/libvorbis media-libs/libogg )
wavpack? ( media-sound/wavpack )
"
DEPEND="${RDEPEND}
sys-devel/gettext
virtual/pkgconfig
"
S=${WORKDIR}/${PN}-${MY_PV}
PATCHES=(
"${FILESDIR}/${P}-ffmpeg3.patch"
"${FILESDIR}/${P}-mac.patch"
)
src_configure() {
econf \
--disable-rpath \
--enable-loop \
--enable-nls \
--enable-transcoding \
$(use_enable debug) \
$(use_enable podcast) \
$(use_enable systray) \
$(use_enable jack jack-mgmt) \
$(use_with alsa) \
$(use_with cdda) \
$(use_with cddb) \
$(use_with ffmpeg lavc) \
$(use_with flac) \
$(use_with ifp) \
$(use_with jack) \
$(use_with ladspa) \
$(use_with lame) \
$(use_with libsamplerate src) \
$(use_with lua) \
$(use_with mac) \
$(use_with modplug mod) \
$(use_with mp3 mpeg) \
$(use_with musepack mpc) \
$(use_with oss) \
$(use_with pulseaudio pulse) \
$(use_with sndfile) \
$(use_with speex) \
$(use_with vorbis vorbis) \
$(use_with vorbis vorbisenc) \
$(use_with wavpack)
}
src_install() {
default
newicon src/img/icon_64.png aqualung.png
make_desktop_entry aqualung Aqualung
}
@@ -0,0 +1,29 @@
From 3f60efe3dbab8e9d2c07a7b183fd009b3c999d60 Mon Sep 17 00:00:00 2001
From: Jamie Heilman <jamie@audible.transient.net>
Date: Sun, 8 May 2016 19:34:36 +0000
Subject: [PATCH] ffmpeg/libav: support libavcodec API 55 and later
With FFmpeg 1.0 and libav 10, AVCodecContext.{get,release}_buffer()
were deprecated; the new default AVCodecContext.get_buffer2()
implementation works fine for us.
---
src/decoder/dec_lavc.c | 2 ++
1 file changed, 2 insertions(+)
diff --git a/src/decoder/dec_lavc.c b/src/decoder/dec_lavc.c
index e2c81c6..5268a64 100644
--- a/src/decoder/dec_lavc.c
+++ b/src/decoder/dec_lavc.c
@@ -280,10 +280,12 @@ lavc_decoder_open(decoder_t * dec, char * filename) {
return DECODER_OPEN_BADLIB;
pd->avCodecCtx = pd->avFormatCtx->streams[pd->audioStream]->codec;
+#if LIBAVCODEC_VERSION_MAJOR < 55
#if LIBAVCODEC_VERSION_MAJOR >= 53
pd->avCodecCtx->get_buffer = avcodec_default_get_buffer;
pd->avCodecCtx->release_buffer = avcodec_default_release_buffer;
#endif /* LIBAVCODEC_VERSION_MAJOR >= 53 */
+#endif /* LIBAVCODEC_VERSION_MAJOR < 55 */
pd->time_base = pd->avFormatCtx->streams[pd->audioStream]->time_base;
@@ -0,0 +1,26 @@
Revert this patch.
From 12c3a45a6d5b6ef0da70e0cdc424beff993eeef6 Mon Sep 17 00:00:00 2001
From: Tom Szilagyi <tszilagyi@users.sourceforge.net>
Date: Mon, 9 Jun 2014 12:54:54 +0000
Subject: [PATCH] Make the APE decoder compile with current libmac-dev
(4.11-u4-b5-s7-d)
git-svn-id: https://svn.code.sf.net/p/aqualung/code/trunk@1303 3cd24cdc-1f22-0410-b8b1-dcf80e670293
---
src/decoder/dec_mac.cpp | 2 +-
1 file changed, 1 insertion(+), 1 deletion(-)
diff --git a/src/decoder/dec_mac.cpp b/src/decoder/dec_mac.cpp
index 024c8b9..2e9bc01 100644
--- a/src/decoder/dec_mac.cpp
+++ b/src/decoder/dec_mac.cpp
@@ -174,7 +174,7 @@ mac_decoder_open(decoder_t * dec, char * filename) {
int ret = 0;
+ wchar_t * pUTF16 = GetUTF16FromANSI(filename);
- wchar_t * pUTF16 = CAPECharacterHelper::GetUTF16FromANSI(filename);
pdecompress = CreateIAPEDecompress(pUTF16, &ret);
free(pUTF16);
+1 -1
View File
@@ -18,6 +18,6 @@
<flag name="systray">Enable system tray support</flag>
</use>
<upstream>
<remote-id type="sourceforge">aqualung</remote-id>
<remote-id type="github">jeremyevans/aqualung</remote-id>
</upstream>
</pkgmetadata>