app-text/sigil: add 2.5.0

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

app-text/sigil/Manifest

@@ -1,2 +1,3 @@
 DIST Sigil_User_Guide_2024.08.15.epub 12641984 BLAKE2B feaa8a4f6b64786d5cbf494a61c8726a5dd3e169ca8902348e2fee9f890ab7496b5ad018d49d6cecd65cb3d3d4a9b4a6bda019ac52c324fa92fad3e7b5dbc680 SHA512 10199c037a57f4b9ed913a8c726a58e376dcd34300a98cdd4cf934fd3a2f9a26d2f92bd85131af7ee1084824d7b082f7becdec9b0731a62f9cde712bfada5a09
 DIST sigil-2.4.2.tar.gz 19144897 BLAKE2B 517d25626fcb6c33bc8176098085c749e4c41e5186363bbc030b3be552a798647aa334a740302fd5c3db8cdfcab7f9ea8c110f6c3f312d751cbfb8d7d87b6f84 SHA512 22355b0c2fe16d2759c1948d8288936575108931a264f6859ea0f0fd52ca34870a1a4b7d7934c649970f7439f30c19192a33237b417debb0a8b7b1db6b900aa7
+DIST sigil-2.5.0.tar.gz 19346255 BLAKE2B 8ab6c543fb3950043cd0894b9865056646408a9b533d249e04cc4205292ae9cceff6d1658096a99f260b2ccb4047a0e5641c124e5cf52ae8374dafa070205717 SHA512 60fbd5f4334866c1430f5e6414433bdc808079fe4d654465d9819409ce52467009cf5295b94ee78697871928fe806a54ca2ad21a91f306ada4c641459096f191

app-text/sigil/sigil-2.5.0.ebuild

@@ -0,0 +1,86 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit xdg cmake python-single-r1
+
+DOC_VERSION="2024.08.15"
+DOC_FILE="Sigil_User_Guide_${DOC_VERSION}.epub"
+
+DESCRIPTION="Multi-platform WYSIWYG ebook editor for ePub format"
+HOMEPAGE="https://sigil-ebook.com/ https://github.com/Sigil-Ebook/Sigil"
+SRC_URI="https://github.com/Sigil-Ebook/Sigil/archive/${PV}.tar.gz -> ${P}.tar.gz
+	doc? ( https://github.com/Sigil-Ebook/sigil-user-guide/releases/download/${DOC_VERSION}/${DOC_FILE} )"
+S=${WORKDIR}/${P^}
+
+LICENSE="GPL-3+ Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="doc +plugins +system-mathjax"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="
+	${PYTHON_DEPS}
+	app-text/hunspell:=
+	dev-libs/libpcre2:=[pcre16]
+	dev-qt/qtbase:6[concurrent,cups,network,widgets,xml]
+	dev-qt/qtwebengine:6[widgets]
+	dev-qt/qtsvg:6
+	sys-libs/zlib[minizip]
+	$(python_gen_cond_dep '
+		dev-python/css-parser[${PYTHON_USEDEP}]
+		dev-python/dulwich[${PYTHON_USEDEP}]
+		dev-python/lxml[${PYTHON_USEDEP}]
+	')
+	plugins? (
+		$(python_gen_cond_dep '
+			dev-python/chardet[${PYTHON_USEDEP}]
+			dev-python/cssselect[${PYTHON_USEDEP}]
+			dev-python/html5lib[${PYTHON_USEDEP}]
+			dev-python/pillow[${PYTHON_USEDEP}]
+			dev-python/regex[${PYTHON_USEDEP}]
+			dev-python/pyqt6[${PYTHON_USEDEP}]
+			dev-python/pyqt6-webengine[${PYTHON_USEDEP}]
+		')
+		$(python_gen_impl_dep 'tk')
+	)
+	system-mathjax? ( >=dev-libs/mathjax-3 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+	dev-qt/qttools:6[linguist]
+"
+
+DOCS=( ChangeLog.txt README.md )
+
+src_configure() {
+	local mycmakeargs=(
+		-DPython3_INCLUDE_DIR="$(python_get_includedir)"
+		-DPython3_LIBRARY="$(python_get_library_path)"
+		-DPython3_EXECUTABLE="${PYTHON}"
+
+		-DUSE_VIRT_PY=0
+		-DINSTALL_BUNDLED_DICTS=0
+		-DSYSTEM_LIBS_REQUIRED=1
+		-DUSE_SYSTEM_LIBS=1
+	)
+	use system-mathjax && mycmakeargs+=( -DMATHJAX3_DIR="${EPREFIX}"/usr/share/mathjax )
+
+	cmake_src_configure
+}
+
+src_install() {
+	cmake_src_install
+	python_fix_shebang "${ED}"/usr/share/sigil/
+	python_optimize "${ED}"/usr/share/sigil/
+
+	if use doc; then
+		dodoc "${DISTDIR}/${DOC_FILE}"
+		docompress -x /usr/share/doc/${PF}/${DOC_FILE}
+	fi
+}