sys-apps/s6: add 2.13.0.0

Signed-off-by: Petr Vaněk <arkamar@gentoo.org>
This commit is contained in:
Petr Vaněk
2024-06-14 15:29:57 +02:00
parent 2a2e7dcf62
commit c9c6cb2bb5
2 changed files with 59 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST s6-2.12.0.4.tar.gz 255314 BLAKE2B 4a7da37affdc2d0651da905fdfbffe897709cc6f2a4a36453f0a87c88da66adb307805b9f8c850813186ce51c18ed07b8a95aa34a8a266a5a24b3b8646b19485 SHA512 dfdb9c0189177762a89d1f47e1d6b0a82bba5554baef4fa899b1c0a85c192d5e1dac2b929173d750df3707f0d699b28591f1eab3e63b8791e4a51af1c65e3e56
DIST s6-2.13.0.0.tar.gz 256126 BLAKE2B 08c20a6e2268bcecea39f7066f8fcbb61723c4c0ae3772af5362b68f53ed65494b824827779d44d64d204688f03634bdd079f08def5b41a5170d88888e2fbc8a SHA512 b54d334496d79d1b845552f5e7763c536d6f253c9bb2d61802695ea1a596af918562daa230f09f4cbfc06614eff70930d0963439d7d84ec8ae0388291912ca9d
+58
View File
@@ -0,0 +1,58 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit optfeature toolchain-funcs
DESCRIPTION="skarnet.org's small and secure supervision software suite"
HOMEPAGE="https://www.skarnet.org/software/s6/"
SRC_URI="https://www.skarnet.org/software/${PN}/${P}.tar.gz"
LICENSE="ISC"
SLOT="0/$(ver_cut 1-2)"
KEYWORDS="~alpha ~amd64 ~arm ~mips ~ppc ~ppc64 ~riscv ~x86"
IUSE="+execline"
RDEPEND="
>=dev-libs/skalibs-2.14.2.0:=
execline? ( dev-lang/execline:= )
"
DEPEND="${RDEPEND}"
HTML_DOCS=( doc/. )
src_prepare() {
default
# Avoid QA warning for LDFLAGS addition
sed -i -e 's/.*-Wl,--hash-style=both$/:/' configure || die
sed -i -e '/AR := /d' -e '/RANLIB := /d' Makefile || die
}
src_configure() {
tc-export AR CC RANLIB
local myconf=(
--bindir=/bin
--dynlibdir="/$(get_libdir)"
--libdir="/usr/$(get_libdir)/${PN}"
--libexecdir=/lib/s6
--with-dynlib="/$(get_libdir)"
--with-lib="/usr/$(get_libdir)/execline"
--with-lib="/usr/$(get_libdir)/skalibs"
--with-sysdeps="/usr/$(get_libdir)/skalibs"
--enable-shared
--disable-allstatic
--disable-static
--disable-static-libc
$(use_enable execline)
)
econf "${myconf[@]}"
}
pkg_postinst() {
optfeature "man pages" app-doc/s6-man-pages
}