dev-python/python-neutronclient: Bump to 14.0.0

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/python-neutronclient/Manifest

@@ -1 +1,2 @@
 DIST python_neutronclient-13.0.0.tar.gz 179680 BLAKE2B 544b7d07d7062ad4634fc2dc8d4213dbb05681497fb891bb047fe05cc109e4f9aaf0e6a31ef82330348b3df30fb4b271e20cfce385b7b85a8cb454ad41c72764 SHA512 76873f4e523fd0514ee34a8b61656dd2c95b62fc19ed5d6a68462d751bf5c178e8674b1b3a4125a540de1bab5c6b97210b02c2a6164a4dbf6276183c7f087c50
+DIST python_neutronclient-14.0.0.tar.gz 165833 BLAKE2B 47eba289264f7264dc2f4217b3a2fe6364815b59735232d70e68996c6d2b4d01a0b02f2c96d8b5169046c22390f523f087a067cfef820976f1d4d68243cee6c2 SHA512 f3a1cede1bd7a36ed5a1a1af0385001261011fab39dd2c1ab076ce3783b32ffea8994b5d6ca00a72859f6a8bf5a7d2d7ba4c9d23f0bf52982b8ef54da6d93212

dev-python/python-neutronclient/python-neutronclient-14.0.0.ebuild

@@ -0,0 +1,72 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( python3_{12..14} )
+
+inherit distutils-r1 pypi
+
+DESCRIPTION="A client for the OpenStack Quantum API"
+HOMEPAGE="
+	https://opendev.org/openstack/python-neutronclient/
+	https://github.com/openstack/python-neutronclient/
+	https://pypi.org/project/python-neutronclient/
+"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+
+RDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	>=dev-python/cliff-3.4.0[${PYTHON_USEDEP}]
+	>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
+	>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
+	>=dev-python/openstacksdk-1.5.0[${PYTHON_USEDEP}]
+	>=dev-python/osc-lib-1.8.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
+	>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
+	>=dev-python/oslo-serialization-2.19.1[${PYTHON_USEDEP}]
+	>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
+	>=dev-python/keystoneauth1-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/python-keystoneclient-3.8.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	>=dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
+	test? (
+		dev-python/bandit[${PYTHON_USEDEP}]
+		dev-python/fixtures[${PYTHON_USEDEP}]
+		dev-python/oslotest[${PYTHON_USEDEP}]
+		dev-python/python-openstackclient[${PYTHON_USEDEP}]
+		dev-python/requests-mock[${PYTHON_USEDEP}]
+		dev-python/testtools[${PYTHON_USEDEP}]
+	)
+"
+
+distutils_enable_tests unittest
+
+src_prepare() {
+	# Needs osprofile
+	rm neutronclient/tests/unit/test_http.py || die
+	distutils-r1_src_prepare
+}
+
+python_test() {
+	# functional tests require cloud instance access
+	eunittest -b neutronclient.tests.unit
+}
+
+python_install() {
+	distutils-r1_python_install
+	# stupid stupid stupid
+	local SITEDIR="${D}$(python_get_sitedir)" || die
+	cd "${SITEDIR}" || die
+	local egg=( python_neutronclient*.dist-info )
+	[[ -d ${egg[0]} ]] || die "python_quantumclient*.dist-info not found"
+	ln -s "${egg[0]}" "${egg[0]/neutron/quantum}" || die
+	ln -s neutronclient quantumclient || die
+	ln -s neutron quantumclient/quantum || die
+}