dev-util/catalyst: Version bump to 3.0.9

Signed-off-by: Matt Turner <mattst88@gentoo.org>

dev-util/catalyst/Manifest

@@ -1 +1,2 @@
 DIST catalyst-3.0.8.tar.bz2 873610 BLAKE2B af6fca5dd8dea377795d1b50b942773b0cb8383e1727ba547f1511f126ad4f1494d64ca3d4b3e479664de366e8ed2f8ad8c09c206bbd213d6f95aa51ae56ea8c SHA512 b00a31d9af9b3c1d220080eb6068c924f6ca9f4d574f4805f2b833e61e0fdb79290ec6f5b190c0c7501e015068eb756ede6aea7a959d2e22cef8a055968b7203
+DIST catalyst-3.0.9.tar.bz2 873866 BLAKE2B 293a4d52c57e73269f1f82fed8ea72934a0f939b3b9d4fb9943f4971fd4155edecc6cf0170b917eba16f0125aac9861041b7e10f85f6110a35659a2f85fd3665 SHA512 c8c25ad1c76b0040bd84b491909d364306746c660afbbb8c6a074911779aabe89b60a12cc3ac5b9cd3398bdf8986b50d24d9979c3d12d2fa9de66ebf62ded309

dev-util/catalyst/catalyst-3.0.9.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+if [[ ${PV} == *9999* ]]; then
+	SRC_ECLASS="git-r3"
+	EGIT_REPO_URI="https://anongit.gentoo.org/git/proj/catalyst.git"
+	EGIT_BRANCH="master"
+else
+	SRC_URI="https://gitweb.gentoo.org/proj/catalyst.git/snapshot/${P}.tar.bz2"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~riscv ~s390 ~sh ~sparc ~x86"
+fi
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit distutils-r1 ${SRC_ECLASS}
+
+DESCRIPTION="Release metatool used for creating releases based on Gentoo Linux"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Catalyst"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="ccache doc +iso kernel_linux system-bootloader"
+
+DEPEND="
+	app-text/asciidoc
+	>=dev-python/snakeoil-0.6.5[${PYTHON_USEDEP}]
+"
+RDEPEND="
+	>=dev-python/snakeoil-0.6.5[${PYTHON_USEDEP}]
+	>=dev-python/pydecomp-0.3[${PYTHON_USEDEP}]
+	app-arch/lbzip2
+	app-crypt/shash
+	sys-fs/dosfstools
+	!kernel_FreeBSD? ( || ( app-arch/tar[xattr] app-arch/libarchive[xattr] ) )
+	kernel_FreeBSD? ( app-arch/libarchive[xattr] )
+	amd64? ( >=sys-boot/syslinux-3.72 )
+	x86? ( >=sys-boot/syslinux-3.72 )
+	ccache? ( dev-util/ccache )
+	iso? ( virtual/cdrtools )
+	kernel_linux? ( app-misc/zisofs-tools >=sys-fs/squashfs-tools-2.1 )
+"
+PDEPEND="system-bootloader? ( >=sys-apps/memtest86+-5.01-r4
+				sys-boot/grub:2
+				amd64? ( sys-boot/grub[grub_platforms_efi-32,grub_platforms_efi-64] )
+				x86? ( sys-boot/grub[grub_platforms_efi-32] )
+				sys-boot/syslinux
+				sys-boot/shim )"
+
+python_prepare_all() {
+	python_setup
+	echo VERSION="${PV}" "${PYTHON}" setup.py set_version
+	VERSION="${PV}" "${PYTHON}" setup.py set_version || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	# build the man pages and docs
+	emake
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	if use doc; then
+		dodoc files/HOWTO.html files/docbook-xsl.css
+	fi
+}