mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-08-06 00:48:18 -07:00
dev-python/translate-toolkit: Bump to 3.19.15
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
@@ -2,3 +2,4 @@ DIST translate-3.19.11.gh.tar.gz 1355618 BLAKE2B 65424bb83f67c04566611ebd426ad6d
|
||||
DIST translate-3.19.12.gh.tar.gz 1363988 BLAKE2B 2a9b9ffc74de96d31fafef18c3576b56834844bfcd459bff0eb7eff01938bbf48ec9051ac97de4e5862bf5c6438d599c0055a50d0a8e661d816fc2d4f95729d4 SHA512 8ee6753d20d4a5bb460a23c7538c2d90be98023d61661b6e036d88d6003f18d4b51ec4673f3ce562b5ecba903a63e0dfa16205548477366c796f9714a541a2b7
|
||||
DIST translate-3.19.13.gh.tar.gz 1365289 BLAKE2B 533cbe8be6e5585157bf63518b9f53f359626c04e1c495d8dc713c3ed00ac43fc5591a2db8c6686776ad440c8711d8e5544003abf11fe9bb457df5ea5a3364d0 SHA512 814ad39c2d49f3c96079039173949a09649ef671516f0c77ce749b0c3b7b8978d4217458e7e39f9c10f497f5bd013f80796fa098794cd59ee33c52466beed867
|
||||
DIST translate-3.19.14.gh.tar.gz 1375782 BLAKE2B 37f1dfb46592e1f70b5f437ff016e529f4f4432747e7c592cfe065ecd286a6dd0ef30e4babca7007fd3eb536b86d2832d81b744aee4a009f6ca23ea88ddf4715 SHA512 27f71881a498054e367e77f1a19df46e2a58c37325f55e764b2022754b0ac11fc2b574874da473f30e0ffb586ee5f16d4b625e49dd843cae1a920b89a185a6a4
|
||||
DIST translate-3.19.15.gh.tar.gz 1406521 BLAKE2B a47cd9202ef318b518a7c268fd3eb8b9f3aca526c4735d1c71d4dccf150da7793b6fd468cf473c25006a4f32fe3a8677b8544f7407a90a9c4f5e3a95a32efcaa SHA512 cdc353b7730eb18a177fdc32a0c0018d636be37cba4392eb6f28d74fcc33c8abf34caa8f54cb0e7351a9fcfddf0bb78ced065a2309995b82a24338766b9c917a
|
||||
|
||||
123
dev-python/translate-toolkit/translate-toolkit-3.19.15.ebuild
Normal file
123
dev-python/translate-toolkit/translate-toolkit-3.19.15.ebuild
Normal file
@@ -0,0 +1,123 @@
|
||||
# Copyright 1999-2026 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
DISTUTILS_USE_PEP517=setuptools
|
||||
PYTHON_COMPAT=( python3_{12..14} )
|
||||
PYTHON_REQ_USE="sqlite"
|
||||
|
||||
inherit distutils-r1
|
||||
|
||||
MY_P=translate-${PV}
|
||||
DESCRIPTION="Toolkit to convert between many translation formats"
|
||||
HOMEPAGE="
|
||||
https://github.com/translate/translate/
|
||||
https://pypi.org/project/translate-toolkit/
|
||||
"
|
||||
SRC_URI="
|
||||
https://github.com/translate/translate/archive/${PV}.tar.gz
|
||||
-> ${MY_P}.gh.tar.gz
|
||||
"
|
||||
S="${WORKDIR}"/${MY_P}
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
IUSE="+html +ical +ini +subtitles +yaml"
|
||||
|
||||
RDEPEND="
|
||||
app-text/iso-codes
|
||||
>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
|
||||
dev-python/cheroot[${PYTHON_USEDEP}]
|
||||
>=dev-python/levenshtein-0.12.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/lxml-5.2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/mistletoe-1.1.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
|
||||
dev-python/ruamel-yaml[${PYTHON_USEDEP}]
|
||||
dev-python/tomlkit[${PYTHON_USEDEP}]
|
||||
>=dev-python/unicode-segmentation-rs-0.2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/wcwidth-0.2.14[${PYTHON_USEDEP}]
|
||||
sys-devel/gettext
|
||||
html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
|
||||
ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
|
||||
ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
|
||||
subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
|
||||
yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
|
||||
"
|
||||
BDEPEND="
|
||||
test? (
|
||||
dev-python/phply[${PYTHON_USEDEP}]
|
||||
)
|
||||
"
|
||||
|
||||
EPYTEST_PLUGINS=( syrupy )
|
||||
EPYTEST_XDIST=1
|
||||
distutils_enable_tests pytest
|
||||
|
||||
src_prepare() {
|
||||
distutils-r1_src_prepare
|
||||
|
||||
# strip unnecessary pins
|
||||
sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
|
||||
}
|
||||
|
||||
src_test() {
|
||||
# unfortunately, this bad quality package doesn't support XDG_DATA_DIRS
|
||||
# correctly, so we need to reassemble all data files in a single directory
|
||||
local -x XDG_DATA_HOME=${T}/share
|
||||
cp -r translate/share "${T}/" || die
|
||||
cp -r "${ESYSROOT}"/usr/share/gaupol "${XDG_DATA_HOME}"/ || die
|
||||
|
||||
distutils-r1_src_test
|
||||
}
|
||||
|
||||
python_test() {
|
||||
local EPYTEST_DESELECT=(
|
||||
# Fails with network-sandbox (and even with it off but w/ softer fail)
|
||||
'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
|
||||
'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
|
||||
)
|
||||
local EPYTEST_IGNORE=(
|
||||
# unpackaged fluent.*
|
||||
tests/translate/storage/test_fluent.py
|
||||
tests/translate/convert/test_fluent2po.py
|
||||
# changes directory and does not change it back, sigh
|
||||
tests/odf_xliff/test_odf_xliff.py
|
||||
)
|
||||
|
||||
if ! has_version "dev-python/iniparse[${PYTHON_USEDEP}]"; then
|
||||
EPYTEST_IGNORE+=(
|
||||
translate/convert/test_ini2po.py
|
||||
translate/convert/test_po2ini.py
|
||||
)
|
||||
fi
|
||||
|
||||
if ! has_version "media-video/gaupol[${PYTHON_USEDEP}]"; then
|
||||
EPYTEST_IGNORE+=(
|
||||
translate/storage/test_subtitles.py
|
||||
)
|
||||
fi
|
||||
|
||||
epytest
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
distutils-r1_python_install_all
|
||||
|
||||
insinto /usr
|
||||
doins -r translate/share
|
||||
|
||||
if ! use html; then
|
||||
rm "${ED}"/usr/bin/{html2po,po2html} || die
|
||||
fi
|
||||
if ! use ical; then
|
||||
rm "${ED}"/usr/bin/{ical2po,po2ical} || die
|
||||
fi
|
||||
if ! use ini; then
|
||||
rm "${ED}"/usr/bin/{ini2po,po2ini} || die
|
||||
fi
|
||||
if ! use subtitles; then
|
||||
rm "${ED}"/usr/bin/{sub2po,po2sub} || die
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user