dev-libs/double-conversion: 3.1.5 version bump

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

dev-libs/double-conversion/Manifest

@@ -1 +1,2 @@
 DIST double-conversion-3.1.4.tar.gz 7022872 BLAKE2B 270f318e6b37205ab3da3ccf5c598ca7a02dc2e728a5d8e3467523bc8f21039651bea3f70aeb9f8579505812d63181de9d1e8106997795a79efeb663e1bc22d7 SHA512 715a34ace2ff74b79d80a8c003c16cfbf958ebc92264e28cc572e1a12a786e1df9678abb46f032c2be387495e1a3d02957b12fa4a245ec6cfe19ca637519ac3c
+DIST double-conversion-3.1.5.tar.gz 7023792 BLAKE2B ed70a554bd52e23aadecbeaa6607dfcdb670450b95e2ff699c784512e6cb0c022f51f6ab775ebc5b3c293f991e5200ff5528d689c74dae92e8e68bedf672c5ac SHA512 0aeabdbfa06c3c4802905ac4bf8c2180840577677b47d45e1c91034fe07746428c9db79260ce6bdbdf8b584746066cea9247ba43a9c38155caf1ef44e214180a

dev-libs/double-conversion/double-conversion-3.1.5.ebuild

@@ -0,0 +1,54 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake multibuild
+
+DESCRIPTION="Binary-decimal and decimal-binary conversion routines for IEEE doubles"
+HOMEPAGE="https://github.com/google/double-conversion"
+SRC_URI="https://github.com/google/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0/3"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="static-libs test"
+
+RESTRICT="!test? ( test )"
+
+pkg_setup() {
+	MULTIBUILD_VARIANTS=( shared $(usev static-libs) )
+}
+
+src_configure() {
+	myconfigure() {
+		local mycmakeargs=(
+			-DBUILD_TESTING=$(usex test)
+		)
+		if [[ ${MULTIBUILD_VARIANT} = static-libs ]]; then
+			mycmakeargs+=( -DBUILD_SHARED_LIBS=OFF )
+		fi
+
+		cmake_src_configure
+	}
+
+	multibuild_foreach_variant myconfigure
+}
+
+src_compile() {
+	multibuild_foreach_variant cmake_src_compile
+}
+
+src_test() {
+	[[ ${MULTIBUILD_VARIANT} = shared ]] && cmake_src_test
+}
+
+src_install() {
+	myinstall() {
+		[[ ${MULTIBUILD_VARIANT} = shared ]] && cmake_src_install
+		[[ ${MULTIBUILD_VARIANT} = static-libs ]] && \
+			dolib.a ${BUILD_DIR}/libdouble-conversion.a
+	}
+
+	multibuild_foreach_variant myinstall
+}