sci-astronomy/kstars: 3.4.3 version bump

Package-Manager: Portage-3.0.0, Repoman-2.3.23
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

sci-astronomy/kstars/Manifest

@@ -1,2 +1,3 @@
 DIST kstars-3.3.9.tar.xz 71097252 BLAKE2B d8593be78f30de8e9ce00744f71ef23eda51bdfdd4fea1aa5b4e25605b2d45c337f66c76b8804b292c8277a768aa08d7acc1d52cb0ad955bc67a54a370e15b74 SHA512 51a8687d8f438eda2e6c079ce9bec25aa1e84b4cff697da08e91d38388e85595bea8ed06a2a8d6a8a4ce133e768e28fb5a6a0ff763514e751d693c32f91e95c6
 DIST kstars-3.4.2.tar.xz 76494596 BLAKE2B 228f4d9250ef6584e6de1164fc0fc2ba506574f34cfda4ad1347984adeeaaa4eee8e8d93cb2d8822635ad200e2df5d43ccc2cf48d2cd24449f21627de9189c9c SHA512 10e806c82b0704c6185c852c74035e7f74ef29d921df3bcde07cb161d86257e7deb4b13941294b699ed46ae5c8197a2f76dcd45599f0222139c584a626881304
+DIST kstars-3.4.3.tar.xz 77697704 BLAKE2B a64901f74952268fb05ab9ef90d4161f48ada210a0c3099218488bb0c327d29855c58f7226ac399e522abe9846fe7109dcbecbdb789d9c3afc1180448ba1fe69 SHA512 47adad28cccd749a7ac3c71df4b06d59a4bdf94bacc064fe5d658dcbe3150f2e4d13aaf23e0aedea57c64c28357452d731caaf764e8c91bc67f5469166cf7ad4

sci-astronomy/kstars/kstars-3.4.3.ebuild

@@ -0,0 +1,98 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+KFMIN=5.60.0
+QTMIN=5.12.3
+inherit ecm kde.org
+
+DESCRIPTION="Desktop Planetarium"
+HOMEPAGE="https://kde.org/applications/education/org.kde.kstars
+https://edu.kde.org/kstars/"
+
+if [[ ${KDE_BUILD_TYPE} = release ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2+ GPL-3+"
+SLOT="5"
+IUSE="fits indi +password raw wcs"
+
+REQUIRED_USE="indi? ( fits ) ${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="
+	>=dev-qt/qtdatavis3d-${QTMIN}:5
+	>=dev-qt/qtdbus-${QTMIN}:5
+	>=dev-qt/qtdeclarative-${QTMIN}:5
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtnetwork-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsql-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwebsockets-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=kde-frameworks/kauth-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kio-${KFMIN}:5
+	>=kde-frameworks/knewstuff-${KFMIN}:5
+	>=kde-frameworks/knotifications-${KFMIN}:5
+	>=kde-frameworks/knotifyconfig-${KFMIN}:5
+	>=kde-frameworks/kplotting-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	sys-libs/zlib
+	fits? ( sci-libs/cfitsio )
+	indi? (
+		>=sci-libs/indilib-1.7.5
+		sci-libs/libnova
+	)
+	password? ( dev-libs/qtkeychain:= )
+	raw? ( media-libs/libraw:= )
+	wcs? ( sci-astronomy/wcslib )
+"
+# TODO: Add back when re-enabled by upstream
+# 	opengl? (
+# 		>=dev-qt/qtopengl-${QTMIN}:5
+# 		virtual/opengl
+# 	)
+DEPEND="${COMMON_DEPEND}
+	dev-cpp/eigen:3
+	>=dev-qt/qtconcurrent-${QTMIN}:5
+"
+RDEPEND="${COMMON_DEPEND}
+	>=dev-qt/qtgraphicaleffects-${QTMIN}:5
+	>=dev-qt/qtpositioning-${QTMIN}:5
+	>=dev-qt/qtquickcontrols-${QTMIN}:5
+	>=dev-qt/qtquickcontrols2-${QTMIN}:5
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DFETCH_TRANSLATIONS=OFF
+		-DBUILD_DOC=$(usex handbook)
+		$(cmake_use_find_package fits CFitsio)
+		$(cmake_use_find_package indi INDI)
+		$(cmake_use_find_package indi Nova)
+		$(cmake_use_find_package password Qt5Keychain)
+		$(cmake_use_find_package raw LibRaw)
+		$(cmake_use_find_package wcs WCSLIB)
+	)
+
+	ecm_src_configure
+}
+
+pkg_postinst() {
+	ecm_pkg_postinst
+
+	if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version "x11-misc/xplanet" ; then
+		elog "${PN} has optional runtime support for x11-misc/xplanet"
+	fi
+	# same for AstrometryNet, which is not packaged.
+}