games-board/four-in-a-row: update EAPI 7 -> 8

Closes: https://github.com/gentoo/gentoo/pull/42531
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

games-board/four-in-a-row/four-in-a-row-3.38.1-r1.ebuild

@@ -0,0 +1,46 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit gnome.org gnome2-utils meson vala xdg
+
+DESCRIPTION="Make lines of the same color to win"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/four-in-a-row"
+
+# Code and most themes are GPL-3+, CC-BY-SA-3.0 is user help license in v3.32.0
+LICENSE="GPL-3+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~riscv ~x86"
+
+RDEPEND="
+	>=dev-libs/glib-2.40.0:2
+	>=media-libs/gsound-1.0.2
+	>=x11-libs/gtk+-3.24.0:3
+	>=gnome-base/librsvg-2.32.0
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	$(vala_depend)
+	media-libs/gsound[vala]
+	gnome-base/librsvg[vala]
+"
+
+src_prepare() {
+	default
+	vala_setup
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}