mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
net-im/mattermost-desktop-bin: add 6.3.1_rc1
Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>
This commit is contained in:
Viorel Munteanu
@@ -6,3 +6,5 @@ DIST mattermost-desktop-6.2.4-rc.1-linux-arm64.tar.gz 124416472 BLAKE2B 00b38265
|
||||
DIST mattermost-desktop-6.2.4-rc.1-linux-x64.tar.gz 126119114 BLAKE2B 1254ac2d73f9c769f8f35d0c2289705ee8b36147b039d039e5a6944261d6de8a768a6c0f4796f6affd9a8e0839cc82af4d1ec6ff4bb0e568e85c0050b3b5a66a SHA512 4fc46014c4a6406032af359fa308ea43dd3b92e62d18b35bddf0a96af34f5698b62cb733ccacb064ea3ca8c3cd585c67625300d1e6ac90a8b253edc69314ff4f
|
||||
DIST mattermost-desktop-6.3.0-linux-arm64.tar.gz 126597799 BLAKE2B bea3998b4dd03a4b64d78b7928d3a0d2ef54b683cbb6b3f706c85f6d4c1babd372d7bf86689b38add27c3f1b89e865c69a4b7962c46f3d6344e61c663e037cbf SHA512 abca09b0a81a3c4cc9a7890cded1200b516a0363dc7311a0dc01604445bfa3070b6c34fa589fc4106d027e884a22667e7b0a25086173af826292b99137f3b093
|
||||
DIST mattermost-desktop-6.3.0-linux-x64.tar.gz 127749162 BLAKE2B deae31a79a7a5577a2f35c6cf3501c1ca881947dafea57186bfcd5f977d5b0790df21e9fd83c721cc2ac1b2328adcc973d0715a19abede1e12ea140ec560ad5d SHA512 69c7697e05df6ebbdf096ac8bfe05409b9d897ee6dd52b1e2264abfcfb24a13e3634e2116d746173691619cf218c81e4e1ce6891bd0ce5e0783f04b01f630abc
|
||||
DIST mattermost-desktop-6.3.1-rc.1-linux-arm64.tar.gz 126598157 BLAKE2B 9135cf1daedbefbe0da96c9f3c684e7861055f2e93827338c96bf0645c101d7ffb12973d47b5cbb2c15ac797b76993f01ec4957c548cab5093d42d46074851cf SHA512 be252c3b1e2ec2f51070a094473d60b5e723cce7928ce651c281d304f2a07a133118b74c2d8c9aca2cc983adc81600ddde90fe5ab0fd2166b99bfd6a4a9b10de
|
||||
DIST mattermost-desktop-6.3.1-rc.1-linux-x64.tar.gz 127749778 BLAKE2B f8bd32fe63239b076860ae4ed4827598aff4dc353967be5ba526387f14f9eb2fdf6ea64c2fac947c828e7e3bcec4251c28d597c537b8a6211883df84eb9a8e3d SHA512 68e08b6cfb17cee0d6c4a468e3871bfaf01692e4c9adf5b36559dfb4e32f6247e3726bee15d4c960237acd8b9be8c45bf46db43268f6f946c766adcfe572103f
|
||||
|
||||
@@ -0,0 +1,123 @@
|
||||
# Copyright 1999-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
MY_PN="${PN%-*}"
|
||||
MY_PV="${PV/_rc/-rc.}"
|
||||
|
||||
inherit desktop toolchain-funcs xdg
|
||||
|
||||
DESCRIPTION="Mattermost Desktop application"
|
||||
HOMEPAGE="https://mattermost.com/"
|
||||
|
||||
SRC_URI="
|
||||
amd64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-x64.tar.gz )
|
||||
arm64? ( https://releases.mattermost.com/desktop/${MY_PV}/mattermost-desktop-${MY_PV}-linux-arm64.tar.gz )
|
||||
"
|
||||
S="${WORKDIR}"
|
||||
|
||||
LICENSE="Apache-2.0 GPL-2+ LGPL-2.1+ MIT"
|
||||
SLOT="0"
|
||||
if [[ ${PV} != *rc* ]]; then
|
||||
KEYWORDS="~amd64 ~arm64"
|
||||
fi
|
||||
|
||||
RDEPEND="
|
||||
>=app-accessibility/at-spi2-core-2.46.0:2[X]
|
||||
dev-libs/expat
|
||||
dev-libs/glib:2
|
||||
dev-libs/nspr
|
||||
dev-libs/nss
|
||||
dev-libs/wayland
|
||||
media-libs/alsa-lib
|
||||
media-libs/mesa
|
||||
net-print/cups
|
||||
sys-apps/dbus
|
||||
sys-libs/glibc
|
||||
virtual/libudev
|
||||
x11-libs/cairo
|
||||
x11-libs/gdk-pixbuf:2
|
||||
x11-libs/gtk+:3[X]
|
||||
x11-libs/libX11
|
||||
x11-libs/libXcomposite
|
||||
x11-libs/libXdamage
|
||||
x11-libs/libXext
|
||||
x11-libs/libXfixes
|
||||
x11-libs/libXrandr
|
||||
x11-libs/libdrm
|
||||
x11-libs/libxcb
|
||||
x11-libs/libxkbcommon
|
||||
x11-libs/pango
|
||||
"
|
||||
|
||||
BDEPEND="
|
||||
dev-util/debugedit
|
||||
"
|
||||
|
||||
QA_PREBUILT="
|
||||
opt/mattermost-desktop/mattermost-desktop
|
||||
opt/mattermost-desktop/chrome_crashpad_handler
|
||||
opt/mattermost-desktop/libnode.so
|
||||
opt/mattermost-desktop/libffmpeg.so
|
||||
opt/mattermost-desktop/libGLESv2.so
|
||||
opt/mattermost-desktop/libEGL.so
|
||||
opt/mattermost-desktop/libvk_swiftshader.so
|
||||
opt/mattermost-desktop/libvulkan.so.1
|
||||
opt/mattermost-desktop/resources/*
|
||||
"
|
||||
|
||||
DOCS=(
|
||||
NOTICE.txt
|
||||
)
|
||||
|
||||
src_prepare() {
|
||||
default
|
||||
|
||||
if use amd64; then
|
||||
find . '(' -name koffi-linux-arm64 -o -name musl_x64 ')' -exec rm -r {} + || die
|
||||
elif use arm64; then
|
||||
find . '(' -name koffi-linux-x64 -o -name musl_arm64 ')' -exec rm -r {} + || die
|
||||
fi
|
||||
|
||||
# file collision with FEATURES=splitdebug, see bug #961437
|
||||
tc-export OBJCOPY
|
||||
find . -type f ! -name '*$(*)*' -print0 | while IFS= read -r -d '' file; do
|
||||
if file "${file}" | grep -qE "ELF (32|64)-bit"; then
|
||||
${OBJCOPY} --remove-section .note.gnu.build-id "${file}" || die
|
||||
debugedit -b "${EPREFIX}/opt/${MY_PN}" -d "/usr/lib/debug" -i "${file}" || die
|
||||
fi
|
||||
done
|
||||
}
|
||||
|
||||
src_install() {
|
||||
if use amd64; then
|
||||
cd mattermost-desktop-${MY_PV}-linux-x64 || die
|
||||
elif use arm64; then
|
||||
cd mattermost-desktop-${MY_PV}-linux-arm64 || die
|
||||
fi
|
||||
newicon app_icon.png ${MY_PN}.png
|
||||
|
||||
insinto "/opt/${MY_PN}/locales"
|
||||
doins locales/*.pak
|
||||
|
||||
insinto "/opt/${MY_PN}/resources"
|
||||
doins -r resources/*.asar*
|
||||
|
||||
insinto "/opt/${MY_PN}"
|
||||
doins *.pak *.bin *.dat
|
||||
exeinto "/opt/${MY_PN}"
|
||||
doexe *.so *.so.* "${MY_PN}" chrome_crashpad_handler
|
||||
|
||||
dosym -r "/opt/${MY_PN}/${MY_PN}" "/usr/bin/${MY_PN}"
|
||||
|
||||
make_desktop_entry --eapi9 mattermost-desktop \
|
||||
-a "--enable-features=WaylandWindowDecorations --ozone-platform-hint=auto %U" \
|
||||
-d Mattermost.Desktop \
|
||||
-n Mattermost \
|
||||
-i mattermost-desktop \
|
||||
-c "Network;InstantMessaging;" \
|
||||
-e "MimeType=x-scheme-handler/mattermost;" -e "StartupWMClass=Mattermost.Desktop"
|
||||
|
||||
einstalldocs
|
||||
}
|
||||
Reference in New Issue
Block a user