x11-terms/st: add 0.9.3

Signed-off-by: Spencer Pavkovic <smp@nandre.com>
Part-of: https://github.com/gentoo/gentoo/pull/43992
Closes: https://github.com/gentoo/gentoo/pull/43992
Signed-off-by: Petr Vaněk <arkamar@gentoo.org>
This commit is contained in:
Spencer Pavkovic
2025-10-01 20:48:02 +02:00
committed by Petr Vaněk
parent 1e93b325aa
commit c64559b5ce
2 changed files with 76 additions and 0 deletions
+1
View File
@@ -1,2 +1,3 @@
DIST st-0.9.2.tar.gz 48381 BLAKE2B 69818e3c2c3af31ceaaa86c4b721bc9842be21005d72db801d1867c3d33ab5674bce8bd34eb194a683d49514fd5e981b079c23844a895497386c0c26c414ea3a SHA512 1ca484227189d9e92ffc1092183fdc6a162da8bb41b9c18df662212d49a9551a84c3c87784ae16f2294105776b9d58983f29396bc681e367b761610bd7071b61
DIST st-0.9.3.tar.gz 49528 BLAKE2B 95d672b8bd25f2bcda9ef7d0238fec522045e5082d5bdfda0b34ad1c67b93c1571e62f96b41f6a024ca00311d405d081a922f61604014d99708a0bdf20eb0e38 SHA512 c07303ac3447de57b72dd48f3cfd590de54267d85f8313517b625b4008de968383ced071e4c396a126d901983278b4242236ebc80f23d6838e6e7390feebc6a6
DIST st-0.9.tar.gz 48171 BLAKE2B f6713b565b785549a571b3775346351c6db79dfbb1a93e29aadd722f30e957e9f77d1644b150cd11f0993dec5accad9d825e6d6b380b4c84c5f526b6589d1b15 SHA512 8d996a68d55c63d84da9962911b076ef437842e8cd83d74672d95531dfbaea91e049430886459a99e859ec760bb3754e94bbe1f646410998725e5a8997fb70ea
+75
View File
@@ -0,0 +1,75 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit desktop savedconfig toolchain-funcs
DESCRIPTION="Simple terminal implementation for X"
HOMEPAGE="https://st.suckless.org/"
if [[ ${PV} == 9999 ]]; then
inherit git-r3
EGIT_REPO_URI="https://git.suckless.org/${PN}"
else
SRC_URI="https://dl.suckless.org/${PN}/${P}.tar.gz"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~m68k ~ppc64 ~riscv ~x86"
fi
LICENSE="MIT"
SLOT="0"
RDEPEND="
>=sys-libs/ncurses-6.0:0=
media-libs/fontconfig
x11-libs/libX11
x11-libs/libXft
~x11-terms/st-terminfo-${PV}
"
DEPEND="
${RDEPEND}
x11-base/xorg-proto
"
BDEPEND="virtual/pkgconfig"
src_prepare() {
default
sed -i \
-e "/^X11LIB/{s:/usr/X11R6/lib:/usr/$(get_libdir)/X11:}" \
-e '/^STLDFLAGS/s|= .*|= $(LDFLAGS) $(LIBS)|g' \
-e '/^X11INC/{s:/usr/X11R6/include:/usr/include/X11:}' \
config.mk || die
sed -i \
-e '/tic/d' \
Makefile || die
restore_config config.h
}
src_configure() {
sed -i \
-e "s|pkg-config|$(tc-getPKG_CONFIG)|g" \
config.mk || die
tc-export CC
}
src_install() {
emake DESTDIR="${D}" PREFIX="${EPREFIX}"/usr install
dodoc TODO
make_desktop_entry ${PN} simpleterm utilities-terminal 'System;TerminalEmulator;' ''
save_config config.h
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
elog "Please ensure a usable font is installed, like"
elog " media-fonts/corefonts"
elog " media-fonts/dejavu"
elog " media-fonts/urw-fonts"
fi
}