app-arch/file-roller: bump to 3.32.4 for translation updates

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio@gentoo.org>
This commit is contained in:
Mart Raudsepp
2020-02-18 14:14:19 +02:00
parent 031d98e888
commit c69d74fb24
2 changed files with 92 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST file-roller-3.32.3.tar.xz 852808 BLAKE2B 939b931d7b179cc45ca3766dd122e2242e4de22b8c15f0942c31b5f9b5e8eed9d636122445d265539f9368f86d2efc10af161aaa046b3de6be05072d2b53004b SHA512 8256995f776524772936c6d60777c6c2668a610a672788a51ed83de1ae1c131b12373d2a918658f64f004757bb8c71b03edbf0c89776fcad6d64b4fc7fdb8e49
DIST file-roller-3.32.4.tar.xz 854444 BLAKE2B 04264e64af8ab4376fa6985683b16be7fef730a4e24044f726933b885aaaa6b630f347a256b09c2ce6183d0a0a392b33b4328715bf6d19cf7128c1980f9f4792 SHA512 16b5ddbdeacf4e9e61265ecff05e8f2e0034147c67ae7355d2442f9b26098ff253d24cb34c8e686c2ac031da6acac8e1e3c8a9f978e1eb2b446b1e045babafc7
@@ -0,0 +1,91 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
inherit gnome.org gnome2-utils meson readme.gentoo-r1 xdg
DESCRIPTION="Archive manager for GNOME"
HOMEPAGE="https://wiki.gnome.org/Apps/FileRoller"
LICENSE="GPL-2+ CC-BY-SA-3.0"
SLOT="0"
IUSE="libnotify nautilus packagekit"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
# gdk-pixbuf used extensively in the source
# cairo used in eggtreemultidnd.c
# pango used in fr-window
RDEPEND="
>=app-arch/libarchive-3:=
>=dev-libs/glib-2.36:2
>=dev-libs/json-glib-0.14
>=x11-libs/gtk+-3.13.2:3
x11-libs/cairo
x11-libs/gdk-pixbuf:2
x11-libs/pango
libnotify? ( >=x11-libs/libnotify-0.4.3:= )
nautilus? ( >=gnome-base/nautilus-2.22.2 )
packagekit? ( app-admin/packagekit-base )
"
DEPEND="${RDEPEND}"
BDEPEND="
dev-util/glib-utils
dev-util/itstool
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
"
DISABLE_AUTOFORMATTING="yes"
DOC_CONTENTS="
${PN} is a frontend for several archiving utilities. If you want a
particular archive format support, see ${HOMEPAGE}
and install the relevant package. For example:
7-zip - app-arch/p7zip
ace - app-arch/unace
arj - app-arch/arj
brotli - app-arch/brotli
cpio - app-arch/cpio
deb - app-arch/dpkg
iso - app-cdr/cdrtools
jar,zip - app-arch/zip and app-arch/unzip
lha - app-arch/lha
lzop - app-arch/lzop
lz4 - app-arch/lz4
rar - app-arch/unrar or app-arch/unar
rpm - app-arch/rpm
unstuff - app-arch/stuffit
zoo - app-arch/zoo"
src_prepare() {
# File providing Gentoo package names for various archivers
cp -v "${FILESDIR}"/3.32-packages.match data/packages.match || die
xdg_src_prepare
}
src_configure() {
local emesonargs=(
-Drun-in-place=false
$(meson_use nautilus nautilus-actions)
$(meson_use libnotify notification)
$(meson_use packagekit)
-Dlibarchive=true
)
meson_src_configure
}
src_install() {
meson_src_install
readme.gentoo_create_doc
}
pkg_postinst() {
xdg_pkg_postinst
gnome2_schemas_update
readme.gentoo_print_elog
}
pkg_postrm() {
xdg_pkg_postrm
gnome2_schemas_update
}