media-sound/pithos: add 1.6.0

Closes: https://bugs.gentoo.org/887353
Signed-off-by: Pacho Ramos <pacho@gentoo.org>
This commit is contained in:
Pacho Ramos
2023-01-28 14:28:50 +01:00
parent 4579b7844a
commit ca752ff15b
2 changed files with 70 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST pithos-1.5.1.tar.gz 123504 BLAKE2B fc7cd51fd773989b5734d7bfcea674c622b3c9e5072d8ae65ed724476a025802f08916c533ea6c338e748aaf5fcce595ff352b0bae6c72dc074de2afaddbb737 SHA512 43841194d0a3c3df9dd98b819c8a1e30862ebd49aad8ba4f92e91cc7e680fba97159b70748f4042737d5e399bda64cd16d6e9f6d0e29136350c78be57474442e
DIST pithos-1.6.0.tar.gz 122025 BLAKE2B c621fe58998790f0eb0159d29c40ac4abf2feff2be790c12008be86387bf628b170e3256c2f3ac83e9b2be254d96d4aa7e3e56ac780b0d59a446d0e158d96d15 SHA512 9e7b1d1456a769882a58639bf93194ec0228d21b7b7d1404224346016532620bb862e7d79a2c741d8ef44238c22741e4fd67bc22eadc8d207818a0ece33411ab
+69
View File
@@ -0,0 +1,69 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{9..11} )
inherit xdg meson gnome2-utils virtualx python-r1
SRC_URI="https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
DESCRIPTION="Pandora.com client for the GNOME desktop"
HOMEPAGE="https://pithos.github.io/"
LICENSE="GPL-3"
SLOT="0"
KEYWORDS="~amd64"
IUSE="appindicator +keybinder libnotify test"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
RDEPEND="
${PYTHON_DEPS}
dev-python/pygobject[${PYTHON_USEDEP}]
app-crypt/libsecret[introspection]
dev-libs/appstream-glib[introspection]
dev-python/dbus-python[${PYTHON_USEDEP}]
dev-python/pylast[${PYTHON_USEDEP}]
media-libs/gstreamer:1.0[introspection]
media-plugins/gst-plugins-meta:1.0[aac,http,mp3]
x11-libs/gtk+:3[introspection]
x11-libs/pango[introspection]
x11-themes/gnome-icon-theme-symbolic
appindicator? ( dev-libs/libdbusmenu[gtk3,introspection] )
keybinder? ( dev-libs/keybinder:3[introspection] )
libnotify? ( x11-libs/libnotify[introspection] )
"
BDEPEND="
virtual/pkgconfig
test? (
${RDEPEND}
dev-libs/glib:2
dev-util/desktop-file-utils
)
"
src_configure() {
python_foreach_impl meson_src_configure
}
src_compile() {
python_foreach_impl meson_src_compile
}
src_test() {
virtx python_foreach_impl meson_src_test
}
src_install() {
python_foreach_impl meson_src_install
einstalldocs
}
pkg_postinst() {
gnome2_schemas_update
xdg_pkg_postinst
}
pkg_postrm() {
gnome2_schemas_update
xdg_pkg_postrm
}