games-strategy/dopewars: add 1.6.2

Closes: https://bugs.gentoo.org/763114
Signed-off-by: Michael Mair-Keimberger <mmk@levelnine.at>
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

games-strategy/dopewars/Manifest

@@ -1 +1,2 @@
 DIST dopewars-1.6.1.tar.gz 1024168 BLAKE2B 28d650e0d1eccdfa9aa799bb4b35e82facc800ed9cbde9778c7182bd615ad0b1ec7d3fd323473f381f3ed1902b8e305a7994a5e351728aa1028be2e0665bfa57 SHA512 fab27b483b5a24abd95ffe6a52fe92c7179d8ee3e7d27393f0e7c265202781ab6a58e3b3214ff84bbc0e8195644b5c2ec94616b5f63b3fa9dc2ad2f9216e37d1
+DIST dopewars-1.6.2.tar.gz 1030811 BLAKE2B 96d333b7760786b215c3b6079498067149de0784099fd16b30c47a785a0f6d4d1d9030e6654a1d309f59803896d2675181146180411aef558e3cf28b715ac192 SHA512 ce41bc4b7f3a45bc759a76e3f70be84cc6ec1243127a60e8c4c96c908bf70d2d6fbb7d871afbeeec18591dac2cfb5d6d2646e14c7e2771ec02cf7b20e5a25a8f

games-strategy/dopewars/dopewars-1.6.2.ebuild

@@ -0,0 +1,70 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit autotools desktop toolchain-funcs
+
+DESCRIPTION="Re-Write of the game Drug Wars"
+HOMEPAGE="https://dopewars.sourceforge.io/"
+SRC_URI="https://github.com/benmwebb/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="nls ncurses gtk gnome sdl"
+
+RDEPEND="
+	ncurses? ( >=sys-libs/ncurses-5.2:0= )
+	gtk? ( x11-libs/gtk+:2 )
+	dev-libs/glib:2
+	nls? ( virtual/libintl )
+	sdl? (
+		media-libs/libsdl2
+		media-libs/sdl2-mixer
+	)
+"
+DEPEND="${RDEPEND}
+	nls? ( sys-devel/gettext )
+"
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( AUTHORS NEWS README.md TODO doc/example-cfg doc/example-igneous )
+
+src_prepare() {
+	default
+	eautoreconf
+	sed -i -e 's:index.html:html/index.html:' \
+		src/dopewars.c || die
+	sed -i -e "s/\-lncurses/$($(tc-getPKG_CONFIG) --libs ncurses)/g" \
+		configure || die
+}
+
+src_configure() {
+	local myservconf
+
+	if ! use gtk ; then
+		myservconf="--disable-gui-client --disable-gui-server --disable-glibtest --disable-gtktest"
+	fi
+
+	local myeconfargs=(
+		$(use_enable ncurses curses-client)
+		$(use_enable nls)
+		$(use_with sdl)
+		--without-esd
+		--enable-networking
+		--enable-plugins
+		${myservconf}
+	)
+
+	econf "${myeconfargs[@]}"
+}
+
+src_install() {
+	emake DESTDIR="${D}" install
+	rm -r "${ED}"/usr/share/gnome || die
+	rm -r "${ED}"/usr/share/doc || die
+	make_desktop_entry "${PN}" "Dopewars" /usr/share/pixmaps/dopewars-weed.png
+	HTML_DOCS="doc/*html doc/help/"
+	einstalldocs
+}