gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-01-06 02:17:34 -08:00
Code Issues Projects Releases Wiki Activity

dev-python/typer: Bump to 0.17.4

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny 2025-09-06 08:40:16 +02:00
parent 9d197cf36c
commit caac78fffa
No known key found for this signature in database
GPG Key ID: 639ADAE2329E240E
2 changed files with 70 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

2
dev-python/typer/Manifest
View File

@ -1,2 +1,4 @@
DIST typer-0.16.1.tar.gz 102836 BLAKE2B bc08cff5c2f0e8dbbcde171f136e89b4992d891b6cefe345a1126b76f12bf0dec3242a584dd5345f827d7d9847de09204826950a2f2f4ae247fba43988a8f30e SHA512 3867a82ea480d81733111088622a7946b771666ee46b0def5eb7e928b71444a16dcb37a54fb6c52872ec83254c27eb7d7e23ff15462d4e27e3933971c96dd608
DIST typer-0.17.3.tar.gz 103517 BLAKE2B 56cff8c8b14f2751c6534821d765dc49a5306373502527e1650aef6db3bf0aec2c0e3f3de49c6cc7ded3a542b60506b55a610fa976bd69b6d0a322ec3ce4c539 SHA512 8180052dbdb98495887d2209263d4336dc3ea923eedbdc2e8752da596c1d80149fa50ae49b410a3434d685ad0a0810bf4a9f12b8829a6c5f6fdc80a1250f9854
DIST typer-0.17.4.tar.gz 103734 BLAKE2B 2eee439d050bfddf51f62d7d634cdccabfdffe1b866bb7fcffbe4d4b1ab0c95291cffe0a041cdf68b0575b16fec24bdff420f05afa5fe0af09efa4c9b5b636ee SHA512 2fa32742976efee760933e31c4a80508903b6901d2c63a9583866067807c55ca9ac0416825e030d164c00a612760a7c7da8aa20b428770b741853b7a0c5d5fee
DIST typer-0.17.4.tar.gz.provenance 8937 BLAKE2B d8b90b79b7ba61ba1249a96ec46c40d6cd530f174b67d2a81ee6c095a8cd71436f70da438d42b2d6705aa386e91d707da4e0461026769045c4d280532d1d60ce SHA512 bb5ecb283f136f129bcc43f976d604b98ff9afe0be738ce780335ee28a71749c8a205adb5daaf126ec431b2509a1c35b3130b3b126825e09a7c9eca61e7ef9da

68
dev-python/typer/typer-0.17.4.ebuild Normal file
View File

@ -0,0 +1,68 @@
# Copyright 2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=pdm-backend
PYPI_VERIFY_REPO=https://github.com/fastapi/typer
PYTHON_COMPAT=( python3_{11..14} )
inherit distutils-r1 shell-completion pypi
DESCRIPTION="Build great CLIs. Easy to code. Based on Python type hints"
HOMEPAGE="
https://typer.tiangolo.com/
https://github.com/fastapi/typer/
https://pypi.org/project/typer/
"
LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64 ~arm64"
IUSE="cli"
RDEPEND="
>=dev-python/click-8.0.0[${PYTHON_USEDEP}]
>=dev-python/rich-10.11.0[${PYTHON_USEDEP}]
>=dev-python/shellingham-1.3.0[${PYTHON_USEDEP}]
>=dev-python/typing-extensions-3.7.4.3[${PYTHON_USEDEP}]
cli? ( !dev-lang/erlang )
"
BDEPEND="
test? (
dev-python/coverage[${PYTHON_USEDEP}]
)
"
EPYTEST_PLUGINS=()
EPYTEST_XDIST=1
distutils_enable_tests pytest
src_prepare() {
distutils-r1_src_prepare
if ! use cli; then
sed -i -e '/typer\.cli/d' pyproject.toml || die
fi
}
python_test() {
# See scripts/tests.sh
local -x TERMINAL_WIDTH=3000
local -x _TYPER_FORCE_DISABLE_TERMINAL=1
local -x _TYPER_RUN_INSTALL_COMPLETION_TESTS=1
epytest
}
python_install() {
if use cli && [[ ! ${COMPLETIONS_INSTALLED} ]]; then
local -x _TYPER_COMPLETE_TEST_DISABLE_SHELL_DETECTION=1
newbashcomp - typer < <(typer --show-completion bash || die)
newzshcomp - typer < <(typer --show-completion zsh || die)
newfishcomp - typer < <(typer --show-completion fish || die)
COMPLETIONS_INSTALLED=1
fi
distutils-r1_python_install
}