mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-24 04:59:14 -07:00
app-i18n/ibus: version bump, 1.5.21
Package-Manager: Portage-2.3.76, Repoman-2.3.17 Signed-off-by: Yixun Lan <dlan@gentoo.org>
This commit is contained in:
Yixun Lan
@@ -1,3 +1,4 @@
|
||||
DIST ibus-1.5.18.tar.gz 2760121 BLAKE2B dfcf549362ac9ac0cb9adb9cedc3fd7146877a42e0e086ad7be18ccb6239868ed940d2c371d83c2e2706c7120702af0bcb0106da60889f0b3d5857b8929b9165 SHA512 34519c3464eaf2cac3320e1568fc76f4edb281afa70f335c015b828ff4e86b3224d77b95cdc0b2e76e42459c54b1044264ff226963fe739dd553ac7326d2f2d3
|
||||
DIST ibus-1.5.19.tar.gz 2842274 BLAKE2B a5aea4770c1c0a58a9e0b1aa26f47a8ab9eb5060a0c06179663984c5b531464ff4575a8ece2f2ee2122f777ca615296c1e46ad4833c68ba2da038f2b85dea374 SHA512 ddcd464c9afb6d081df1cfac65069506877eb4818c3ba5594bcf76f3c6795ef6c17177a778dc89b2ef69d10d87297aa12c8e04f156b750e500b51b32787bd9fc
|
||||
DIST ibus-1.5.20.tar.gz 3393487 BLAKE2B 0ed930cbadf7ecf9fa82ee2c0e2a8aa8cfb25a8dc1a2e2ffef0d4f894df31f879f08d7ed14508736836545cbc25b929707939c3b0ea53f2b44ba7489d6dc80ed SHA512 2bbcc19742882fa55d9c8704251f133c5be9f36a93cf52d70c460a4713419868deb634f965e67c1d5c45b615de388b92c0fbb863b118a546fbb89370a38eb77b
|
||||
DIST ibus-1.5.21.tar.gz 3463069 BLAKE2B 75b9e7cc4d84b69941d53321da1fe63ad911740a36ed51c7fceaa2a7bc30f6ae39d3f575b4b5fc4268d7c3b3e1c0bae11881dd7a8b7bd441ecf89c83c7279858 SHA512 c7c06e13e78fb4d4d26ce8975b6db4f7914efb325a903999a82197229e13d5ebb4afc876ef67e1d86db58f08c16350dc095aaea050b2f69c2bfc4c452adc5331
|
||||
|
||||
180
app-i18n/ibus/ibus-1.5.21.ebuild
Normal file
180
app-i18n/ibus/ibus-1.5.21.ebuild
Normal file
@@ -0,0 +1,180 @@
|
||||
# Copyright 1999-2019 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=6
|
||||
PYTHON_COMPAT=( python{2_7,3_5,3_6,3_7} )
|
||||
VALA_MIN_API_VERSION="0.34"
|
||||
VALA_USE_DEPEND="vapigen"
|
||||
|
||||
inherit autotools bash-completion-r1 gnome2-utils python-r1 vala virtualx xdg-utils
|
||||
|
||||
DESCRIPTION="Intelligent Input Bus for Linux / Unix OS"
|
||||
HOMEPAGE="https://github.com/ibus/ibus/wiki"
|
||||
SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV}/${P}.tar.gz"
|
||||
|
||||
LICENSE="LGPL-2.1"
|
||||
SLOT="0"
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
|
||||
IUSE="+X +emoji gconf +gtk +gtk2 +introspection kde nls +python test +unicode vala wayland"
|
||||
REQUIRED_USE="emoji? ( gtk )
|
||||
gtk2? ( gtk )
|
||||
kde? ( gtk )
|
||||
python? (
|
||||
${PYTHON_REQUIRED_USE}
|
||||
introspection
|
||||
)
|
||||
test? ( gtk )
|
||||
vala? ( introspection )"
|
||||
|
||||
CDEPEND="app-text/iso-codes
|
||||
dev-libs/glib:2
|
||||
gnome-base/dconf
|
||||
gnome-base/librsvg:2
|
||||
sys-apps/dbus[X?]
|
||||
X? (
|
||||
x11-libs/libX11
|
||||
!gtk? ( x11-libs/gtk+:2 )
|
||||
)
|
||||
gconf? ( gnome-base/gconf:2 )
|
||||
gtk? (
|
||||
x11-libs/gtk+:3
|
||||
x11-libs/libX11
|
||||
x11-libs/libXi
|
||||
gtk2? ( x11-libs/gtk+:2 )
|
||||
)
|
||||
introspection? ( dev-libs/gobject-introspection )
|
||||
kde? ( dev-qt/qtgui:5 )
|
||||
nls? ( virtual/libintl )
|
||||
python? (
|
||||
${PYTHON_DEPS}
|
||||
dev-python/pygobject:3[${PYTHON_USEDEP}]
|
||||
)
|
||||
wayland? (
|
||||
dev-libs/wayland
|
||||
x11-libs/libxkbcommon
|
||||
)"
|
||||
RDEPEND="${CDEPEND}
|
||||
python? (
|
||||
gtk? (
|
||||
x11-libs/gtk+:3[introspection]
|
||||
)
|
||||
)"
|
||||
DEPEND="${CDEPEND}
|
||||
$(vala_depend)
|
||||
dev-util/glib-utils
|
||||
virtual/pkgconfig
|
||||
emoji? (
|
||||
app-i18n/unicode-cldr
|
||||
app-i18n/unicode-emoji
|
||||
)
|
||||
nls? ( sys-devel/gettext )
|
||||
unicode? ( app-i18n/unicode-data )"
|
||||
|
||||
src_prepare() {
|
||||
vala_src_prepare --ignore-use
|
||||
sed -i "/UCD_DIR=/s/\$with_emoji_annotation_dir/\$with_ucd_dir/" configure.ac
|
||||
if ! has_version 'x11-libs/gtk+:3[wayland]'; then
|
||||
touch ui/gtk3/panelbinding.vala
|
||||
fi
|
||||
if ! use emoji; then
|
||||
touch \
|
||||
tools/main.vala \
|
||||
ui/gtk3/panel.vala
|
||||
fi
|
||||
if ! use kde; then
|
||||
touch ui/gtk3/panel.vala
|
||||
fi
|
||||
|
||||
# for multiple Python implementations
|
||||
sed -i "s/^\(PYGOBJECT_DIR =\).*/\1/" bindings/Makefile.am
|
||||
# fix for parallel install
|
||||
sed -i "/^if ENABLE_PYTHON2/,/^endif/d" bindings/pygobject/Makefile.am
|
||||
# require user interaction
|
||||
sed -i "/^TESTS += ibus-\(compose\|keypress\)/d" src/tests/Makefile.am
|
||||
|
||||
sed -i "/^bash_completion/d" tools/Makefile.am
|
||||
|
||||
default
|
||||
eautoreconf
|
||||
xdg_environment_reset
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
local unicodedir="${EPREFIX}"/usr/share/unicode
|
||||
local python_conf=()
|
||||
if use python; then
|
||||
python_setup
|
||||
python_conf+=(
|
||||
$(use_enable gtk setup)
|
||||
--with-python=${EPYTHON}
|
||||
)
|
||||
else
|
||||
python_conf+=( --disable-setup )
|
||||
fi
|
||||
|
||||
econf \
|
||||
$(use_enable X xim) \
|
||||
$(use_enable emoji emoji-dict) \
|
||||
$(use_with emoji unicode-emoji-dir "${unicodedir}"/emoji) \
|
||||
$(use_with emoji emoji-annotation-dir "${unicodedir}"/cldr/common/annotations) \
|
||||
$(use_enable gconf) \
|
||||
$(use_enable gtk gtk3) \
|
||||
$(use_enable gtk ui) \
|
||||
$(use_enable gtk2) \
|
||||
$(use_enable introspection) \
|
||||
$(use_enable kde appindicator) \
|
||||
$(use_enable nls) \
|
||||
$(use_enable test tests) \
|
||||
$(use_enable unicode unicode-dict) \
|
||||
$(use_with unicode ucd-dir "${EPREFIX}/usr/share/unicode-data") \
|
||||
$(use_enable vala) \
|
||||
$(use_enable wayland) \
|
||||
"${python_conf[@]}"
|
||||
}
|
||||
|
||||
src_test() {
|
||||
unset DBUS_SESSION_BUS_ADDRESS
|
||||
virtx emake -j1 check
|
||||
}
|
||||
|
||||
src_install() {
|
||||
default
|
||||
find "${ED}" -name '*.la' -delete || die
|
||||
|
||||
if use python; then
|
||||
python_install() {
|
||||
emake -C bindings/pygobject \
|
||||
pyoverridesdir="$(${EPYTHON} -c 'import gi; print(gi._overridesdir)')" \
|
||||
DESTDIR="${D}" \
|
||||
install
|
||||
}
|
||||
python_foreach_impl python_install
|
||||
fi
|
||||
|
||||
keepdir /usr/share/ibus/engine
|
||||
|
||||
newbashcomp tools/${PN}.bash ${PN}
|
||||
|
||||
insinto /etc/X11/xinit/xinput.d
|
||||
newins xinput-${PN} ${PN}.conf
|
||||
}
|
||||
|
||||
pkg_preinst() {
|
||||
use gconf && gnome2_gconf_savelist
|
||||
}
|
||||
|
||||
pkg_postinst() {
|
||||
use gconf && gnome2_gconf_install
|
||||
use gtk && gnome2_query_immodules_gtk3
|
||||
use gtk2 && gnome2_query_immodules_gtk2
|
||||
gnome2_icon_cache_update
|
||||
gnome2_schemas_update
|
||||
dconf update
|
||||
}
|
||||
|
||||
pkg_postrm() {
|
||||
use gtk && gnome2_query_immodules_gtk3
|
||||
use gtk2 && gnome2_query_immodules_gtk2
|
||||
gnome2_icon_cache_update
|
||||
gnome2_schemas_update
|
||||
}
|
||||
Reference in New Issue
Block a user