www-plugins/lightspark: Add a fresh snapshot

www-plugins/lightspark/Manifest

@@ -1 +1,2 @@
 DIST lightspark-0.7.2_p20150318.tar.gz 1039961 SHA256 92e4fa23e9760ebc73efd269a373c7e566eb1550ccf1c7cc7cff58b0d53d048a SHA512 2deb55a9ab7f00d0469b8fd5b053f43155d63c12f4b40bd40d6aa802501b5c7d4d3fe5d442f6ddb67eb1f592d48ccd1490b92e738359e78c162a39eb1605f9a5 WHIRLPOOL 72b471f193ffeba8e2078cad35917eac2d5c8d399cc18a177c1da0a88f85506025f28c86cb22a4dac6dd92feb0a32bc202c60cfe8ca334407f1d1fa6ba2f305f
+DIST lightspark-0.7.2_p20160107.tar.gz 1803064 SHA256 83b58db86e466e9a3acc33c7c1bbff284edb3f7fef377a3397ac26ac06cac22f SHA512 937352c8d428579a9ac89a45724db2beb624eba874da59d684e07d9d306305d85937f4b2e692c56750a1b5e6ca485e05d9997409d3bc934fab209124cd471601 WHIRLPOOL 268f2a95758def3fb722daa6580e6c4ff5577eacdc27e82005ce7e0b51d55ae78fbc6ae5c1d839b4b21848a0d2a61b0b023f4741487fc042450a7a20bfee01bb

www-plugins/lightspark/lightspark-0.7.2_p20160107.ebuild

@@ -0,0 +1,103 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+inherit cmake-utils nsplugins vcs-snapshot toolchain-funcs
+
+DESCRIPTION="High performance flash player"
+HOMEPAGE="http://lightspark.github.io/"
+SRC_URI="https://github.com/lightspark/lightspark/archive/308241eb55c5379765033e60f28dfdd956c7abcd.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="cpu_flags_x86_sse2 curl ffmpeg gles libav nsplugin ppapi profile rtmp"
+
+# Note: code-wise llvm-4.0 is fine but due to CMake bug it can't work:
+# https://gitlab.kitware.com/cmake/cmake/issues/16606
+RDEPEND="app-arch/xz-utils:0=
+	dev-cpp/glibmm:2=
+	>=dev-libs/boost-1.42:0=
+	dev-libs/glib:2=
+	dev-libs/libpcre:3=[cxx]
+	media-fonts/liberation-fonts
+	media-libs/freetype:2=
+	media-libs/libpng:0=
+	media-libs/libsdl2:0=
+	media-libs/sdl2-mixer:0=
+	>=sys-devel/gcc-4.6.0:*[cxx]
+	<sys-devel/llvm-4:0=
+	>=sys-devel/llvm-3.4:0=
+	sys-libs/zlib:0=
+	x11-libs/cairo:0=
+	x11-libs/gtk+:2=
+	x11-libs/libX11:0=
+	x11-libs/pango:0=
+	virtual/jpeg:0=
+	curl? ( net-misc/curl:0= )
+	ffmpeg? (
+		libav? ( media-video/libav:0= )
+		!libav? ( media-video/ffmpeg:0= )
+	)
+	gles? ( media-libs/mesa:0=[gles2] )
+	!gles? (
+		>=media-libs/glew-1.5.3:0=
+		virtual/opengl:0=
+	)
+	rtmp? ( media-video/rtmpdump:0= )"
+DEPEND="${RDEPEND}
+	amd64? ( dev-lang/nasm )
+	x86? ( dev-lang/nasm )
+	virtual/pkgconfig"
+
+S=${WORKDIR}/${P/_rc*/}
+
+pkg_pretend() {
+	if [[ ${MERGE_TYPE} != binary ]]; then
+		if tc-is-gcc && [[ $(gcc-major-version) == 4 && $(gcc-minor-version) -lt 6 || $(gcc-major-version) -lt 4 ]] ; then
+			eerror "You need at least sys-devel/gcc-4.6.0"
+			die "You need at least sys-devel/gcc-4.6.0"
+		fi
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_CURL=$(usex curl)
+		-DENABLE_GLES2=$(usex gles)
+		-DENABLE_LIBAVCODEC=$(usex ffmpeg)
+		-DENABLE_RTMP=$(usex rtmp)
+
+		-DENABLE_MEMORY_USAGE_PROFILING=$(usex profile)
+		-DENABLE_PROFILING=$(usex profile)
+		-DENABLE_SSE2=$(usex cpu_flags_x86_sse2)
+
+		-DCOMPILE_PLUGIN=$(usex nsplugin)
+		-DPLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/${PN}/plugins
+		# TODO: install /etc/chromium file? block adobe-flash?
+		-DCOMPILE_PPAPI_PLUGIN=$(usex ppapi)
+		-DPPAPI_PLUGIN_DIRECTORY="${EPREFIX}"/usr/$(get_libdir)/chromium-browser/${PN}
+	)
+
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use nsplugin && inst_plugin /usr/$(get_libdir)/${PN}/plugins/liblightsparkplugin.so
+}
+
+pkg_postinst() {
+	if use nsplugin && ! has_version www-plugins/gnash; then
+		elog "Lightspark now supports gnash fallback for its browser plugin."
+		elog "Install www-plugins/gnash to take advantage of it."
+	fi
+	if use nsplugin && has_version "www-plugins/gnash[nsplugin]"; then
+		elog "Having two plugins installed for the same MIME type may confuse"
+		elog "Mozilla based browsers. It is recommended to disable the nsplugin"
+		elog "USE flag for either gnash or lightspark. For details, see"
+		elog "https://bugzilla.mozilla.org/show_bug.cgi?id=581848"
+	fi
+}

www-plugins/lightspark/lightspark-9999.ebuild

@@ -27,7 +27,7 @@ RDEPEND="app-arch/xz-utils:0=
 	media-libs/libpng:0=
 	media-libs/libsdl2:0=
 	media-libs/sdl2-mixer:0=
-	>=sys-devel/gcc-4.6.0[cxx]
+	>=sys-devel/gcc-4.6.0:*[cxx]
 	<sys-devel/llvm-4:0=
 	>=sys-devel/llvm-3.4:0=
 	sys-libs/zlib:0=