dev-libs/libwacom: Version bump to 2.6.0

Closes: https://bugs.gentoo.org/802558
Signed-off-by: Matt Turner <mattst88@gentoo.org>

dev-libs/libwacom/Manifest

@@ -1,2 +1,3 @@
 DIST libwacom-2.4.0.tar.xz 108812 BLAKE2B 18f41cd052b18c652c61062948355b4738afe57db344749055492cc6853bcbe3048c582a72318891727ec0fb01a7799f4c80c544b37b51c9246f98e5ae3fef1b SHA512 c67b8a81e9f4285a4e6f422b29e9b8b3677e3fc45e5190fd2b95ad361e5ef35e124b7d78bcf2bb9d7b7183525a6be9916b3038714c42c9ef405a1075750465f3
 DIST libwacom-2.5.0.tar.xz 109284 BLAKE2B cb9443aba276694eb64c6073488746ff4aff75ed77f334425d2f391a591f0a6cf222ef2124b6533ca7f2ca8e5eef36cd335026a87afabc12d912918ac1f930ed SHA512 62d181a5f4ce1335cd72623b7e82d5d44b9a11c08ec2ef4a98fd815fe2e1f814f42c909c2977e1b1ce803f04bac43414577830ff3724643fcecaf37113d098cf
+DIST libwacom-2.6.0.tar.xz 110288 BLAKE2B 321bacccab84f287141257b4c7af12822fca976c335027d399765fdbbb2c59eabcc76f40d4fd83c7cf1cdc88e2c57ccd317b1922ea3dddb98cf2a0847e920ff1 SHA512 aacf234e77bd976de2e2a687294c5ab704dca5a70df01fa2485441029e4faa34bec2824c455642115ae79f5cbbac41d064569e4eb2788655c324b37149009d26

dev-libs/libwacom/libwacom-2.6.0.ebuild

@@ -0,0 +1,66 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library for identifying Wacom tablets and their model-specific features"
+HOMEPAGE="https://github.com/linuxwacom/libwacom"
+SRC_URI="https://github.com/linuxwacom/${PN}/releases/download/${P}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/9" # libwacom SONAME
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/libgudev:=
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep '
+			dev-python/python-libevdev[${PYTHON_USEDEP}]
+			dev-python/pyudev[${PYTHON_USEDEP}]
+			dev-python/pytest[${PYTHON_USEDEP}]
+		')
+	)
+"
+
+python_check_deps() {
+	use test || return 0
+	python_has_version "dev-python/python-libevdev[${PYTHON_USEDEP}]" &&
+	python_has_version "dev-python/pyudev[${PYTHON_USEDEP}]" &&
+	python_has_version "dev-python/pytest[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	default
+
+	# Don't call systemd daemon-reload in the test suite
+	sed -i -e '/daemon-reload/d' test/test_udev_rules.py || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature doc documentation)
+		$(meson_feature test tests)
+		-Dudev-dir=$(get_udevdir)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}

dev-libs/libwacom/metadata.xml

@@ -5,6 +5,6 @@
 		<email>freedesktop-bugs@gentoo.org</email>
 	</maintainer>
 	<upstream>
-		<remote-id type="sourceforge">linuxwacom</remote-id>
+		<remote-id type="github">linuxwacom/libwacom</remote-id>
 	</upstream>
 </pkgmetadata>