app-emulation/containers-storage: Bump to version 1.14.0

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Zac Medico <zmedico@gentoo.org>
This commit is contained in:
Zac Medico
2019-11-20 22:10:12 -08:00
parent d2541deb97
commit c9c2e92009
2 changed files with 61 additions and 0 deletions
@@ -1,2 +1,3 @@
DIST containers-storage-1.13.5.tar.gz 5968281 BLAKE2B 9690ebc87ce32a82b7560d594e192e0ad4dc9e8885797593d8c9699c13b9ddf0814773bce081edafe3050aba5d2bc470855c0717874c091b1468d52f7ad08658 SHA512 7f9f65e3141b7843a42389c78b3fbcc55a205eb661968f85942ccc2751fa6eb3fdf1199e8d244264d1b8f392e290a1770f93d5a8fd58de98f9d9a277aa39155f
DIST containers-storage-1.14.0.tar.gz 5969311 BLAKE2B 7a7a7cb02b0dde590a633f14c0f17ed9b020c352857914b142efe3b47202c94869828b442fe703ad796c6c16a4f7321bc0832ddcc2a588bcc10c25af4bddc75e SHA512 95f8804808e2603cbca0ada584c2057832d6d7a0e83cc59defea27e8a825c4db1bb1e604311d81421341e2cb324d2f1833e6498f05e71d22d86414e5206ac748
DIST github.com-pquerna-ffjson-e517b90714f7c0eabe6d2e570a5886ae077d6db6.tar.gz 103470 BLAKE2B 81f0f6ea6648997cb61723d09d456802e60a3d1eb35134c4bbc8af5943b955b1402fe2b3f8d0d4d2d0293ab256a9be66d53262d5f79ca00bf8c18ded39dc44f4 SHA512 fadca5a7bd0c0578b23281720a08c505054f3497daeee8efa36b5acafa4118feb4b8a96c4acb4c279d72ebcd50846307cfbb846a355b62f350c961f9102c93a6
@@ -0,0 +1,60 @@
# Copyright 1999-2019 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit go-module
KEYWORDS="~amd64"
DESCRIPTION="containers/storage library"
HOMEPAGE="https://github.com/containers/storage"
LICENSE="Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
SLOT="0"
IUSE="btrfs +device-mapper test"
EGO_PN="${HOMEPAGE#*//}"
EGIT_COMMIT="v${PV}"
SRC_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
RDEPEND="
btrfs? ( sys-fs/btrfs-progs )
device-mapper? ( sys-fs/lvm2:= )"
DEPEND="${RDEPEND}
dev-go/go-md2man
test? (
sys-fs/btrfs-progs
sys-fs/lvm2
sys-apps/util-linux
)"
RESTRICT="test"
S=${WORKDIR}/${P#containers-}
src_prepare() {
default
sed -e 's:GO111MODULE=off:GO111MODULE=on:' -i Makefile || die
[[ -f hack/btrfs_tag.sh ]] || die
use btrfs || { echo -e "#!/bin/sh\necho exclude_graphdriver_btrfs" > \
"hack/btrfs_tag.sh" || die; }
[[ -f hack/libdm_tag.sh ]] || die
use device-mapper || { echo -e "#!/bin/sh\necho btrfs_noversion exclude_graphdriver_devicemapper" > \
"hack/libdm_tag.sh" || die; }
}
src_compile() {
export -n GOCACHE XDG_CACHE_HOME #678856
emake containers-storage docs
}
src_install() {
dobin "${PN}"
while read -r -d ''; do
mv "${REPLY}" "${REPLY%.1}" || die
done < <(find "${S}/docs" -name '*.[[:digit:]].1' -print0)
find "${S}/docs" -name '*.[[:digit:]]' -exec doman '{}' + || die
}
src_test() {
GOPATH="${S}" unshare -m emake local-test-unit || die
}