www-client/epiphany: bump to 3.26.7, fixes CVE-2018-11396/CVE-2018-12016

Package-Manager: Portage-2.3.43, Repoman-2.3.10

www-client/epiphany/Manifest

@@ -1 +1,2 @@
 DIST epiphany-3.24.5.tar.xz 3216736 BLAKE2B 8a4dd668606521d1b0144afc9ace8607f52eac457f0059e6087216323ec1132dbe1c755e40dfe9993bf685e5444db1268ada1cdf55edc04c51058fdd256c6047 SHA512 a8f203d182b8c87878a3272f8b4f642b0cf4128476e0727208135cfdffeb293425cf662c58820f0d3aed2e1b20fe6dc4cf5cbb8277a398c6f533a0bea34f40f2
+DIST epiphany-3.26.7.tar.xz 4429308 BLAKE2B cdd8cf084631891e97585307c90bd67f45e71deb6564f54711deb8dfd39c09007732efeb22ad5be45c1b0af6af7be30cf13a9d90aa1e9506a2e997f6f3f8d854 SHA512 686c8825d476a4c6675dadd7a68bf72727714bc6fe01b4dbf67d39b2dc7e3f21d4f630417865800664a716d6316df8a97fde5201ec72c90f448fd6f0af4b49a0

www-client/epiphany/epiphany-3.26.7.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome.org gnome2-utils meson xdg virtualx
+
+DESCRIPTION="GNOME webbrowser based on Webkit"
+HOMEPAGE="https://wiki.gnome.org/Apps/Web"
+
+LICENSE="GPL-3+"
+SLOT="0"
+IUSE="test"
+KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
+
+COMMON_DEPEND="
+	>=dev-libs/glib-2.52.0:2
+	>=x11-libs/gtk+-3.22.13:3
+	>=dev-libs/nettle-3.2:=
+	>=net-libs/webkit-gtk-2.17.4:4=
+	>=x11-libs/cairo-1.2
+	>=app-crypt/gcr-3.5.5:=[gtk]
+	>=x11-libs/gdk-pixbuf-2.36.5:2
+	>=gnome-base/gnome-desktop-2.91.2:3=
+	dev-libs/icu:=
+	>=app-text/iso-codes-0.35
+	>=dev-libs/json-glib-1.2.4
+	>=x11-libs/libnotify-0.5.1
+	>=app-crypt/libsecret-0.14
+	>=net-libs/libsoup-2.48:2.4
+	>=dev-libs/libxml2-2.6.12:2
+	>=dev-libs/libxslt-1.1.7
+	dev-db/sqlite:3
+	dev-libs/gmp:0=
+	>=gnome-base/gsettings-desktop-schemas-0.0.1
+"
+RDEPEND="${COMMON_DEPEND}
+	x11-themes/adwaita-icon-theme
+"
+# paxctl needed for bug #407085
+DEPEND="${COMMON_DEPEND}
+	app-text/yelp-tools
+	dev-util/gdbus-codegen
+	sys-apps/paxctl
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# https://bugzilla.gnome.org/show_bug.cgi?id=751591
+	# ephy-file-helpers tests are currently disabled due to https://gitlab.gnome.org/GNOME/epiphany/issues/419
+	# So this patch is currently without effect. Retest with PORTAGE_TMPDIR=/var/tmp once re-enabled upstream.
+	#"${FILESDIR}"/${PN}-3.16.0-unittest-1.patch
+)
+
+src_configure() {
+	local emesonargs=(
+		-Ddeveloper_mode=false
+		-Ddistributor_name=Gentoo
+		-Dhttps_everywhere=false # removed in 3.28
+		$(meson_use test unit_tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_icon_cache_update
+	gnome2_schemas_update
+}