app-admin/vault: Bump to version 1.5.5

Bug: https://bugs.gentoo.org/747157
Package-Manager: Portage-3.0.9, Repoman-3.0.2
Signed-off-by: Zac Medico <zmedico@gentoo.org>
This commit is contained in:
Zac Medico
2020-11-16 21:55:27 -08:00
parent 03b4c32163
commit c8cc4e84cb
2 changed files with 80 additions and 0 deletions
+2
View File
@@ -10,3 +10,5 @@ DIST vault-1.5.0-webui.tar.xz 1237556 BLAKE2B 2647d9733a6a20b61f5884b15dd46d0487
DIST vault-1.5.0.tar.gz 34940170 BLAKE2B cbc4b25bbb6881415c63be41970429e4413e3f70fc9aa3dfb3c54136719c7166896475d77a11d33d3e388344d863a19d63836f2ed3e20cc42db98ee2b57ba9a4 SHA512 245d5ea837f561d6c3832a0cb28d851dabe908fac2be7e53d3fd466689778d67b2cd5d9ea8c297f8daceb003c571a9768254a7e27d1fbeb1a376ac75e3c6edfb
DIST vault-1.5.2-webui.tar.xz 1242056 BLAKE2B 7ec3bf3c30170bad5e09168bd75ebccf5664a6500bbfdcbf8fab8abb2bc78472a0614e602d4521ecf998547a9e5f86f27f265324b9220db84c724f7add52b64a SHA512 04fb481936bd0ce8e60865962a5b6726f2ab82bc56d25c888f7cf7d920174cbb7916255fd38a701709c1d56a00f8216a22f884c2456c26f510075fc0ad9d41f8
DIST vault-1.5.2.tar.gz 35118624 BLAKE2B 96e9f3070ffea0d1c513004ad02558363a5c51da2e8211e664fadefc004cf65c8da6489c3a95573a9a1712ece9355966298efc122b350f9c6df79f1fd9cc2ec3 SHA512 be2c5eb530687fe199762195960fc497badbae933d57ac2861f88c05991e967e2512a5de90e3ce9ce14a094a25da18eb482da59360b6d6de594e91d75bff09c6
DIST vault-1.5.5-webui.tar.xz 1239480 BLAKE2B d1f9d98c2a6ece03f994c08c1e842343f713bdcde981c55ea75049f3cc51f4989a9187786190ff138a9c8ef264a7a9a26428f8a7d916b4b2c0554da85e48ae4d SHA512 a9516605ec262ad44cb8ae61308a70a5cfa0458b8bb2e80d49c4e28711db5a7ad18ef2bcf0e9756b9da6534f1d47ed8bcfc6c7c734042aa8d9b0e9851059fa9d
DIST vault-1.5.5.tar.gz 35123385 BLAKE2B 428d509378cd912d2ef13630a0fd4ff4df89a7144b30291cecd3c62e91b10a67210c7ae79e5459d7da5d9c635ae2634d3edd99614c40cce744d93713804c407b SHA512 de19be6b9fdaf06ce2debc7784ef1a6dff00ced7811a110b58348d61b304ed2c850d957605a47abfa0cc7568488b3b0920437ace7891a69d470e98b44c0f9fae
+78
View File
@@ -0,0 +1,78 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit fcaps go-module systemd
DESCRIPTION="A tool for managing secrets"
HOMEPAGE="https://vaultproject.io/"
VAULT_WEBUI_ARCHIVE="${P}-webui.tar.xz"
SRC_URI="https://github.com/hashicorp/vault/archive/v${PV}.tar.gz -> ${P}.tar.gz
webui? (
https://dev.gentoo.org/~zmedico/dist/${VAULT_WEBUI_ARCHIVE}
)"
LICENSE="MPL-2.0 Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
SLOT="0"
KEYWORDS="~amd64"
IUSE="+webui"
BDEPEND="dev-go/gox
>=dev-lang/go-1.14.7"
COMMON_DEPEND="acct-group/vault
acct-user/vault"
DEPEND="${COMMON_DEPEND}"
RDEPEND="${COMMON_DEPEND}"
FILECAPS=(
-m 755 'cap_ipc_lock=+ep' usr/bin/${PN}
)
RESTRICT+=" test"
src_prepare() {
default
# Avoid the need to have a git checkout
sed -e 's:^\(GIT_COMMIT=\).*:\1:' \
-e 's:^\(GIT_DIRTY=\).*:\1:' \
-e s:\'\${GIT_COMMIT}\${GIT_DIRTY}\':: \
-i scripts/build.sh || die
sed -e "/hooks/d" \
-e 's|^\([[:space:]]*\)goimports .*)|\1true|' \
-i Makefile || die
if [[ -f "${WORKDIR}/http/bindata_assetfs.go" ]]; then
mv "${WORKDIR}/http/bindata_assetfs.go" "${S}/http" ||
die "mv failed"
fi
}
src_compile() {
mkdir "${T}"/bin || die
BUILD_TAGS="$(usex webui ui '')" \
GOFLAGS="-mod=vendor" \
GOPATH="${T}" \
XC_ARCH=$(go env GOARCH) \
XC_OS=$(go env GOOS) \
XC_OSARCH=$(go env GOOS)/$(go env GOARCH) \
emake
}
src_install() {
dobin bin/${PN}
dodoc CHANGELOG.md CONTRIBUTING.md README.md
insinto /etc/${PN}.d
doins "${FILESDIR}/"*.json.example
insinto /etc/logrotate.d
newins "${FILESDIR}/${PN}.logrotated" "${PN}"
newinitd "${FILESDIR}/${PN}.initd" "${PN}"
newconfd "${FILESDIR}/${PN}.confd" "${PN}"
systemd_dounit "${FILESDIR}/${PN}.service"
keepdir /var/log/${PN}
fowners ${PN}:${PN} /var/log/${PN}
}
pkg_postinst() {
fcaps_pkg_postinst
go-module_pkg_postinst
}