kde-apps/kate-lib: 25.12.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
2026-03-05 19:05:23 +01:00
parent c3d51f53ef
commit c49d4beba9
2 changed files with 69 additions and 0 deletions
+1
View File
@@ -1 +1,2 @@
DIST kate-25.12.2.tar.xz 8534324 BLAKE2B c12fa200ff2e079a06bf0e1980420380dab2b3db9878289d300a83d6ecae190bd5cb8050704c0e5f90816edb75a2684d9106bfad708ece7a8a4075969c14312f SHA512 82e887c56b5f9a7a142f14d465c5693db91da07596535c1f4741a0866358270623a6bc494ac1f8c40039840f54076a428b84e15b27ea0fe1a46a63c2b63f6974
DIST kate-25.12.3.tar.xz 8561744 BLAKE2B fb3fcac7db2907bc6dd1c122c5bf99a6b3ea976e6eb228e5cd566295f8b4af957b5baf4f5dd9ffae6b06af6bcd3640758f069ccfa37b68b0d7de43c45b549a68 SHA512 249a5cd4e50151b0c725e67efe74fdff7318ca5af969509492e852e5ce29fd66499d2fead75237c562b250e4123b22c1f89a512460bc6a7a0b859f5e74ab5410
+68
View File
@@ -0,0 +1,68 @@
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
KDE_ORG_CATEGORY="utilities"
KDE_ORG_NAME="kate"
ECM_TEST="true"
KFMIN=6.19.0
QTMIN=6.10.1
inherit ecm gear.kde.org
DESCRIPTION="Shared library used by Kate/Kwrite and Kate-Addons"
HOMEPAGE="https://kate-editor.org/ https://apps.kde.org/kate/"
LICENSE="LGPL-2 LGPL-2+ MIT"
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="telemetry"
DEPEND="
>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,widgets,xml]
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kiconthemes-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kjobwidgets-${KFMIN}:6
>=kde-frameworks/kparts-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
>=kde-frameworks/ktexteditor-${KFMIN}:6
>=kde-frameworks/ktextwidgets-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/syntax-highlighting-${KFMIN}:6
telemetry? ( >=kde-frameworks/kuserfeedback-${KFMIN}:6 )
"
RDEPEND="${DEPEND}
>=kde-apps/kate-common-${PV}
"
CMAKE_SKIP_TESTS=(
{session_manager,sessions_action}_test # tests hang
)
# bug #967516: weird interaction w/ git: only works from git repo
[[ ${KDE_BUILD_TYPE} != live ]] && CMAKE_SKIP_TESTS=(
kateapp-file_history_tests
)
src_prepare() {
ecm_src_prepare
ecm_punt_po_install
}
src_configure() {
local mycmakeargs=(
-DBUILD_addons=FALSE
-DBUILD_kate=FALSE
-DBUILD_kwrite=FALSE
-DCMAKE_DISABLE_FIND_PACKAGE_KF6DocTools=ON
$(cmake_use_find_package telemetry KF6UserFeedback)
)
ecm_src_configure
}