dev-python/scikit-learn: Bump to 1.7.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/scikit-learn/Manifest

@@ -1,2 +1,3 @@
 DIST scikit-learn-1.6.1.gh.tar.gz 7046495 BLAKE2B 83292549cc12e44033451345fe6deac17fa4f3d013f9755839d4d7f1c7de9690c089a754493d0d3879ef44ed8523400d617fa4d135ce8500dab608552777cdf6 SHA512 ad91d7bd67884851334fed9b0f3b6f3bfacb6b1521b89acbe22e9428a88009579373118bbd3a55358ea60c997e98609062fc4eac8b1def1d0ad18026c0491074
+DIST scikit-learn-1.7.0.gh.tar.gz 7155945 BLAKE2B bd95523f81d64c1eca8bb162372344a91331007a0a0c9764d84fd6e92ce5ae4f72f9595598e8ea806b7bcfcff1f97e020bb6976a738fcca8c0f22ae348355207 SHA512 9093af3df99bdb9dc3961e4ba576ec53a2fd27c9a6dbe49b24a9cc9de9ae33536dff7c68c4430ff0c29bd4e0e2ee05f937c94b048a2443aa92c7258a82011fca
 DIST scikit-learn-1.7.0rc1.gh.tar.gz 7160017 BLAKE2B 15534eeef26f8f7ee335f14cb193be3742c1fe215093f2852e7ad6a00e23237fae2b6af820632bc07630c51a54f6cc5bdd8e4a7b40834c2b1ddf6b385c55eb06 SHA512 103dda41a312dad7a9586ffcc3d2e95594de566dfa33cce5e06b34b30bd62eceae762af4ecfc5094313a28502db2c22aafd1bd69bffe5347ccb651fa589ebe9d

dev-python/scikit-learn/scikit-learn-1.7.0.ebuild

@@ -0,0 +1,83 @@
+# Copyright 2020-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=meson-python
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1
+
+DESCRIPTION="Machine learning library for Python"
+HOMEPAGE="
+	https://scikit-learn.org/stable/
+	https://github.com/scikit-learn/scikit-learn/
+	https://pypi.org/project/scikit-learn/
+"
+SRC_URI="
+	https://github.com/scikit-learn/scikit-learn/archive/${PV/_}.tar.gz
+		-> ${P/_}.gh.tar.gz
+"
+S=${WORKDIR}/${P/_}
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86 ~arm64-macos ~x64-macos"
+IUSE="examples"
+
+DEPEND="
+	virtual/blas:=
+	virtual/cblas:=
+	>=dev-python/numpy-1.22.0:=[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	${DEPEND}
+	>=dev-python/joblib-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/scipy-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/threadpoolctl-3.1.0[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pythran-0.14.0[${PYTHON_USEDEP}]
+	>=dev-python/cython-3.0.10[${PYTHON_USEDEP}]
+"
+
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+# For some reason this wants to use urllib to fetch things from the internet
+# distutils_enable_sphinx doc \
+# 	dev-python/matplotlib \
+# 	dev-python/memory-profiler \
+# 	dev-python/numpydoc \
+# 	dev-python/pandas \
+# 	dev-python/pillow \
+# 	dev-python/seaborn \
+# 	dev-python/sphinx-gallery \
+# 	dev-python/sphinx-prompt \
+# 	dev-python/scikit-image
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# TODO: floating-point problems
+		gaussian_process/kernels.py::sklearn.gaussian_process.kernels.ExpSineSquared
+	)
+
+	case ${ARCH} in
+		ppc64)
+			EPYTEST_DESELECT+=(
+				# TODO
+				ensemble/_weight_boosting.py::sklearn.ensemble._weight_boosting.AdaBoostRegressor
+			)
+	esac
+
+	rm -rf sklearn || die
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest --pyargs sklearn
+}
+
+python_install_all() {
+	find "${S}" -name \*LICENSE.txt -delete || die
+	distutils-r1_python_install_all
+	use examples && dodoc -r examples
+}