media-libs/libsfml: version bump to 2.4.0

media-libs/libsfml/Manifest

@@ -1 +1,2 @@
 DIST libsfml-2.3.2.tar.gz 22203359 SHA256 55e7c864938e03ceb7d6d05c66f8e0dc886e632805d0ae17c222da317ba14e4c SHA512 db491b57595d567e6ce47d081fd6292bff924678fe0a61243f2dfa23df187d2c58f3bd91ea13447e49bec5f888777f338bfa461aec86d9328710623d73aeb424 WHIRLPOOL acef2cc6775ee16151cf5809e78ede2e10f5a5ae51d5d90851a17f8b73b4f599e4eb11bc16bca1db53db507906936f149a38a5670e8a81797ac5a5165d9adc83
+DIST libsfml-2.4.0.tar.gz 24578301 SHA256 712da18445a1dcbb717b010d9b19889222c95b6632c343457aa61712cbe1d76b SHA512 76d1c0421b905c2c04324e591d2c309eb9547eae3917f7df966fc5e462ef4e10198f36c5d089273ec0fcff49fd42b7cb82d166c4134ccd2308b47082d2a3354c WHIRLPOOL d6304e52e280f32a067695f386cea7921aaf203fb28c8d4ad181533130b57bda04334ec0d3bc7013673a7404e0d3e88fb19766840c669118c75544a5956e6deb

media-libs/libsfml/libsfml-2.4.0.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit cmake-utils versionator
+
+MY_P=SFML-${PV}
+
+DESCRIPTION="Simple and Fast Multimedia Library (SFML)"
+HOMEPAGE="http://www.sfml-dev.org/ https://github.com/SFML/SFML"
+SRC_URI="https://github.com/SFML/SFML/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="ZLIB"
+SLOT="0/$(get_version_component_range 1-2)"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug doc examples"
+
+RDEPEND="media-libs/freetype:2
+	media-libs/libpng:0=
+	media-libs/mesa
+	media-libs/flac
+	media-libs/libogg
+	media-libs/libvorbis
+	media-libs/openal
+	sys-libs/zlib
+	virtual/jpeg:0
+	virtual/libudev:0
+	virtual/opengl
+	x11-libs/libX11
+	x11-libs/libXrandr
+	x11-libs/libxcb
+	x11-libs/xcb-util-image"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )"
+
+DOCS="changelog.txt readme.txt"
+
+S=${WORKDIR}/${MY_P}
+
+src_prepare() {
+	local PATCHES=( "${FILESDIR}"/${PN}-2.2-no-docs.patch )
+
+	sed -i "s:DESTINATION .*:DESTINATION /usr/share/doc/${PF}:" \
+		doc/CMakeLists.txt || die
+
+	default
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DSFML_BUILD_DOC=$(usex doc)
+		-DSFML_INSTALL_PKGCONFIG_FILES=TRUE
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	insinto /usr/share/cmake/Modules
+	doins cmake/Modules/FindSFML.cmake
+
+	if use examples ; then
+		docompress -x /usr/share/doc/${PF}/examples
+		dodoc -r examples
+		find "${ED}"/usr/share/doc/${PF}/examples -name CMakeLists.txt -delete
+	fi
+}