app-misc/kanatest: port to EAPI 8

Signed-off-by: David Seifert <soap@gentoo.org>

app-misc/kanatest/files/kanatest-0.4.8-desktop-QA.patch

@@ -0,0 +1,16 @@
+--- a/data/kanatest.desktop
++++ b/data/kanatest.desktop
+@@ -1,11 +1,10 @@
+ [Desktop Entry]
+-Encoding=UTF-8
+ Name=Hiragana and Katakana Test
+ Comment=Hiragana and Katakana drill tool
+ Exec=kanatest
+-Icon=kanatest.png
++Icon=kanatest
+ Terminal=false
+ Type=Application
+ StartupNotify=true
+ X-Desktop-File-Install-Version=0.10
+-Categories=Game;Application;X-Fedora;
++Categories=Game;X-Fedora;

app-misc/kanatest/kanatest-0.4.8.ebuild

@@ -1,48 +1,37 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=8
 
-inherit autotools epatch gnome2-utils
+inherit autotools xdg
 
 DESCRIPTION="Visual flashcard tool for memorizing the Japanese Hiragana and Katakana alphabet"
-HOMEPAGE="http://www.clayo.org/kanatest"
-SRC_URI="http://www.clayo.org/${PN}/${P}.tar.gz"
+HOMEPAGE="https://www.clayo.org/kanatest"
+SRC_URI="https://www.clayo.org/${PN}/${P}.tar.gz"
 
 LICENSE="GPL-2 GPL-2+"
 SLOT="0"
 KEYWORDS="amd64 ppc ppc64 x86"
 
-RDEPEND=">=x11-libs/gtk+-2.12:2=
+RDEPEND="
+	x11-libs/gtk+:2
 	dev-libs/libxml2:="
-DEPEND="${RDEPEND}
-	virtual/pkgconfig"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
 
-DOCS=( AUTHORS TRANSLATORS ChangeLog README )
+PATCHES=(
+	"${FILESDIR}"/${P}+gtk-2.22.patch
+	"${FILESDIR}"/${P}-autoconf.patch
+	"${FILESDIR}"/${P}-cflags.patch
+	"${FILESDIR}"/${P}-desktop-QA.patch
+)
 
 src_prepare() {
-	epatch \
-		"${FILESDIR}"/${P}+gtk-2.22.patch \
-		"${FILESDIR}"/${P}-autoconf.patch \
-		"${FILESDIR}"/${P}-cflags.patch
-
-	sed -i \
-		-e '/Encoding/d' \
-		-e '/^Categories/s:Application;::' \
-		-e '/^Icon/s:.png::' \
-		data/${PN}.desktop || die
-
+	default
 	eautoreconf
 }
 
-pkg_preinst() {
-	gnome2_icon_savelist
-}
-
-pkg_postinst() {
-	gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-	gnome2_icon_cache_update
+src_install() {
+	default
+	dodoc TRANSLATORS
 }