dev-python/rich: Bump to 13.5.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/rich/Manifest

@@ -1 +1,2 @@
 DIST rich-13.4.2.gh.tar.gz 15063000 BLAKE2B f65079440bc7d89a3ff03be01fa71e076493ae50f22ae8781be2448a7ff2769c174d6654db3a835d34720c34cd8cbecfdd6b13e3064cf7fdcade71806563309d SHA512 17052a9fb0e1d89b31a00d8a719214719891d048fd805185b2d4258c8766130f44bf2280c9567bc162f3b34d9bf2eb7d747d6a37d910c81cd53d3003b51f70bd
+DIST rich-13.5.0.gh.tar.gz 15064859 BLAKE2B 70122d319145ed8ba7ce9caa5bb79600b3b66adb897a6555c02d4d5f41ab7aa36298bbc890ce2a895a7968f0fd4c6b15b3f4772a2cf867a56cbd9755442ac0cd SHA512 0c7c62d99b15fecfc54b955e01e88eae6dc5fee7dc56749f8b9c9447425a5c32b89d19b1132c72a32204a1df0a14268e2b0797a3ba3e164dc94f72858f790a17

dev-python/rich/rich-13.5.0.ebuild

@@ -0,0 +1,65 @@
+# Copyright 2022-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=poetry
+PYTHON_COMPAT=( python3_{10..12} pypy3 )
+
+inherit distutils-r1 optfeature
+
+DESCRIPTION="Python library for rendering rich text, tables, etc. to the terminal"
+HOMEPAGE="
+	https://github.com/Textualize/rich/
+	https://pypi.org/project/rich/
+"
+SRC_URI="
+	https://github.com/Textualize/rich/archive/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/colorama[${PYTHON_USEDEP}]
+	>=dev-python/markdown-it-py-2.2.0[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.13.0[${PYTHON_USEDEP}]
+"
+
+distutils_enable_tests pytest
+
+python_test() {
+	local -x COLUMNS=80
+	local EPYTEST_DESELECT=(
+		# TODO
+		tests/test_console.py::test_size_can_fall_back_to_std_descriptors
+		tests/test_inspect.py::test_inspect_integer_with_methods_python38_and_python39
+		# pygments?
+		tests/test_syntax.py::test_python_render_simple_indent_guides
+		tests/test_syntax.py::test_python_render_line_range_indent_guides
+	)
+	# version-specific output -- the usual deal
+	case ${EPYTHON} in
+		pypy3)
+			EPYTEST_DESELECT+=(
+				# pypy3.10, to be more precise
+				tests/test_inspect.py::test_inspect_integer_with_methods_python310only
+			)
+			;;
+		python3.12)
+			EPYTEST_DESELECT+=(
+				tests/test_inspect.py::test_inspect_builtin_function_except_python311
+				tests/test_inspect.py::test_inspect_integer_with_methods_python310only
+				tests/test_inspect.py::test_inspect_integer_with_methods_python311_and_above
+				tests/test_pretty.py::test_attrs_broken
+			)
+			;;
+	esac
+	epytest -p no:pytest-qt
+}
+
+pkg_postinst() {
+	optfeature "integration with HTML widgets for Jupyter" dev-python/ipywidgets
+}