dev-python/simsimd: Bump to 6.5.2

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/simsimd/Manifest

@@ -1 +1,2 @@
 DIST SimSIMD-6.5.1.gh.tar.gz 225914 BLAKE2B f093f6c4cbd42d4c5c1e6c995a269d2fd0832cd754d1c6e897d8ba76e58d3cafd91b64227d70a511fb652d127a1b52c165345aca250c2d45f57257611964c865 SHA512 0003651b577b48205e581e99390c5969d38ad25e6264b505b43122e8480cf4834c1b24129c28793c3df8afbdf38fee63e3eefb6a8bfb9071d7808961438193d5
+DIST SimSIMD-6.5.2.gh.tar.gz 220738 BLAKE2B ae2a22bd3ac9dc1f02c3675061bee4e8e24ee535520db904d518560e0fa4daf80bec8a3d4451ea1f12143e6c584ed9e41fc7806011e958deadd6a887a6961243 SHA512 2963a74386771a32345b8018a6bf45fb77a42689ed4120e37257bec33a43a4a8802ca5ca8e2ce57fff73afa2564975b11a8ea0871e88194c16ce87129bf95956

dev-python/simsimd/simsimd-6.5.2.ebuild

@@ -0,0 +1,70 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+
+inherit distutils-r1 toolchain-funcs
+
+MY_P=SimSIMD-${PV}
+DESCRIPTION="Fastest SIMD-Accelerated Vector Similarity Functions for x86 and Arm"
+HOMEPAGE="
+	https://github.com/ashvardanian/SimSIMD/
+	https://pypi.org/project/simsimd/
+"
+# no sdist, as of 4.3.1
+# https://github.com/ashvardanian/SimSIMD/issues/113
+SRC_URI="
+	https://github.com/ashvardanian/SimSIMD/archive/v${PV}.tar.gz
+		-> ${MY_P}.gh.tar.gz
+"
+S=${WORKDIR}/${MY_P}
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="openmp"
+
+BDEPEND="
+	test? (
+		dev-python/tabulate[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-repeat )
+distutils_enable_tests pytest
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]] && use openmp; then
+		tc-check-openmp
+	fi
+}
+
+pkg_setup() {
+	if [[ ${MERGE_TYPE} != binary ]] && use openmp; then
+		tc-check-openmp
+	fi
+}
+
+src_prepare() {
+	sed -i -e '/-O3/d' setup.py || die
+	if ! use openmp; then
+		sed -i -e '/-fopenmp/d' setup.py || die
+	fi
+
+	distutils-r1_src_prepare
+}
+
+src_compile() {
+	einfo "Please disregard initial compiler errors -- the package is checking"
+	einfo "for target support."
+
+	distutils-r1_src_compile
+}
+
+python_test() {
+	epytest scripts/test.py
+}