gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-09-24 04:59:14 -07:00
Code Issues Projects Releases Wiki Activity

dev-qt/qtdeclarative: add 6.9.0

Browse Source 
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>
This commit is contained in:
Ionen Wolkens
2025-04-02 00:40:13 -04:00
parent ddb887131e
commit c787de8a03
2 changed files with 62 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-qt/qtdeclarative/Manifest
View File

@@ -2,3 +2,4 @@ DIST qtdeclarative-5.15.16-gentoo-kde-1.tar.xz 19148 BLAKE2B ebdc17253887c5b2281
DIST qtdeclarative-everywhere-opensource-src-5.15.16.tar.xz 21599596 BLAKE2B 7f69370eab4909891beb27a730e7082030715f1fcbd9faf87bdd8f3d7d3e469c56b609f58a1cf769bdb22303829d573d30fd9aaff4824456778d11ae46f7ddaa SHA512 be492d95d11ab13e13d27ca2024b5b5860d515d0b66c6d1c201bdba155841996bfdb3b813313dc75578228b6d3e661220dcc5db037624fe73d6e5e1c3ec84aa7
DIST qtdeclarative-everywhere-src-6.8.2.tar.xz 36485320 BLAKE2B 9d12d40450c6a5e6771c1e48e4c0a00d33aec269aec1050a4f1e689350d70f5208b0fc0c2fe2c0e8671989e392132ef3c7e7062483703ce5206ffdb66ebdc25c SHA512 0dbb8c96974424a18f047fe27124a3c87fb4a485094a2515aadefde92a0554b0da34fd67cff2c8ab5a3d93da7829a745a39713676702cd7470561eb776c72d95
DIST qtdeclarative-everywhere-src-6.8.3.tar.xz 36503988 BLAKE2B 5c155c9a09facc6ef10653af313a65854fa4ffff2cdc782ddc18417e94f85abafa2e2e312eda36a640131d3667c0876ab620d3faeeab0ee6838d178ef85ca83f SHA512 75c9fdc8ba26ef95ae8ff0c82b18589b74d7ff3065e86e5bd8427bc36336e569eaa22fa07863f99d0592eec0c1a69c3409c7b3941eae14361ff523c058e56084
DIST qtdeclarative-everywhere-src-6.9.0.tar.xz 36835960 BLAKE2B ec6c53ad9f1d66b7b655d92bd8a9c233ef5f67a8ee4ed8af739c5e9b237a3634677d930e1bc75aecbf62844b8290864aefdff7c7718c90ba2259a89803334d2a SHA512 51f216af71019d845b19e675d7eb8e11d9ab6a8b5f254fe31db4d0f0033272ffda053e597792447045bfc4c9e111a08d19eb4b85e1b401b0242b03b0086b2755

61
dev-qt/qtdeclarative/qtdeclarative-6.9.0.ebuild Normal file
View File

@@ -0,0 +1,61 @@
# Copyright 2021-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{10..13} )
# behaves very badly when qtdeclarative is not already installed, also
# other more minor issues (installs junk, sandbox/offscreen issues)
QT6_RESTRICT_TESTS=1
inherit python-any-r1 qt6-build
DESCRIPTION="Qt Declarative (Quick 2)"
if [[ ${QT6_BUILD_TYPE} == release ]]; then
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
fi
IUSE="accessibility +jit +network opengl qmlls +sql +ssl svg vulkan +widgets"
RDEPEND="
~dev-qt/qtbase-${PV}:6[accessibility=,gui,network=,opengl=,sql?,ssl?,vulkan=,widgets=]
qmlls? ( ~dev-qt/qtlanguageserver-${PV}:6 )
svg? ( ~dev-qt/qtsvg-${PV}:6 )
"
DEPEND="
${RDEPEND}
vulkan? ( dev-util/vulkan-headers )
"
BDEPEND="
${PYTHON_DEPS}
~dev-qt/qtshadertools-${PV}:6
"
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package qmlls Qt6LanguageServerPrivate)
$(cmake_use_find_package sql Qt6Sql)
$(cmake_use_find_package svg Qt6Svg)
$(qt_feature jit qml_jit)
$(qt_feature network qml_network)
$(qt_feature ssl qml_ssl)
)
qt6-build_src_configure
}
src_install() {
qt6-build_src_install
if [[ ! -e ${D}${QT6_LIBDIR}/libQt6QuickControls2.so.6 ]]; then #940675
eerror "${CATEGORY}/${PF} seems to have been improperly built and"
eerror "install was aborted to protect the system. Possibly(?) due"
eerror "to a rare portage ordering bug. If using portage, try:"
eerror " emerge -1 qtshadertools:6 qtdeclarative:6"
eerror "If that did not resolve the issue, please provide build.log"
eerror "on https://bugs.gentoo.org/940675"
die "aborting due to incomplete/broken build (see above)"
fi
}