mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-09-23 16:49:10 -07:00
media-plugins/gst-plugins-vaapi: drop 1.24.10-r2
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner
@@ -1,2 +1 @@
|
||||
DIST gstreamer-vaapi-1.24.10.tar.xz 555624 BLAKE2B ffcbbc4d8096c622a3a89804f6b038fbd1ac75cd214f644ede09119b9ba7b5afa19788a9f6c66fad0537ae67c33e1b334cea75133100ad0daf1882a25601f54e SHA512 dad62a767eec9067afefdd7941df2eef31191cc597cd82fd42f196a36ee4dd3c94bd6852118cc8ba6318443dde0de16a77585daf93f61d683acfb034c167aa46
|
||||
DIST gstreamer-vaapi-1.24.11.tar.xz 547692 BLAKE2B 9373f9f56191ea8b9681a9638135eeff58c45669829aad6e5035003ac880048df1f5131699e6061586dc8869edc4e1506e9f3b27eb1428b4b20b9182e925be4d SHA512 dfe5ee78283d695103e9bac6bbece63705618f91122f7ab1e91edfce105d9848f2f552d0e83e05ed3d052a3151a4efe1db0955c48af6b3e40c903ffb335fd466
|
||||
|
||||
@@ -1,105 +0,0 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
inherit gstreamer-meson
|
||||
|
||||
MY_PN="gstreamer-vaapi"
|
||||
DESCRIPTION="Hardware accelerated video decoding through VA-API plugin for GStreamer"
|
||||
HOMEPAGE="https://gitlab.freedesktop.org/gstreamer/gstreamer-vaapi"
|
||||
SRC_URI="https://gstreamer.freedesktop.org/src/${MY_PN}/${MY_PN}-${PV}.tar.xz"
|
||||
|
||||
LICENSE="LGPL-2.1+"
|
||||
SLOT="1.0"
|
||||
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
|
||||
IUSE="+drm +egl +gles2 opengl wayland +X" # Keep default enabled IUSE in sync with gst-plugins-base and libva
|
||||
|
||||
# gst-vaapi configure is based around GL platform mainly, unlike gst-plugins-bad that goes by GL API mainly; for less surprises,
|
||||
# we design gst-vaapi ebuild in terms of GL API as main choice as well, meaning that USE opengl and/or gles2 is required to
|
||||
# enable opengl support at all and choices get chained from there.
|
||||
# One or multiple video output are required: drm, x11, glx, egl and/or wayland;
|
||||
# but GL API is our main trigger, thus USE=egl should be ineffective if neither gles2 or opengl is enabled;
|
||||
# So "|| ( drm egl opengl wayland X )" would be wrong, because egl isn't built with USE="egl -opengl -gles2", ending up with no video outputs.
|
||||
# As we ensure at least one working GL output with other REQUIRED_USE, we can put gles2/opengl in REQUIRED_USE instead of egl, solving the issue.
|
||||
# gles2 API only supported windowing system (on linux) is EGL, so require it
|
||||
# opengl API only supported windowing systems (on linux) are EGL and GLX, so require one of them (glx is enabled with USE="opengl X")
|
||||
REQUIRED_USE="
|
||||
|| ( drm gles2 opengl wayland X )
|
||||
gles2? ( egl )
|
||||
opengl? ( || ( egl X ) )
|
||||
wayland? ( drm )
|
||||
"
|
||||
|
||||
# glx doesn't require libva-glx (libva[opengl]) afaics, only by tests/test-display.c
|
||||
# USE flag behavior:
|
||||
# 'drm' enables vaapi drm support
|
||||
# 'egl' enables EGL platform support (but only if also 'opengl||gles2')
|
||||
# - 'egl' is exposed as a USE flag mainly to get EGL support instead of or in addition to GLX support with desktop GL while keeping it optional for pure GLX cases;
|
||||
# it's always required with USE=gles2, thus USE="gles2 opengl X" will require and build desktop GL EGL platform support as well on top of GLX, which doesn't add extra deps at that point.
|
||||
# 'gles2' enables GLESv2 or GLESv3 based GL API support
|
||||
# 'opengl' enables desktop OpenGL based GL API support
|
||||
# 'wayland' enables non-GL Wayland support; wayland EGL support when combined with 'egl' (but only if also 'opengl||gles2')
|
||||
# 'X' enables non-GL X support; GLX support when combined with 'opengl'
|
||||
# gst-plugins-bad still needed for codecparsers (GL libraries moved to -base); checked for 1.14 (recheck for 1.16)
|
||||
GST_REQ="${PV}"
|
||||
GL_DEPS="
|
||||
>=media-libs/gst-plugins-base-${GST_REQ}:${SLOT}[egl?,gles2?,opengl?,wayland?,X?]
|
||||
|| (
|
||||
>=media-libs/mesa-24.1.0_rc1[opengl,X?,${MULTILIB_USEDEP}]
|
||||
<media-libs/mesa-24.1.0_rc1[gles2?,egl(+)?,X?,${MULTILIB_USEDEP}]
|
||||
)
|
||||
"
|
||||
RDEPEND="
|
||||
>=media-libs/gst-plugins-base-${GST_REQ}:${SLOT}[${MULTILIB_USEDEP}]
|
||||
>=media-libs/gst-plugins-bad-${GST_REQ}:${SLOT}[${MULTILIB_USEDEP}]
|
||||
>=media-libs/libva-1.15.0:=[drm(+)?,wayland?,X?,${MULTILIB_USEDEP}]
|
||||
drm? (
|
||||
>=virtual/libudev-208:=[${MULTILIB_USEDEP}]
|
||||
>=x11-libs/libdrm-2.4.98[${MULTILIB_USEDEP}]
|
||||
)
|
||||
gles2? ( ${GL_DEPS} )
|
||||
opengl? ( ${GL_DEPS} )
|
||||
wayland? ( >=dev-libs/wayland-1.11.0[${MULTILIB_USEDEP}] )
|
||||
X? (
|
||||
>=x11-libs/libX11-1.6.2[${MULTILIB_USEDEP}]
|
||||
>=x11-libs/libXrandr-1.4.2[${MULTILIB_USEDEP}]
|
||||
x11-libs/libXrender[${MULTILIB_USEDEP}] )
|
||||
"
|
||||
DEPEND="${RDEPEND}"
|
||||
|
||||
S="${WORKDIR}/${MY_PN}-${PV}"
|
||||
|
||||
# FIXME: "Failed to create vaapipostproc element"
|
||||
RESTRICT="test"
|
||||
|
||||
PATCHES=(
|
||||
"${FILESDIR}"/${PN}-1.24.10-wayland-optionality.patch
|
||||
)
|
||||
|
||||
multilib_src_configure() {
|
||||
GST_PLUGINS_NOAUTO="wayland"
|
||||
|
||||
local emesonargs=(
|
||||
-Dencoders=enabled
|
||||
$(meson_feature drm)
|
||||
$(meson_feature X x11)
|
||||
$(meson_feature wayland)
|
||||
)
|
||||
|
||||
if use opengl || use gles2; then
|
||||
emesonargs+=( $(meson_feature egl) )
|
||||
else
|
||||
emesonargs+=( -Degl=disabled )
|
||||
fi
|
||||
|
||||
if use opengl && use X; then
|
||||
emesonargs+=( -Dglx=enabled )
|
||||
else
|
||||
emesonargs+=( -Dglx=disabled )
|
||||
fi
|
||||
|
||||
# Workaround EGL/eglplatform.h being built with X11 present
|
||||
use X || export CFLAGS="${CFLAGS} -DEGL_NO_X11"
|
||||
|
||||
gstreamer_multilib_src_configure
|
||||
}
|
||||
Reference in New Issue
Block a user