mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-21 21:17:37 -08:00
dev-python/translate-toolkit: Bump to 3.17.4
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
parent
4cfa318e3b
commit
c4a13b625f
@ -1,3 +1,4 @@
|
||||
DIST translate-3.16.3.gh.tar.gz 1182562 BLAKE2B 25ea88b5490891140670cdc384c9c1a318dce0085d6b9c8f6b1a7fbb0892a2e6eb80c26c02fa4890d3ec45c0d9c3958d7c3c4c33dba76d1ee03d977ee0a6863a SHA512 e2e59ca01769a88fd7c6367d0e1e8b96da9f950b600fc62eecae9aed4ad072877b1fd1a6742f0588b2b27d33f6652e98db4c90e63fb4d09481a651019beaee44
|
||||
DIST translate-3.17.2.gh.tar.gz 1237809 BLAKE2B b7f1ea65990ac2b5380e674cadc47c1df6ff2476afed25d36b8c636b4d0fba32005086015b03425bdea38f4b22ed7c53d1b664ed92a06aa65f80720e34c49072 SHA512 8658101eec4d4da05c34f4e7b4e0fb77bf8f576bf867118bd4f5b39609fb7d67064412dfab514edc448331b93fd12c148e53cff57c6b1fe1155427059ad7821a
|
||||
DIST translate-3.17.3.gh.tar.gz 1241480 BLAKE2B 2c3e32f1959b37903214005bb360a0efd9c3b8ebbd8c1996be0af80aa753e109512656c896c51cf9a1e0f449fef47116938e5c92a9828c21cd5a3cd6a2bc4315 SHA512 8d5c83b10a706300ba73310469b1e1857338c6dffa5790765fee316c183b832b3f142080759fd6155fcfa716613c6019be17b3ad70ffcf57eeb27e7eb5b62397
|
||||
DIST translate-3.17.4.gh.tar.gz 1242234 BLAKE2B da13cc36d463c7f50724b1f398d77e817db03abe2ca9bbc19de6900f48de839feff63b7efcbf76e4eb6d252525e56d0abe67403102f2eaf45c5bcc2007f00e55 SHA512 1ee5a3bb82cd7cd57e6ab3cc95469c0c1b00018accb0129fda909317dfd62df77ea69061fddec9838c8e5f0e76fc45c130c93ce99d2e628b508551e573ef9279
|
||||
|
||||
129
dev-python/translate-toolkit/translate-toolkit-3.17.4.ebuild
Normal file
129
dev-python/translate-toolkit/translate-toolkit-3.17.4.ebuild
Normal file
@ -0,0 +1,129 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
DISTUTILS_USE_PEP517=setuptools
|
||||
PYTHON_COMPAT=( python3_{11..14} )
|
||||
PYTHON_REQ_USE="sqlite"
|
||||
|
||||
inherit distutils-r1
|
||||
|
||||
MY_P=translate-${PV}
|
||||
DESCRIPTION="Toolkit to convert between many translation formats"
|
||||
HOMEPAGE="
|
||||
https://github.com/translate/translate/
|
||||
https://pypi.org/project/translate-toolkit/
|
||||
"
|
||||
SRC_URI="
|
||||
https://github.com/translate/translate/archive/${PV}.tar.gz
|
||||
-> ${MY_P}.gh.tar.gz
|
||||
"
|
||||
S="${WORKDIR}"/${MY_P}
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm64"
|
||||
IUSE="+html +ical +ini +subtitles +yaml"
|
||||
|
||||
RDEPEND="
|
||||
app-text/iso-codes
|
||||
>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
|
||||
dev-python/cheroot[${PYTHON_USEDEP}]
|
||||
>=dev-python/levenshtein-0.12.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/lxml-5.2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/mistletoe-1.1.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
|
||||
dev-python/ruamel-yaml[${PYTHON_USEDEP}]
|
||||
dev-python/tomlkit[${PYTHON_USEDEP}]
|
||||
>=dev-python/unicode-segmentation-rs-0.2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/wcwidth-0.2.14[${PYTHON_USEDEP}]
|
||||
sys-devel/gettext
|
||||
html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
|
||||
ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
|
||||
ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
|
||||
subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
|
||||
yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
|
||||
"
|
||||
# Technically, the test suite also has undeclared dependency
|
||||
# on dev-python/snapshottest but all the tests using it are broken
|
||||
# anyway, so we skip them.
|
||||
BDEPEND="
|
||||
test? (
|
||||
dev-python/phply[${PYTHON_USEDEP}]
|
||||
)
|
||||
"
|
||||
|
||||
EPYTEST_PLUGINS=()
|
||||
EPYTEST_XDIST=1
|
||||
distutils_enable_tests pytest
|
||||
|
||||
src_prepare() {
|
||||
distutils-r1_src_prepare
|
||||
|
||||
# strip unnecessary pins
|
||||
sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
|
||||
}
|
||||
|
||||
src_test() {
|
||||
# unfortunately, this bad quality package doesn't support XDG_DATA_DIRS
|
||||
# correctly, so we need to reassemble all data files in a single directory
|
||||
local -x XDG_DATA_HOME=${T}/share
|
||||
cp -r translate/share "${T}/" || die
|
||||
cp -r "${ESYSROOT}"/usr/share/gaupol "${XDG_DATA_HOME}"/ || die
|
||||
|
||||
distutils-r1_src_test
|
||||
}
|
||||
|
||||
python_test() {
|
||||
local EPYTEST_DESELECT=(
|
||||
# Fails with network-sandbox (and even with it off but w/ softer fail)
|
||||
'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
|
||||
'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
|
||||
# all tests based on snapshottest are broken and I'm too tired
|
||||
# to figure this out
|
||||
tests/translate/tools/test_pocount.py::test_{cases,output}
|
||||
tests/translate/tools/test_junitmsgfmt.py::test_output
|
||||
)
|
||||
local EPYTEST_IGNORE=(
|
||||
# unpackaged fluent.*
|
||||
tests/translate/storage/test_fluent.py
|
||||
# changes directory and does not change it back, sigh
|
||||
tests/odf_xliff/test_odf_xliff.py
|
||||
)
|
||||
|
||||
if ! has_version "dev-python/iniparse[${PYTHON_USEDEP}]"; then
|
||||
EPYTEST_IGNORE+=(
|
||||
translate/convert/test_ini2po.py
|
||||
translate/convert/test_po2ini.py
|
||||
)
|
||||
fi
|
||||
|
||||
if ! has_version "media-video/gaupol[${PYTHON_USEDEP}]"; then
|
||||
EPYTEST_IGNORE+=(
|
||||
translate/storage/test_subtitles.py
|
||||
)
|
||||
fi
|
||||
|
||||
epytest
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
distutils-r1_python_install_all
|
||||
|
||||
insinto /usr
|
||||
doins -r translate/share
|
||||
|
||||
if ! use html; then
|
||||
rm "${ED}"/usr/bin/{html2po,po2html} || die
|
||||
fi
|
||||
if ! use ical; then
|
||||
rm "${ED}"/usr/bin/{ical2po,po2ical} || die
|
||||
fi
|
||||
if ! use ini; then
|
||||
rm "${ED}"/usr/bin/{ini2po,po2ini} || die
|
||||
fi
|
||||
if ! use subtitles; then
|
||||
rm "${ED}"/usr/bin/{sub2po,po2sub} || die
|
||||
fi
|
||||
}
|
||||
Loading…
x
Reference in New Issue
Block a user