app-admin/consul: add 1.15.7

Bug: https://bugs.gentoo.org/917614
Signed-off-by: Zac Medico <zmedico@gentoo.org>

app-admin/consul/Manifest

@@ -1 +1,2 @@
 DIST consul-1.15.3-vendor.tar.gz 43434721 BLAKE2B 7595c98cdecf67e9fb412d8fea1d790dc6b1c29f7bc427e1d0872045a05f8873dc6107f196cea04fe0a2f2553d4fbb1f8d501e5e107b2bea3ae841e5d94eda64 SHA512 b69e3a7c1ebb01c7a64f2c6167e63e8a530b81be9aad8b591d0a71f512f5157ba9a564b46f9effe52a5abd3ae61732e7af10c5ba002110f745eb3d94ebcec256
+DIST consul-1.15.7-vendor.tar.gz 46252048 BLAKE2B c63d69fb206895c535ffd60ada3589d99ec6aec81d7abe6b27169d4638bcc272f5d7c0b37d0bbe6be54f5e2d32f1e40fa1f4088da7fb4931f0c5c10007838197 SHA512 1e52f133f822cf11ee8498b7e92a7460c74d3ed4736c02e0957e3d950608f4aeaec8e8df7e9eb72ae7d4c31c4dcf5d827c9c42bdc7c4b991be53df22c150658a

app-admin/consul/consul-1.15.7.ebuild

@@ -0,0 +1,57 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit go-module systemd
+
+DESCRIPTION="A tool for service discovery, monitoring and configuration"
+HOMEPAGE="https://www.consul.io"
+GIT_COMMIT="8e803db6b98d10b2d310800f2aef7e20d3add03c"
+
+SRC_URI="https://github.com/zmedico/consul/archive/v${PV}-vendor.tar.gz -> ${P}-vendor.tar.gz"
+
+LICENSE="MPL-2.0 Apache-2.0 BSD BSD-2 CC0-1.0 ISC MIT"
+RESTRICT="test"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+BDEPEND="dev-go/gox"
+COMMON_DEPEND="
+	acct-group/consul
+	acct-user/consul"
+	DEPEND="${COMMON_DEPEND}"
+	RDEPEND="${COMMON_DEPEND}"
+
+S=${WORKDIR}/${P}-vendor
+
+src_prepare() {
+	default
+	sed -e 's|^GIT_DATE=.*|GIT_DATE=2023-10-31T14:10:44Z|' -i GNUmakefile || die
+}
+
+src_compile() {
+	# The dev target sets causes build.sh to set appropriate XC_OS
+	# and XC_ARCH, and skips generation of an unused zip file,
+	# avoiding a dependency on app-arch/zip.
+	GIT_DESCRIBE="v${PV}" \
+	GIT_DIRTY="" \
+	GIT_COMMIT="${GIT_COMMIT}" \
+	emake dev-build
+}
+
+src_install() {
+	dobin bin/consul
+
+	keepdir /etc/consul.d
+	insinto /etc/consul.d
+	doins "${FILESDIR}/"*.json.example
+
+	keepdir /var/log/consul
+	fowners consul:consul /var/log/consul
+
+	newinitd "${FILESDIR}/consul.initd" "${PN}"
+	newconfd "${FILESDIR}/consul.confd" "${PN}"
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+	systemd_dounit "${FILESDIR}/consul.service"
+}