dev-python/nbconvert: add 6.5.3

Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

dev-python/nbconvert/Manifest

@@ -1,2 +1,3 @@
 DIST nbconvert-6.5.0.tar.gz 908377 BLAKE2B a91c6c93e9e33f90c5c7f19743e20aa6cf88e5dd29be4ee777744d96037dddd15294858776c8391d79f5436e929fb1b623a3f11f6c4cbcf60728dba2204b6e2e SHA512 4e0d26d581435525f819c05207890cc7cbeaff786a16c354f0356c9bc50111a724a92b7e15445a0cf0ebf1e1c2f0ff064a2c8722267f66dd8677ad82b5e61714
 DIST nbconvert-6.5.2.tar.gz 910454 BLAKE2B 0c80232697e1ecf31af17f10ae5ad9bcfaec89e06ab5f81c87f231f2abd585c23977d0b154363e72f6066a97d04ec96184b0d8325e5aaa399a1a9335109577bb SHA512 b955bd55bc1f69700652faae12a585230d939877551f792eebee57936a293b9b54caff5eb1bcaf996efa38c737f141069d4af2c2959b8b6318966c9020e8a2f5
+DIST nbconvert-6.5.3.tar.gz 910597 BLAKE2B a6336f2227098caf1d59aafa770fc3dd3466160329d5344dc760425cdde7ca35ad8d1e8839fe3189d1623a682a61ea3feedb7fdfdb2ec349e6ec890d873a936a SHA512 a991d8a66fe7a244d3943974d93eb13769016843d37f6c9dcf4ba84dd16511364f45b5020060bf2c10d35fe52b4df4b678d045eedc883d3156a6cb689a977525

dev-python/nbconvert/nbconvert-6.5.3.ebuild

@@ -0,0 +1,84 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit distutils-r1
+
+DESCRIPTION="Converting Jupyter Notebooks"
+HOMEPAGE="
+	https://nbconvert.readthedocs.io/
+	https://github.com/jupyter/nbconvert/
+	https://pypi.org/project/nbconvert/
+"
+SRC_URI="
+	mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+
+RDEPEND="
+	dev-python/beautifulsoup4[${PYTHON_USEDEP}]
+	dev-python/bleach[${PYTHON_USEDEP}]
+	dev-python/defusedxml[${PYTHON_USEDEP}]
+	>=dev-python/entrypoints-0.2.2[${PYTHON_USEDEP}]
+	dev-python/jinja[${PYTHON_USEDEP}]
+	dev-python/jupyter_core[${PYTHON_USEDEP}]
+	dev-python/jupyterlab_pygments[${PYTHON_USEDEP}]
+	dev-python/lxml[${PYTHON_USEDEP}]
+	>=dev-python/markupsafe-2.0[${PYTHON_USEDEP}]
+	>=dev-python/mistune-2.0.2[${PYTHON_USEDEP}]
+	dev-python/nbclient[${PYTHON_USEDEP}]
+	dev-python/nbformat[${PYTHON_USEDEP}]
+	>=dev-python/pandocfilters-1.4.1[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/tinycss2[${PYTHON_USEDEP}]
+	>=dev-python/traitlets-5.1.1[${PYTHON_USEDEP}]
+	dev-python/testpath[${PYTHON_USEDEP}]
+	www-servers/tornado[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pebble[${PYTHON_USEDEP}]
+		dev-python/ipykernel[${PYTHON_USEDEP}]
+		dev-python/ipywidgets[${PYTHON_USEDEP}]
+		>=dev-python/jupyter_client-4.2[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+PATCHES=(
+	"${FILESDIR}"/nbconvert-6.5.0-mistune-2.patch
+)
+
+src_test() {
+	mkdir -p "${HOME}/.local" || die
+	cp -r share "${HOME}/.local/" || die
+	distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# Missing pyppeteer for now
+		# TODO: Doesn't skip?
+		nbconvert/exporters/tests/test_webpdf.py
+		# Needs pyppeteer too
+		'nbconvert/tests/test_nbconvertapp.py::TestNbConvertApp::test_webpdf_with_chromium'
+	)
+
+	epytest --pyargs nbconvert
+}
+
+pkg_postinst() {
+	if ! has_version app-text/pandoc ; then
+		einfo "Pandoc is required for converting to formats other than Python,"
+		einfo "HTML, and Markdown. If you need this functionality, install"
+		einfo "app-text/pandoc."
+	fi
+}