xfce-base/xfce4-power-manager: Bump to 4.21.1

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/xfce4-power-manager/Manifest

@@ -1,2 +1,3 @@
 DIST xfce4-power-manager-4.20.0.tar.bz2 1523787 BLAKE2B 9df4b976665ee9363b68218ccadeddfba2b79f4446614a16617511c155aa761dac29003f5460b01c98bf27f7845cbf62c5434a521d93f9fc954964c0c9c48657 SHA512 e61762b4ff374562fa3d70b1eb7c9928a1a7197df5b597763adf16435183fd693307267f37f0eb7dd08b573664a397d2fd22674b5db7e07ee9302089772ff6e7
 DIST xfce4-power-manager-4.21.0.tar.xz 626228 BLAKE2B f45ea03e39d7fdcf3db796c6f356b65218f5c64f31a235f4e3a73fc9e05e08ae3aa8d90520f73aac5316d7149b3a7cc135d87944277e29409a231b3574f4a649 SHA512 67fb672dcda66c67f783d44a5e8acecb1ddcfac323904a73c3500b689db350ab977f617d972c06d7d9bac4c403cdd408e1c9f10f05a3281457d5016c970487c1
+DIST xfce4-power-manager-4.21.1.tar.xz 628104 BLAKE2B fe7b8416c1edc3946c9510e5b094c88accbc51c1e68e73ad79282aaf7acce6f504dfaf9d1775a03ca3a297117436a6461f4cea3e690863d07129f08171ca64bf SHA512 cf10c7d24c6d51274c7e6a170770678ab3a27d9d407bd5706d70d28f148627e4d90559aeae91d7d5493d994aaabbf5e8bf66cb4da358be18ce806bb44b9be85b

xfce-base/xfce4-power-manager/xfce4-power-manager-4.21.1.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg-utils
+
+DESCRIPTION="Power manager for the Xfce desktop environment"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/xfce4-power-manager/start
+	https://gitlab.xfce.org/xfce/xfce4-power-manager/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="+panel-plugin policykit wayland X"
+REQUIRED_USE="|| ( wayland X )"
+
+DEPEND="
+	>=dev-libs/glib-2.72.0
+	>=sys-power/upower-0.99.10
+	>=x11-libs/gtk+-3.24.0:3[wayland?,X?]
+	>=x11-libs/libnotify-0.7.8
+	>=xfce-base/xfconf-4.18.0:=
+	>=xfce-base/libxfce4ui-4.21.0:=[gtk3(+)]
+	>=xfce-base/libxfce4util-4.19.4:=
+	panel-plugin? ( >=xfce-base/xfce4-panel-4.18.0:= )
+	policykit? ( >=sys-auth/polkit-0.102 )
+	wayland? (
+		>=dev-libs/wayland-1.20
+	)
+	X? (
+		>=x11-libs/libX11-1.6.7
+		>=x11-libs/libXrandr-1.5.0
+		>=x11-libs/libXext-1.0.0
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+DEPEND+="
+	x11-base/xorg-proto
+	wayland? (
+		>=dev-libs/wayland-protocols-1.25
+	)
+"
+BDEPEND="
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	wayland? (
+		>=dev-util/wayland-scanner-1.20
+	)
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature X x11)
+		$(meson_feature wayland)
+		$(meson_feature panel-plugin)
+		$(meson_feature policykit polkit)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+
+	if ! has_version sys-apps/systemd && ! has_version sys-auth/elogind
+	then
+		elog "Suspend/hibernate support requires a logind provider installed"
+		elog "(sys-apps/systemd or sys-auth/elogind)"
+	fi
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}