gentoo-mirror/gentoo
1
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-08-25 07:08:13 -07:00
Code Issues Projects Releases Wiki Activity

dev-python/hypothesis: Bump to 5.37.3

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2020-10-15 12:36:00 +02:00
parent d791b8d279
commit c433688d3f
2 changed files with 64 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/hypothesis/Manifest
View File

@@ -7,3 +7,4 @@ DIST hypothesis-python-5.36.1.tar.gz 9086877 BLAKE2B 4b71daa1e9417d8249364292ca1
DIST hypothesis-python-5.36.2.tar.gz 9088227 BLAKE2B 578c28d045f3b3f288d43765d556f1e7bbde661684b71f6379df3eba516d8ece86f31a38a414e676532f6ecb8a1ee69ac77d207a8637eaef8b9a86584d3292eb SHA512 d6792d5b9f60aea6181018c69eaa12982ef0ab353bff3f46bc987a4633a15b655ed04ee8ae3aca7dbd9e23cf5f85e4a95e455082f4035e246342b72e2dafe258
DIST hypothesis-python-5.37.0.tar.gz 9091454 BLAKE2B 2e51479f872dca6834d6cf8c2815e20cdb53c8968c3f5e5f6144a34c040e7dce9627c578ee072b21252b64af0507f361e4d5dfd3b65f8eb1abef9bfdac6d49ea SHA512 66e6f7a8ae11e9a8c8da79aa433d151733e07038ea37f211773972596bedaa227e8492fe7b9f363ea92ffcfd8c3e5a0a5364e04be22aab010a20544d3abcc93a
DIST hypothesis-python-5.37.1.tar.gz 9091568 BLAKE2B 7f4ffdb680ba473ffb16bb201b9664184cb43b04a2993cbd379c7f91a8ff8ec78eb36e9e54740d38656d8e6681ada220d1b0845aab7c931558003143e8e60aef SHA512 57101d12cf81641cb47ee2b9da9a4a3233ea4eec178d16c16778b4ce869e70463ca1381d983abd48382fe8eb4d0f8f8e4ea41f7b3b6c9e71b73c4a119cba85f8
DIST hypothesis-python-5.37.3.tar.gz 9092178 BLAKE2B 1d7caae90176ce62a235679bf55ae4142bb9647195e10271321891bc45d25ac5e90e4fcc6cb00af3018f69f99ac408256b72280af67e42d2c74ca66cb63d3c4c SHA512 d2c7a7a0799eb5468d38e4b15d793ff37a52b02afffe4726078daf62cb3530f1f8fbc605b20ae4120440b63bbcbc57ba85aee78945eeaca6b105b6940e3cbb51

63
dev-python/hypothesis/hypothesis-5.37.3.ebuild Normal file
View File

@@ -0,0 +1,63 @@
# Copyright 1999-2020 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
DISTUTILS_USE_SETUPTOOLS=rdepend
PYTHON_COMPAT=( python3_{6,7,8,9} pypy3 )
PYTHON_REQ_USE="threads(+),sqlite"
inherit distutils-r1 eutils multiprocessing optfeature
DESCRIPTION="A library for property based testing"
HOMEPAGE="https://github.com/HypothesisWorks/hypothesis https://pypi.org/project/hypothesis/"
SRC_URI="https://github.com/HypothesisWorks/${PN}/archive/${PN}-python-${PV}.tar.gz"
S="${WORKDIR}/${PN}-${PN}-python-${PV}/${PN}-python"
LICENSE="MPL-2.0"
SLOT="0"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="cli test"
RESTRICT="!test? ( test )"
RDEPEND="
>=dev-python/attrs-19.2.0[${PYTHON_USEDEP}]
>=dev-python/sortedcontainers-2.1.0[${PYTHON_USEDEP}]
cli? (
$(python_gen_cond_dep '
dev-python/black[${PYTHON_USEDEP}]
dev-python/click[${PYTHON_USEDEP}]
' python3_{6..9})
)
"
BDEPEND="
test? (
${RDEPEND}
dev-python/mock[${PYTHON_USEDEP}]
dev-python/pexpect[${PYTHON_USEDEP}]
>=dev-python/pytest-5.3.5[${PYTHON_USEDEP}]
dev-python/pytest-xdist[${PYTHON_USEDEP}]
!!<dev-python/typing-3.7.4.1
)
"
python_prepare() {
if ! use cli || [[ ${EPYTHON} != python* ]]; then
sed -i -e '/console_scripts/d' setup.py || die
fi
}
python_test() {
pytest -vv tests/cover tests/pytest tests/quality \
-n "$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")" ||
die "Tests fail with ${EPYTHON}"
}
pkg_postinst() {
optfeature "datetime support" dev-python/pytz
optfeature "dateutil support" dev-python/python-dateutil
optfeature "numpy support" dev-python/numpy
optfeature "django support" dev-python/django dev-python/pytz
optfeature "pandas support" dev-python/pandas
optfeature "pytest support" dev-python/pytest
}