media-video/subliminal: verbump to 2.0_rc1

Currently masked due to unsatisfied >=dev-python/rarfile-2.7 dependency.
See Gentoo bug 582500.

Yes, I've tested with =dev-python/rarfile-2.6 and it doesn't work.

Package-Manager: portage-2.2.28

Signed-off-by: Ian Delaney <idella4@gentoo.org>

media-video/subliminal/Manifest

@@ -1 +1,2 @@
 DIST subliminal-1.1.1-r1.tar.gz 4117531 SHA256 fd02eec1206ab1ef0ce83b0e051b3e029d90348f7a06461b9b6cdc681cea7de6 SHA512 b00bb34def5982041b6eec1acba84b0c297ea1b909dc0b9fe7c290c20f0b00e17e19a847987f549a07e5edfe0fee92913f00396cb8abe26c1f86927e027bccf1 WHIRLPOOL 0d95103c6cca1d50d05b3cf3ae113fadf0a294569cac9e55c549357d16f7c77ce408e3914e2a2b9e3a837659924bd1ff47db4f3459c42b4892b823d0fcf87cce
+DIST subliminal-2.0_rc1.tar.gz 4391496 SHA256 f5782e86834d35dc3658ed8002de380060c49a21b5445c5d3894c0ff46ae2450 SHA512 5955251baa0b527261d27eb358856a2353efe938440877877775f59814429609dd62c9b87df28e515e80866063657adc3c4d0d63e09ffe0c71e4502a4e490df8 WHIRLPOOL f1c90375394827a768302d06a181c763cdcb5178e770ae815efcbee34dcbc2500a07b77fc3421a05e3d15610f7cc7505011124201521bcbd5ee521750073cef2

media-video/subliminal/subliminal-2.0_rc1.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4} )
+
+inherit distutils-r1
+
+MY_PV="${PV/_/-}"
+
+DESCRIPTION="Python library to search and download subtitles"
+HOMEPAGE="https://github.com/Diaoul/subliminal https://pypi.python.org/pypi/subliminal"
+SRC_URI="https://github.com/Diaoul/${PN}/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+RDEPEND="
+	>=dev-python/guessit-2.0.1[${PYTHON_USEDEP}]
+	>=dev-python/babelfish-0.5.2[${PYTHON_USEDEP}]
+	>=dev-python/enzyme-0.4.1[${PYTHON_USEDEP}]
+	>=dev-python/beautifulsoup-4.2.0:4[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.0.1[${PYTHON_USEDEP}]
+	>=dev-python/click-4.0[${PYTHON_USEDEP}]
+	>=dev-python/dogpile-cache-0.5.4[${PYTHON_USEDEP}]
+	>=dev-python/stevedore-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/chardet-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/pysrt-1.0.1[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	>=dev-python/appdirs-1.3[${PYTHON_USEDEP}]
+	>=dev-python/rarfile-2.7[compressed,${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	virtual/python-futures[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}
+	test? (
+		>=dev-python/vcrpy-1.6.1[${PYTHON_USEDEP}]
+		dev-python/pytest-cov[${PYTHON_USEDEP}]
+		dev-python/pytest-runner[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/sympy[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep 'dev-python/mock[${PYTHON_USEDEP}]' python2_7)
+	)
+"
+
+# Tests require network and severely broken too.
+RESTRICT=test
+
+S="${WORKDIR}/${PN}-${MY_PV}"
+
+python_prepare_all() {
+	# Disable code checkers as they require unavailable dependencies.
+	sed -i -e 's/--\(pep8\|flakes\)//g' pytest.ini || die
+	sed -i -e "s/'pytest-\(pep8\|flakes\)',//g" setup.py || die
+
+	# Disable unconditional dependency on dev-python/pytest-runner.
+	sed -i -e "s|'pytest-runner'||g" setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	esetup.py test
+}