dev-python/magic-wormhole: Bump to 0.20.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/magic-wormhole/Manifest

@@ -1 +1,2 @@
 DIST magic_wormhole-0.19.2.tar.gz 304264 BLAKE2B 101563e2e21773d6ef49d81db83eb042da3122bad4c33e3ffda73c734c80d8623a5222b46efd101a6ce3028228a02025d734da92f1e818a417970ffe6106e8b4 SHA512 c73b01eb1ac32b09a6b6c527b9a9c8eece860b98cc35ee8e1ca9d908fca553b60ca6be6db755c6253e66a3d8a9f2dcf547722129020c5f5b7bd8a443fe15805e
+DIST magic_wormhole-0.20.0.tar.gz 302626 BLAKE2B a32ac4b95da7dae168239433a50bc79b1be1a977c6c761e68516ef5dd00590cb9d02c0f2cbf5ccb73e8bed18da180496d0479390ca16c7f68f3f441f9c26c6d2 SHA512 8a0455474183f1e0561e3638dc7ec067d277b7539d50679b4027c47a84f1547ee83b2925f10e988d0a75c448567356b67ff86fca558a90940e2d8f9cb358bf86

dev-python/magic-wormhole/magic-wormhole-0.20.0.ebuild

@@ -0,0 +1,69 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi shell-completion
+
+DESCRIPTION="Get Things From One Computer To Another, Safely"
+HOMEPAGE="
+	https://magic-wormhole.readthedocs.io/en/latest/
+	https://github.com/magic-wormhole/magic-wormhole/
+	https://pypi.org/project/magic-wormhole/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+RDEPEND="
+	>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
+	>=dev-python/autobahn-0.14.1[${PYTHON_USEDEP}]
+	dev-python/automat[${PYTHON_USEDEP}]
+	dev-python/click[${PYTHON_USEDEP}]
+	dev-python/cryptography[${PYTHON_USEDEP}]
+	dev-python/humanize[${PYTHON_USEDEP}]
+	>=dev-python/iterable-io-1.0.0[${PYTHON_USEDEP}]
+	dev-python/noiseprotocol[${PYTHON_USEDEP}]
+	dev-python/pynacl[${PYTHON_USEDEP}]
+	>=dev-python/qrcode-8.0[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	~dev-python/spake2-0.9[${PYTHON_USEDEP}]
+	>=dev-python/tqdm-4.13.0[${PYTHON_USEDEP}]
+	dev-python/twisted[ssl,${PYTHON_USEDEP}]
+	>=dev-python/txtorcon-18.0.2[${PYTHON_USEDEP}]
+	>=dev-python/zipstream-ng-1.7.1[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	dev-python/versioneer[${PYTHON_USEDEP}]
+	test? (
+		dev-python/magic-wormhole-mailbox-server[${PYTHON_USEDEP}]
+		dev-python/magic-wormhole-transit-relay[${PYTHON_USEDEP}]
+		dev-python/pytest-twisted[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	distutils-r1_src_prepare
+	rm versioneer.py || die
+}
+
+python_test() {
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+	epytest -p pytest_twisted
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	newbashcomp "${ED}/usr/wormhole_complete.bash" wormhole
+	newfishcomp "${ED}/usr/wormhole_complete.fish" wormhole.fish
+	newzshcomp "${ED}/usr/wormhole_complete.zsh" _wormhole
+	rm "${ED}/usr"/wormhole_complete* || die
+}