media-gfx/kphotoalbum: add 6.1.0

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

media-gfx/kphotoalbum/Manifest

@@ -1 +1,2 @@
 DIST kphotoalbum-6.0.1.tar.xz 11526784 BLAKE2B 2ebeb977ed902a66116305d3774f86820efa0eb1676af1f07847fc9374d1e6f51010e8953eafd9b95efd1f5f866b7ef0d1835c7e1cec8ed777e4b045fa52dc6b SHA512 9d0a9e45f32da3f129688b575021a6fff2dd6c0cdb0f8b8c479c33d5243f251d0598e331b8029a9e95d442a9b63cae8a43f2e1232a82b6c6a86daa5d0d6e7690
+DIST kphotoalbum-6.1.0.tar.xz 14356604 BLAKE2B 06730d1cb5559637a26f9d7ee257e46047a3bfb9e7740d5534dab0e428ce6ba3cfe2b798fce2a8ba4980733cc38473ac276bcdb55a24cc7979633f556529d234 SHA512 8f66a076dddfea6e0d0ad9c405abf5fc0a4ce48d0db265754cf442ba183f45db30999b1647ccbb4ae7b237304c33aef3fa383fe3efd2b3f531fd870ed8499b77

media-gfx/kphotoalbum/kphotoalbum-6.1.0.ebuild

@@ -0,0 +1,68 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="forceoptional"
+KFMIN=6.9.0
+QTMIN=6.8.1
+inherit ecm kde.org xdg
+
+DESCRIPTION="Tool for indexing, searching, and viewing images"
+HOMEPAGE="https://www.kphotoalbum.org/"
+
+if [[ ${KDE_BUILD_TYPE} != live ]]; then
+	SRC_URI="mirror://kde/stable/${PN}/${PV}/${P}.tar.xz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2+ FDL-1.2 CC-BY-SA-4.0"
+SLOT="0"
+IUSE="+map phonon +raw share +vlc"
+
+REQUIRED_USE="|| ( phonon vlc )"
+
+DEPEND="
+	>=dev-qt/qtbase-${QTMIN}:6[dbus,gui,sql,sqlite,widgets,xml]
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kcolorscheme-${KFMIN}:6
+	>=kde-frameworks/kcompletion-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kiconthemes-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/kjobwidgets-${KFMIN}:6
+	>=kde-frameworks/kservice-${KFMIN}:6
+	>=kde-frameworks/ktextwidgets-${KFMIN}:6
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
+	>=kde-frameworks/kxmlgui-${KFMIN}:6
+	media-gfx/exiv2:=
+	media-libs/libjpeg-turbo:=
+	map? ( kde-apps/marble:6 )
+	phonon? ( >=media-libs/phonon-4.12.0[qt6(+)] )
+	raw? ( kde-apps/libkdcraw:6 )
+	share? ( >=kde-frameworks/purpose-${KFMIN}:6 )
+	vlc? ( media-video/vlc:= )
+"
+RDEPEND="${DEPEND}
+	!${CATEGORY}/${PN}:5
+	media-video/ffmpeg
+"
+BDEPEND=">=dev-build/cmake-3.30"
+
+DOCS=( CHANGELOG.{md,old} README.md )
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake_use_find_package map Marble)
+		$(cmake_use_find_package phonon Phonon4Qt6)
+		$(cmake_use_find_package raw KDcrawQt6)
+		$(cmake_use_find_package share KF6Purpose)
+		$(cmake_use_find_package vlc LIBVLC)
+	)
+
+	ecm_src_configure
+}