dev-python/flask-login: Added ebuild for v0.4.1, add PyPy3, doc

Also sort and fix dependencies, for instance unittest2 is not required
for Python >= 2.7.

Closes: https://bugs.gentoo.org/611258
Closes: https://github.com/gentoo/gentoo/pull/9043

dev-python/flask-login/Manifest

@@ -1 +1,2 @@
 DIST flask-login-0.3.2.tar.gz 38626 BLAKE2B fbcac55e4a8dc5fe78b4b5b3cb8acbe7293bfcc30ce5323ebe992c92407238198d34724179ac12e688875356e54f85f21a2870249ccafb48499df3880a6c2062 SHA512 c42af6ed7902145cc4778815f247ed88de6df7c929abe0a1f22aca0515495a54d298b2af2b74ba7d5e0ce9b453eee4c4ce03802a3e9ab531137e117e9dcdfc1b
+DIST flask-login-0.4.1.tar.gz 43679 BLAKE2B f30df1cc84289bc2dd1e59a30284d7152cee0731daf8b6e58b8203007c0ba74eb512bf9f2e41608d9656138038f5b5c752509ef5a203ef1e8bdba9182912b133 SHA512 c87a2948ac37439ddd76f3f11584bdd5910cb00e96a7400343cf4dadc5a0f9bc84d40bdc068d2e8c05bd5a510046e18473e9ad71502c5039a5f05b371ce9bb4c

dev-python/flask-login/flask-login-0.4.1.ebuild

@@ -0,0 +1,48 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+DESCRIPTION="Login session support for Flask"
+HOMEPAGE="https://pypi.org/project/Flask-Login/"
+# Should be replaced with the PyPi URI for the next release, if possible
+# See https://github.com/maxcountryman/flask-login/pull/393
+SRC_URI="https://github.com/maxcountryman/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+
+RDEPEND=">=dev-python/flask-0.10[${PYTHON_USEDEP}]"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	doc? (
+		dev-python/sphinx[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		dev-python/blinker[${PYTHON_USEDEP}]
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+		dev-python/semantic_version[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	sed -i "s/'sphinx.ext.intersphinx', //" docs/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		emake -C docs html
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	nosetests -v || die "Tests fail with ${EPYTHON}"
+}