app-emacs/citre: new package; add version 0.4.2

Signed-off-by: Maciej Barć <xgqt@gentoo.org>

app-emacs/citre/Manifest

@@ -0,0 +1 @@
+DIST citre-0.4.2.gh.tar.gz 684966 BLAKE2B 7c4672df4e6b9aec47a0c3334a2e37df516b5ac25b5d83acabd034c21ef232907c37b0330d286ba663b31710001feabdb5cad3d48521e119d4074600598a4ea9 SHA512 e105fc3cea8c1c13ded2336e14d51170ee69202cbbd00666474f61e7ce60c68b7fe753aa023f8d4f56a70d1699cb6dd041d2ac51ba2a07c93597a805c16fb6a1

app-emacs/citre/citre-0.4.2.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=9
+
+inherit elisp
+
+DESCRIPTION="Superior code reading and auto-completion with pluggable backends for GNU Emacs"
+HOMEPAGE="https://github.com/universal-ctags/citre/"
+
+if [[ "${PV}" == *9999* ]] ; then
+	inherit git-r3
+
+	EGIT_REPO_URI="https://github.com/universal-ctags/${PN}"
+else
+	SRC_URI="https://github.com/universal-ctags/${PN}/archive/refs/tags/v${PV}.tar.gz
+		-> ${P}.gh.tar.gz"
+
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-3+"
+SLOT="0"
+
+RDEPEND="
+	dev-util/global
+	dev-util/ctags
+"
+BDEPEND="
+	${RDEPEND}
+"
+
+DOCS=( CHANGELOG.md README.md )
+SITEFILE="50${PN}-gentoo.el"
+
+src_test() {
+	emake test-common
+	emake test-tags
+	emake test-global
+}
+
+src_compile() {
+	elisp_src_compile
+	elisp-make-autoload-file
+}
+
+src_install() {
+	elisp_src_install
+	dodoc -r ./docs/{developer,user}-manual/
+	docompress -x /usr/share/doc/${PF}/{developer,user}-manual/
+}

app-emacs/citre/files/50citre-gentoo.el

@@ -0,0 +1,2 @@
+(add-to-list 'load-path "@SITELISP@")
+(load "@SITELISP@/citre-autoloads.el" nil t)

app-emacs/citre/metadata.xml

@@ -0,0 +1,13 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+
+<pkgmetadata>
+  <maintainer type="project">
+    <email>gnu-emacs@gentoo.org</email>
+    <name>Gentoo GNU Emacs project</name>
+  </maintainer>
+  <upstream>
+    <bugs-to>https://github.com/universal-ctags/citre/issues/</bugs-to>
+    <remote-id type="github">universal-ctags/citre</remote-id>
+  </upstream>
+</pkgmetadata>