dev-python/b2sdk: new package, add 2.9.4

As noted in the bug, can't add it as a dep to duplicity (though perhaps we
could really; would be worth maybe talking more about optional runtime deps
vs Python, as optfeature isn't perfect for this as it doesn't guarantee matching
impls, but that's a discussion for another day), just an optfeature
at some point.

Closes: https://bugs.gentoo.org/657466
Signed-off-by: Sam James <sam@gentoo.org>

dev-python/b2sdk/Manifest

@@ -0,0 +1 @@
+DIST b2sdk-2.9.4.gh.tar.gz 412163 BLAKE2B 8bb3273ff9bc73de76466845e165f3d9b16f1cff19ea88758162cfa21320e8670bb816e7ad21190e54a450c6088d749388c3864f206a6ed31c07a7f1c2a599f1 SHA512 b14d373ea5d68406660a8c461bc5e9c31ee0ef672fc80d79d21b3a64b1ac1c56366c58f330d7b57e4b376b7b87bb1c84efed1e73b2e8a958ec725e8bdb9342f3

dev-python/b2sdk/b2sdk-2.9.4.ebuild

@@ -0,0 +1,46 @@
+# Copyright 2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=pdm-backend
+PYTHON_COMPAT=( python3_{11..13} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="B2 Python SDK"
+HOMEPAGE="
+	https://github.com/Backblaze/b2-sdk-python
+	https://pypi.org/project/b2sdk/
+"
+# No tests in sdist
+SRC_URI="https://github.com/Backblaze/b2-sdk-python/archive/refs/tags/v${PV}.tar.gz -> ${P}.gh.tar.gz"
+S="${WORKDIR}"/b2-sdk-python-${PV}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+
+# pydantic can be used but it has a fallback
+RDEPEND="
+	dev-python/logfury[${PYTHON_USEDEP}]
+	dev-python/requests[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	test? (
+		dev-python/pytest-lazy-fixtures[${PYTHON_USEDEP}]
+		dev-python/tqdm[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_IGNORE=(
+	# Requires network access and real API keys
+	test/integration/test_bucket.py
+	test/integration/test_download.py
+	test/integration/test_file_version_attributes.py
+	test/integration/test_sync.py
+	test/integration/test_upload.py
+	test/integration/test_raw_api.py
+)
+
+distutils_enable_tests pytest

dev-python/b2sdk/metadata.xml

@@ -0,0 +1,17 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>sam@gentoo.org</email>
+		<name>Sam James</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>python@gentoo.org</email>
+		<name>Python</name>
+	</maintainer>
+	<stabilize-allarches/>
+	<upstream>
+		<remote-id type="pypi">b2sdk</remote-id>
+		<remote-id type="github">Backblaze/b2-sdk-python</remote-id>
+	</upstream>
+</pkgmetadata>