media-sound/gpodder: add 3.11.5

Signed-off-by: Brand Huntsman <au@qzx.com>
Closes: https://github.com/gentoo/gentoo/pull/40569
Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>

media-sound/gpodder/Manifest

@@ -1 +1,2 @@
 DIST gpodder-3.11.4.tar.gz 1183463 BLAKE2B ec16bd8dbe531869dd68b062e12013adeb4010a1423b274e52e5cf765828ddffccbfe021a3936e1a6985c2a00f9d1aaf63b80f89beace968501b2e55d284d53d SHA512 f60e2e04abec7d9713d169f9eccb431325bcfe40303e14d0cb42c3b5b4696d7435b86eb1c69b430ef99f81a6b71f89dffafec84d1f1c51118af59e57dcfa0d2d
+DIST gpodder-3.11.5.tar.gz 1228661 BLAKE2B d598dee5a3c5d7ee715a31ae654fa6103d3df99907966a0a92edbaf8f4b93316f60b1f9272330d7c614d48e90b2efef3a74475e658c8b6d3e7769f30d1a00f5b SHA512 5364ff4e819dac30e5153859a4a81ca97a62ec4137b924b6a9367c820452a96cf90dd4fadead94dcf8d36bddf1f832aa4f2c1e325aca7bdcafe68808ae201a83

media-sound/gpodder/gpodder-3.11.5.ebuild

@@ -0,0 +1,93 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=setuptools
+DISTUTILS_SINGLE_IMPL=1
+PYTHON_COMPAT=( python3_{11..13} )
+PYTHON_REQ_USE="sqlite"
+
+inherit distutils-r1 optfeature xdg
+
+DESCRIPTION="A free cross-platform podcast aggregator"
+HOMEPAGE="https://gpodder.github.io/"
+SRC_URI="
+	https://github.com/${PN}/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz
+"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+dbus bluetooth mtp"
+
+RDEPEND="
+	$(python_gen_cond_dep '
+		dev-python/html5lib[${PYTHON_USEDEP}]
+		dev-python/pycairo[${PYTHON_USEDEP}]
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+		dev-python/podcastparser[${PYTHON_USEDEP}]
+		dev-python/mygpoclient[${PYTHON_USEDEP}]
+		dev-python/requests[${PYTHON_USEDEP}]
+		dbus? ( dev-python/dbus-python[${PYTHON_USEDEP}] )
+	')
+	bluetooth? ( net-wireless/bluez )
+	mtp? ( media-libs/libmtp:= )
+	kernel_linux? ( sys-apps/iproute2 )
+"
+BDEPEND="
+	dev-util/desktop-file-utils
+	dev-util/intltool
+	sys-apps/help2man
+	test? (
+		$(python_gen_cond_dep '
+			dev-python/minimock[${PYTHON_USEDEP}]
+			dev-python/pytest-httpserver[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+distutils_enable_tests pytest
+
+src_prepare() {
+	default
+
+	sed -e 's:--cov=gpodder::' -i makefile || die
+
+	emake PYTHON="${EPYTHON}" build
+}
+
+python_test() {
+	# These are pulled out from the Makefile to give us more control
+	# See bug #795165
+	# Previously, we used 'emake releasetest' in src_test
+
+	local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
+
+	local -x EPYTEST_IGNORE=(
+		src/gpodder/utilwin32ctypes.py
+	)
+
+	epytest \
+		--ignore=tests \
+		--doctest-modules src/gpodder/util.py \
+		src/gpodder/jsonconfig.py
+
+	epytest tests \
+		--ignore=src/mygpoclient \
+		-p pytest_httpserver
+}
+
+src_install() {
+	distutils-r1_src_install
+
+	touch "${ED}/usr/share/gpodder/no-update-check" || die
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	optfeature "track length detection for device sync (only one package is needed)" media-video/mplayer dev-python/eyed3
+	optfeature "for the YouTube extension" net-misc/yt-dlp
+	optfeature "iPod sync support" media-libs/libgpod
+}